Excel2003日付指定で数値を返す

質問

A 　　　　　 B 　　　　　 C 　　　　　 D 　　　　 E
1 　 コード　　　　日付　　　枚数　　　金額　　　　　締め
2 　 1525 　　　 7/05 　　　　 3 　　　 4800 　　　 5
3 　 2555 　　　 7/11 　　　　 5 　　　 3900 　　　 15
4 　1524 　　　　 7/16 　　　　 2 　　　2980 　　 　 20

日付で1日～5日は締め5日　6日～10日は締め10日　11日～15日は締め15日　16日～20日は締め20日　21日～25日は締め25日　26日～31日は締め末日　と　日付によって締めが変わってきます、入力された日付で締め日を自動入力出来ればと　IF関数を使ってやってみたのですがうまく行きません、どうぞ宜しくお願いいたします。

回答No.8

keithin

Ｅ２に
=IF(B2="","",IF(DAY(B2)<26,CEILING(DAY(B2),5),DAY(DATE(YEAR(B2),MONTH(B2)+1,0))))
ぐらいでいいです。

回答No.7

esupuresso

まず先に「EOMONTH」という関数を使いますので「ツール」→「アドイン」→「分析ツール」にチェックを入れて「OK」で閉じます

IF関数を使って値を返す場合の数式は次の通り
セルE2=IF(DAY(B2)>=26,TEXT(DAY(EOMONTH(B2,0)),"D")*1,IF(DAY(B2)>=21,25,IF(DAY(B2)>=16,20,IF(DAY(B2)>=11,15,IF(DAY(B2)>=6,10,IF(DAY(B2)>=1,5,""))))))

「EOMONTH」葉そのまま使うと日付で値を返してきますので「TEXT」関数をを使い更に数値化してあげます
更にその月の最終日も出力することが出来ますので閏年、その他も特に心配する必要はありません

一応、画像を添付しておきます　<(_ _)>

回答No.6

nicotinism

=IF(DAY(B2) >25,DAY(DATE(YEAR(B2),MONTH(B2)+1,0)),INT((DAY(B2)-1)/5+1)*5)
とか？

回答No.5

tom04

No.3・4です！

何度もごめんなさい。
No.3で誤記がありました。

＞メニュー　→　ツール　→　オプション　→　「分析ツール」に・・・
は
＞メニュー　→　ツール　→　アドイン　→　「分析ツール」に・・・
が正解です。

どうも失礼しました。m（_ _）m

回答No.4

tom04

No.3です！
たびたびごめんなさい。

前回の数式内　Match関数で余計なものが入っていました。
（そのままでも問題ないと思いますが）

数式を

=IF(B2="","",IF(DAY(B2)>=26,DAY(EOMONTH(B2,0)),CHOOSE(MATCH(DAY(B2),{1,6,11,16,21},1),5,10,15,20,25)))

に訂正してください。m（_ _）m

回答No.3

tom04

こんにちは！
No.1さんとほぼ同じやり方になりますが・・・

E2セルに

=IF(B2="","",IF(DAY(B2)>=26,DAY(EOMONTH(B2,0)),CHOOSE(MATCH(DAY(B2),{1,6,11,16,21,26},1),5,10,15,20,25)))

という数式を入れオートフィルで下へコピーではどうでしょうか？

※　Excel2003というコトですので、EOMONTH関数を使用するにあたり
メニュー　→　ツール　→　オプション　→　「分析ツール」にチェックを入れておく必要があります。

※　E列セルの表示形式は　ユーザー定義から
0日
としておきます。

参考になりますかね？m（_ _）m

回答No.2

noname#204879

》 26日～31日は締め末日

単に「末」あるいは「末日」と表示させるのですか？それとも…
１月、２月、４月はそれぞれ 31、28(または 29)、30 と表示させるのですか？
ソコントコ明確にしなきゃ～！

補足

そこまで厳密に考えて質問をしていませんでした。mike_gさんの指摘どおりですね、暦によって末日は変わります。ありがとうございます。

回答No.1

aokii

=CHOOSE(DAY(B2),5,5,5,5,5,10,10,10,10,10,15,15,15,15,15,20,20,20,20,20,25,25,25,25,25,DAY(EOMONTH(B2,0)),DAY(EOMONTH(B2,0)),DAY(EOMONTH(B2,0)),DAY(EOMONTH(B2,0)),DAY(EOMONTH(B2,0)),DAY(EOMONTH(B2,0)))