xlAPPがないと、キャンセルしても無視される

質問

Sub xlAPPがある場合()

Dim xlAPP As Application
Dim strPathName As String, vntPathName As Variant
Dim strFileName As String

Set xlAPP = Application

'ここでわざとESCキーかキャンセルを押す
vntPathName = xlAPP.InputBox("参照するフォルダ名を入力して下さい。", , "C:\")

If VarType(vntPathName) = vbBoolean Then
MsgBox "キャンセルがクリックされました"
Exit Sub
End If

End Sub

Sub xlAPPがない場合()

Dim strPathName As String, vntPathName As Variant
Dim strFileName As String

'ここでわざとESCキーかキャンセルを押す
vntPathName = InputBox("参照するフォルダ名を入力して下さい。", , "C:\")

　　’無視される
If VarType(vntPathName) = vbBoolean Then
MsgBox "キャンセルがクリックされました"
Exit Sub
End If

End Sub
**************************************************
InputBoxを開いた時にキャンセルするふたつのプロシージャーを比較した時に、
xlAPPがないコードは、キャンセルしても無視されます。

xlAPPがどんな役割をしているのか、
xlAPPがないと、なぜ無視されるのかがわかりません。

あと、二つを比較すると、表示されるInputBoxの形式も違います。

ご教授よろしくお願いします。

回答No.2

queuerev2 · ベストアンサー

Application.InputBoxを使っているということは、No.1さんも書かれていますがExcel VBAですね。
xlAPPがないInputBoxでも、StrPtr関数でキャンセルを判別することができるそうです。
（公式の仕様ではないという話もあるようですが）

Dim strPathName As String, vntPathName As Variant
'vntPathNameはString型にしても大丈夫なようです
Dim strFileName As String

'ここでわざとESCキーかキャンセルを押す
vntPathName = InputBox("参照するフォルダ名を入力して下さい。", , "C:\")

If StrPtr(vntPathName) = 0 Then
MsgBox "キャンセルがクリックされました"
Exit Sub
End If

参考URL：

http://hpcgi1.nifty.com/MADIA/VBBBS2/wwwlng.cgi?print+200509/05090069.txt

お礼

どうもありがとうございました。

回答No.1

watabe007

InputBoxは、2つあります。
◆ApplicationオブジェクトのInputBoxメソッド
　　　　入力されたデータを「文字列」「数値」「数式」「セルへの参照」などとして取得できる。
　　　　[キャンセル]ボタンが選択された場合、False(理論値)が返される。
　　　　キャンセルの場合
　　　　If VarType(vntPathName) = vbBoolean Then
　　　　　　MsgBox "キャンセルがクリックされました"
　　　　　　Exit Sub
　　　　End If

◆ InputBox 関数
　　　　入力されたデータはすべて文字列として取得される。
　　　　[キャンセル]ボタンが選択された場合、空の文字列("")が返される
　　　　キャンセルの場合
　　　　If 　vntPathName = "" Then
　　　　　　MsgBox "キャンセルがクリックされました"
　　　　　　Exit Sub
　　　　End If

参考URL：

http://officetanaka.net/excel/vba/tips/tips37.htm

お礼

どうもありがとうございました。