AS2でキーによる音楽制御について

質問

AS勉強中で初心者の者です。
今回キーによる音楽制御を勉強しておりまして、不明点がありますので教えてください。

環境はwindows、Flash5.5、AS2です。
内容はAキーを押すと音楽がループ再生し、Bキーを押すと音楽が停止するもの。また他のキーを使って複数の音楽を同時再生、そのうちの１つの音楽のみを停止させる等、複数の音楽をそれぞれ制御できるものを制作したいです。

現在ライブラリにボタン１とボタン２、リンゲージ設定されたsoundAを用意し、シーン１にボタン１を配置し、ボタン１に

on (release) {
soundObj.start(0, 100);
}

を書きました。
同じようにシーン１にボタン２を配置し、ボタン２に

on (release) {
soundObj.stop("soundA");
}

を書きました。
そして、シーン１のタイムライン１フレーム目に

soundObj = new Sound();
soundObj.attachSound("ｓoundA");

を書きました。

これではステージ上のボタン１、２をマウスクリックすることで音楽を制御することになります。
これをキーで制御したいのですが、どのようにすればいいのでしょうか？
自分なりに模索したのはon (release) をonClipEvent(onKeyDown)にすればいいのか（←これだとAキー等の指定はどうすればいいか？）、on (release) ではなくKey.isDown(65)；を使うのか（これは動かなかったので、何かた足りないのか？）です。
後はそもそもキーで制御する際はボタンではなく、ムービークリップの方がいいのでしょうか？

説明が下手で至らない点もあるとは思いますが、どうぞよろしくお願いします。

回答No.2

BlurFiltan · ベストアンサー

＃１です。

＃１の【補足】を読ませていただきましたが，
８種類の音を別々に鳴らすのでしたら
少なくとも８個のSoundオブジェクトが必要になると思います。

var soundObjA:Sound = new Sound();
soundObjA.attachSound("soundA");

var soundObjB:Sound = new Sound();
soundObjB.attachSound("soundB");

　…略…

var soundObjH:Sound = new Sound();
soundObjH.attachSound("soundH");

↑このように。

しかし...，
８種類の音を制御するにしても
結局，具体的に「何をしたときに何をどうしたいのか」がわかりませんので
それ以上あまり具体的なことは書けませんよ。。。

具体的な動作がわからないので，
キー「A」「B」「C」「D」「E」「F」「G」「H」を押したときに
それぞれに対応する音が流れ
テンキーの
キー「0」「1」「2」「3」「4」「5」「6」「7」を押したときに
それぞれに対応する音(0ならAの音，1ならBの音)が止まる。
というルールで行くものと勝手に決めます。

また，複数の音は同時に鳴ることがあるものとします。

【動作例１】
キー「A」を押してキー「B」を押すと，
「Aの音」が鳴りさらに「Bの音」が重なって鳴る。

【動作例２】
キー「A」を押してキー「B」を押してキー「0」を押すと，
「Aの音」が鳴りさらに「Bの音」が重なって鳴り「Aの音」が消え「Bの音」だけが残って鳴り続ける。

このようなものを作成する場合の方法例ですが，
まず各音シンボルのリンケージで
８つある音に，0 からの連番付きの識別子を付けます。
「sound0」，「sound1」，……，「sound7」

※↑「soundA」，「soundB」，……，「soundH」ではありません。

そうしておいた上で，
シーン１のタイムライン１フレーム目に次のスクリプトス(例)を書きます。
ActionScript 2.0 です。

//-------------------------------------------
//この階層を変数化
var me:MovieClip = this;

//変数 i を 0～7 の間で 1 ずつ加算しながらループ
for (var i:Number = 0; i<=7; i++) {
//Soundオブジェクト「sound_obj0」～「sound_obj7」を作成
me["sound_obj" + i] = new Sound();
//各Soundオブジェクトに各音を割り当てる
me["sound_obj"+i].attachSound("sound"+i);
//各音の再生フラグ「sound_flg0」～「sound_flg7」を用意
me["sound_flg"+i] = false;
}

//キーを監視させるオブジェクトを作成
var key_obj:Object = new Object();

//キーを押したときに実行する関数の定義
key_obj.onKeyDown = function():Void {
//
//押されたキーコードを保存
var key_num:Number = Key.getCode();
//
//押されたキーコードが65～72(キーがA～H)の間であれば
if (key_num>=65 && key_num<=72) {
//さらにそのキーの音に対応するフラグが false であれば
if (!me["sound_flg"+(key_num-65)]) {
trace("sound_obj"+(key_num-65));
//そのキーに対応する音を再生
me["sound_obj"+(key_num-65)].start(0, 100);
//その音に対応するフラグを true にする
me["sound_flg"+(key_num-65)] = true;
}
//押されたキーコードが96～103(キーが1～7)の間であれば
} else if (key_num>=96 && key_num<=103) {
trace("sound_obj"+(key_num-96));
//そのキーに対応する音を停止
me["sound_obj"+(key_num-96)].stop("sound"+(key_num-96));
//その音に対応するフラグを false にする
me["sound_flg"+(key_num-96)] = false;
}
};

//key_obj を Key のリスナーとして登録
Key.addListener(key_obj);
//-------------------------------------------

me["sound_obj" + i] などで使っている [ ] を「配列アクセス演算子」と言います。

また，各キーとキーコードには次のような規則性があります。

キーA=コード65→ 65+0
キーB=コード66→ 65+1
キーC=コード67→ 65+2
キーD=コード68→ 65+3
キーE=コード69→ 65+4
キーF=コード70→ 65+5
キーG=コード71→ 65+6
キーH=コード72→ 65+7

キー0=コード96→ 96+0
キー1=コード97→ 96+1
キー2=コード98→ 96+2
キー3=コード99→ 96+3
キー4=コード100→ 96+4
キー5=コード101→ 96+5
キー6=コード102→ 96+6
キー7=コード103→ 96+7

この規則性を利用してスクリプトを簡素化しています。

お礼

何度もありがとうございます！！
希望の動作はBlurFiltanさんに仮定していただいた通りです。
スクリプト中にもご丁寧なコメントをしていただけたので、初めて見るスクリプトでしたがどんな処理がされるのかが、初心者の私にもよくわかって助かりました！！
今後の学習にも活かすことができ、大変嬉しく思います。
ご親切かつわかりやすい説明を本当にありがとうございました！！

回答No.1

BlurFiltan

まず，
ご使用の Flash のバージョンは
Flash5.5 ではなく Flash CS 5.5 ですよね？
Flash 5.x(西暦2000年バージョン) では ActionScript 1.0 の中でも最も初期のスクリプトしか使えません。

あと，
書かれていらっしゃるスクリプトの
soundObj.attachSound("ｓoundA");
の括弧内にある ｓoundA の最初の ｓ が
全角の ｓ になっていますが
これは間違いで半角の s ですよね？

そういうこととして以下を書きます。

> これをキーで制御したいのですが、
> どのようにすればいいのでしょうか？

すでに作ってあるボタンを使うのでしたら
次のようにすれば良いと思います。

//---シーン１のタイムライン１フレーム目------
soundObj = new Sound();
soundObj.attachSound("soundA");

//キーの状態を示すフラグを用意
key_flg = false;
//------------------------------------------

//---ボタン１------------------------------
//このボタンをクリックしたとき と
//「A」キーを押したとき に実行
on (release, keyPress "a") {
//もし key_flg が false であれば
if (!key_flg) {
soundObj.start(0, 100);
// key_flg を true にする
key_flg = true;
}
}
//------------------------------------------

//---ボタン２------------------------------
//このボタンをクリックしたとき と
//「スペース」キーを押したとき に実行
on (release, keyPress "<Space>") {
soundObj.stop("soundA");
// key_flg を false にする
key_flg = false;
}
//------------------------------------------

もし「このボタンをクリックしたとき」の動作が要らないのでしたら
on (release, keyPress "a") や
on (release, keyPress "<Space>") の
「release,」を削除すれば良いです。
(音を止めるときのキーが不明であったため，仮に「スペース」キーを使うものとしました。)

「key_flg」などというものを用意しているのは
「A」キーを押しっぱなしにされたときの重複実行阻止処理のためです。

「A」キーを押しっぱなしにされたり，何度も押されると，
何度も soundObj.start(0, 100); が実行されて
音が重なって無茶苦茶になります。
それを阻止するために「key_flg」を入れています。

ちなみに上のスクリプトは
ActionScript 2.0 設定でも使えますが
実質は ActionScript 1.0 の範囲内のスクリプトです。

> そもそもキーで制御する際はボタンではなく、
> ムービークリップの方がいいのでしょうか？

う～ん...，
それは正に Flash 5(2000年バージョン) 的な発想ですね。
「キー」を監視するのに
「キー」とは無関係なムービークリップを作るのは変ではないでしょうか？

Flash MX(2002年バージョン) 以降は
ムービークリップではなく Keyオブジェクト(Keyクラス) を使って「キー」を監視するのがナチュラルで一般的です。

念のため繰り返しますが，
Flash CS 5.5 で ActionScript 2.0 を使うのですよね？

ActionScript 2.0 が使えるのは Flash MX 2004(2004年バージョン) 以降です。
もし パブリッシュ設定 が
Flash Player 5 とか ActionScript 1.0 になっていましたら
とりあえず Flash Player 6 以上の ActionScript 2.0 にしてください。

そして上記スクリプトで使った「ボタン１」や「ボタン２」はステージ上から削除します。

そしてフレームに次のように書きます。

//---シーン１のタイムライン１フレーム目------
var soundObj:Sound = new Sound();
soundObj.attachSound("soundA");

//キーを監視させるオブジェクトを作成
var key_obj:Object = new Object();

//キーの状態を示すフラグを用意
var key_flg:Boolean = false;

//キーを押したときに実行する関数の定義
key_obj.onKeyDown = function():Void {
trace(Key.getCode());
//もし key_flg が false であり
if (!key_flg) {
//もし押されたキーが「A」であれば
if (Key.isDown(65)) {
soundObj.start(0, 100);
//もし押されたキーが「スペース」キーであれば
}else if(Key.isDown(32)){
soundObj.stop("soundA");
}
// key_flg を true にする
key_flg = true;
}
};

//キーを放したときに実行する関数の定義
key_obj.onKeyUp = function():Void {
// key_flg を false にする
key_flg = false;
};

//key_obj を Key のリスナーとして登録
Key.addListener(key_obj);
//------------------------------------------

これがボタンを用意しない場合の
ActionScript 2.0 (Flash MX 2004 以降)的 なやり方と そのスクリプトです。

※ 注意事項

Flash(SWF) でキーイベントを受け取ることができるのは
Flash(SWF) にフォーカスが当たっているときだけです。

ですから
HTML に SWF を貼り付けるときなどにおいては
ボタンは一切不要だとしても
「スタート」ボタンのようなものを最初に表示させるなど
Flash(SWF) にフォーカスを当ててもらうような工夫が必要です。

または
JavaScript で Flash にフォーカスを当てるとか。

Google検索例「swf フォーカス javascript」
http://www.google.co.jp/search?hl=ja&source=hp&q=swf+%E3%83%95%E3%82%A9%E3%83%BC%E3%82%AB%E3%82%B9+javascript

補足

ご丁寧な回答ありがとうございます。
いろいろなサイトを参考にし自分ではCS5.5のAS2でやっていたつもりでしたが、Flash5のAS1になっていました；
BlurFiltanさんから教えていただいた通りにやってみたところ、AS1でもAS2でもつくれました(^^)

そしてもう一つ補足質問なんですが、現在は１つの音楽制御が出来ていますが複数の音楽制御を行うにはどうしたらいいんでしょうか。

soundB(２つ目の音楽)、「B」キー（再生キー）、「C」キー（停止キー）としてやってみたのですが、
AS１の方では

//---シーン１のタイムライン１フレーム目------
soundObj = new Sound();
soundObj.attachSound("soundA");
　soundObj.attachSound("soundB");　　　←ここを加えた

//キーの状態を示すフラグを用意
key_flg = false;
//------------------------------------------

//---ボタンB------------------------------
//このボタンをクリックしたとき と
//「A」キーを押したとき に実行
on (release, keyPress "ｂ") {　　　　　←aをbに書き換えた
//もし key_flg が false であれば
if (!key_flg) {
soundObj.start(0, 100);
// key_flg を true にする
key_flg = true;
}
}
//------------------------------------------

//---ボタンC------------------------------
//このボタンをクリックしたとき と
//「スペース」キーを押したとき に実行
on (release, keyPress "ｃ") {　　　　←スペースをｃに書き換えた
soundObj.stop("soundB");　　　　　　　←soundAをsoundBに書き換え
// key_flg を false にする
key_flg = false;
}
//------------------------------------------

にしたところ、どちらの再生キー（「A」キーと「B」キー）を押してもsoundBが流れてしまい、停止もスペースキーは反応なしで「C」キーで停止するようになってしましました。

AS2はsoundBを足す以外いじり方がわからない状態です。

//---シーン１のタイムライン１フレーム目------
var soundObj:Sound = new Sound();
soundObj.attachSound("soundA");
　soundObj.attachSound("soundB");　　　←soundBを足した

//キーを監視させるオブジェクトを作成
var key_obj:Object = new Object();

//キーの状態を示すフラグを用意
var key_flg:Boolean = false;

//キーを押したときに実行する関数の定義
key_obj.onKeyDown = function():Void {
trace(Key.getCode());
//もし key_flg が false であり
if (!key_flg) {
//もし押されたキーが「A」であれば
if (Key.isDown(65)) {
soundObj.start(0, 100);
//もし押されたキーが「スペース」キーであれば
}else if(Key.isDown(32)){
soundObj.stop("soundA");
}
// key_flg を true にする
key_flg = true;
}
};

//キーを放したときに実行する関数の定義
key_obj.onKeyUp = function():Void {
// key_flg を false にする
key_flg = false;
};

//key_obj を Key のリスナーとして登録
Key.addListener(key_obj);
//------------------------------------------

最終的に音は８種類制御したいのですが、AS1、AS2どちらでもいいのでご指導いただけませんか？
すみませんがよろしくお願いいたします。