サブフォームのビューを切り替えたい

質問

親フォーム（フォーム１）にサブフォームとして、
テーブルをソースとするサブフォーム（テーブル1のサブフォーム）を配置しました。

親フォームからサブフォームのビューを変更したいのですが
どうすればいいか教えてください。

親フォームのコマンドボタンにはそれぞれ
Private Sub 単票フォームへ切り替え_Click()
Me.Controls("テーブル1のサブフォーム").Form.DefaultView = 1 '帳票フォーム
End Sub

Private Sub 帳票フォームへ切り替え_Click()
Me.Controls("テーブル1のサブフォーム").Form.DefaultView = 0 '単票フォーム
End Sub
としたのですが、
実行すると

実行時エラー 2136
"このプロパティを設定するには、フォームまたはレポートをデザインビューで開きます"。

となってしまいます。

Private Sub 帳票フォームへ切り替え_Click()
DoCmd.SelectObject acForm, "テーブル1のサブフォーム"
DoCmd.RunCommand acCmdFormView
End Sub

にしたところ、
実行時エラー　2489
“オブジェクト　テーブル１が開いていません、”
になります。

サブフォームに埋め込んでいて親フォームを開いていても
開いてない事になるのですね。

フォームビューの時に、切り替える事は不可能なのでしょうか？

帳票ビュー表示用フォーム、
単票ビュー表示用フォーム
を作るしかないのでしょうか？

回答No.1

hatena1989 · ベストアンサー

DefaultView の設定はデザインビューでしかできません。ですので、下記のような手順が必要です。

サブフォームコントロールのソースオブジェクトをクリアする。
サブフォームをデザインビューで開く
DefaultView を設定する
サブフォームを閉じる
サブフォームコントロールのソースオブジェクトを設定する

Private Sub 帳票フォームへ切り替え_Click()
On Error GoTo ErrorHandler

　　DoCmd.Echo False
　　Me.テーブル1のサブフォーム.SourceObject = ""
　　DoCmd.OpenForm "顧客", acDesign
　　Forms!テーブル1のサブフォーム.DefaultView = 1 '帳票フォーム
　　DoCmd.Close acForm, "テーブル1のサブフォーム", acSaveYes
　　Me.テーブル1のサブフォーム.SourceObject = "テーブル1のサブフォーム"

ExitProcedure:
　　DoCmd.Echo True
　　Exit Sub
ErrorHandler:
　　MsgBox Err & ":" & Err.Description
　　Resume ExitProcedure
End Sub

ちらつき防止の為に、DoCmd.Echo False を追加してます。
また、万一エラーが出ても DoCmd.Echo True は必ず実行されるように
エラー処理を追加してます。

お礼

デザインビューでしか切り替えられないのですか。
知りませんでした。
ヘルプをよく読んでみます。

ついでに
データシート_Click
も作成して、
hatena1989様のご回答を参考にＶＢＡを作成してみました。
--------------------------------------------------
Dim acFormView As Long

Sub FormView切り替え()
DoCmd.Echo False
Me.テーブル1.SourceObject = "" 'サブフォームコントロールのソースオブジェクトをクリアする。
DoCmd.OpenForm "テーブル1", acDesign 'サブフォームをデザインビューで開く
Forms!テーブル1.DefaultView = acFormView 'DefaultView を設定する
DoCmd.Close acForm, "テーブル1", acSaveYes 'サブフォームを閉じる
Me.テーブル1.SourceObject = "テーブル1" 'サブフォームコントロールのソースオブジェクトを設定する
DoCmd.Echo True
End Sub

Private Sub データシートへ切り替え_Click()
acFormView = 2 ' Datasheet
Call FormView切り替え
End Sub

Private Sub 単票フォームへ切り替え_Click()
acFormView = 0 '単票フォーム
Call FormView切り替え
End Sub

Private Sub 帳票フォームへ切り替え_Click()
acFormView = 1 '帳票フォーム
Call FormView切り替え
End Sub

とすることでうまく出来ました。
エラーの対応もしていきたいと思います。
とても助かりました。

ありがとうございました。大変参考になりました。