VBA マクロ付きExcelファイルを無効で開く

質問

タイトルの通り、マクロを含むExcelファイルを、マクロ無効でオープンしたいのですが、そういうことは出来るでしょうか？

新規ファイル作成.xlsというマクロがあって、temp.xlsというマクロを含んだファイルをnew.xlsというファイル名でコピーし、それをオープンしてデータを追加して終了。
次にそのnew.xlsをオープンした時にはtemp.xlsに含まれるマクロが実行される・・・
というようなことをしたいと思っています。

もしくは新規ファイル作成.xlsのマクロから、直接new.xlsのファイルにコーディングが可能であれば、それでも良いのですが・・・

データベースから表を作成し、作成後の変更データを再度データベースへ戻す、ということがやりたいのですが、上記の方法しか思いつきません。
もし上記の方法が出来ない場合は、別の方法がありますでしょうか？
どなたかアドバイス、よろしくお願いします。

回答No.2

papayuka · ベストアンサー

#1の方への補足から、B.xls の WorkBook_Open に UserFormを開くイベントがあり、マクロから B.xls を開いた場合は実行したくないって事だと判断しました。
意味が違ったら読み飛ばしてください。Excel97で確認してます。

A.xls と B.xls が同じフォルダ内にあるとして

Sub Test()
Dim motoB As String, copyB As String, wb As Workbook
　motoB = ThisWorkbook.Path & "\B.xls"
　copyB = ThisWorkbook.Path & "\New.xls"
　FileCopy motoB, copyB　　　　　　 'B.xlsをコピー
　Application.EnableEvents = False　'イベントを一時無効化
　Set wb = Workbooks.Open(copyB)　　'B.xlsのコピーを開く
　Application.EnableEvents = True　 'イベントを有効に戻す
　'ここから
　wb.Worksheets(1).Range("A1") = Now
　wb.Save
　wb.Close
　'ここまではサンプルとして適当な処理
End Sub

また、別の方法として B.xls の WorkBook_Open を止めて、標準モジュールに

Sub Auto_Open()
　UserForm1.Show
End Sub

のようにすると A.xls 側で EnableEvents を使わなくても Auto_Open は実行されません。

お礼

お礼が遅れて申し訳ありません！

はい、papayukaさんが冒頭で言われている事をしたいと思っていました。
EnableEventsというプロパティ？は知りませんでした。
これが処理を止める方法なのですね。
助かりました、ありがとうございました。