エクセルで出荷表と出荷伝票をつくりたい

質問

【シート１】に
列　　Ａ　　　　　Ｂ　　　　Ｃ　　　　Ｄ　　　　　Ｅ　　・・・・
　　　　　　　　　　　　　出荷日　出荷日　出荷日　・・・
　　商品名　　コード　1月1日　1月5日　1月10日　・・・
　　　ア　　　　　01　　　　10
　　　イ　　　　　05　　　　　　　　　5
　　　ウ　　　　　03　　　　5　　　　　　　　　23
　　　・
　　　・
　　　・

上記のような感じで横軸に出荷日、縦軸に商品名の在庫一覧がある

【シート2】に
シート1で入力したら、その該当の商品名等を引っ張ってくる出荷伝票を作りたいのです
出荷日　　商品名　　　コード　　数量
1/1　　　　　ア　　　　　　01　　　　10
1/1　　　　　ウ　　　　　　03　　　　5

回答No.1

keithin · ベストアンサー

シート１は
Ａ列に商品名
Ｂ列にコード
Ｃ列からとりあえず最大ＡＡ列まで出荷日

２行目Ｃ２から右に出荷日
３行目以下とりあえず最大９９行まで，つまりＣ３から右下が数量の記入欄

という配置にしておきます。

シート２は
Ａ２に
=IF(ROW(A1)>COUNT(Sheet1!$C$3:$AA$99),"",INDEX(Sheet1!$2:$2,SMALL(IF(Sheet1!$C$3:$AA$99="","",COLUMN(Sheet1!$C$3:$AA$99)),ROW(A1))))
と記入して，コントロールキーとシフトキーを押しながらEnterで入力

Ｂ２には
=IF(A2="","",INDEX(Sheet1!A:A,MATCH(C2,Sheet1!B:B,0)))
と記入してEnterで入力

Ｃ２には
=IF(A2="","",INDEX(Sheet1!$B:$B,SMALL(IF(INDEX(Sheet1!$C$3:$AA$99,0,MATCH(A2,Sheet1!$C$2:$AA$2,0))="","",ROW(Sheet1!$C$3:$AA$99)),COUNTIF($A$2:A2,A2))))
と記入して，コントロールキーとシフトキーを押しながらEnterで入力

Ｄ２には
=IF(A2="","",INDEX(Sheet1!$C$3:$AA$99,MATCH(C2,Sheet1!$B$3:$B$99,0),MATCH(A2,Sheet1!$C$2:$AA$2,0)))
と記入してEnterで入力。

Ａ２：Ｄ２を下向けにコピー。

＃補足
（シート１に入力することで）「使いやすくしたい」ためにこんな無茶な使いにくい数式を組むハメになります。

エクセル的には，シート２の型式でダラダラとデータを順不同でどんどん記入していき，ピボットテーブルレポートなどの機能を使ってさくっとシート１の格好に整理させた方が，遙かに簡単に作成できます。