ExelVBA Dirでのファイル名検索について

質問

VBA勉強中の者です。早速ですが質問させて頂きます。
CドライブのSample Picturesという様々な形式の画像があるフォルダの中から、
jpgとpngの画像のみ名前をsheet4のA1から下方向に書き出したいと考え、
サイトや本で調べながら以下のコードを作成しました。

Sub sample()

Worksheets(4).Cells.Clear

Dim pngFileName As String
Dim jpgFileName As String
Dim CellsCount As Long

Const path As String = "C:\Documents and Settings\All Users\Documents\My Pictures\Sample Pictures\"

pngFileName = Dir(path & "*.png")

Do While pngFileName <> ""
CellsCount = CellsCount + 1
Cells(CellsCount, 1) = pngFileName
pngFileName = Dir()
Loop

jpgFileName = Dir(path & "*.jpg")

Do While jpgFileName <> ""
CellsCount = CellsCount + 1
Cells(CellsCount, 1) = jpgFileName
jpgFileName = Dir()
Loop

End Sub

一応目的は達成出来ているのですが、スッキリできません。
Dir(path & ~ の部分で、ワイルドカードの指定文字が "*.jpg" と "*.png" の２種類ある時には
わざわざDo White Loopを２回繰り返しさないといけいないのか疑問です。
仮に画像ファイルだけでなく、何種類もの拡張子を指定して抽出したい時には
そのつどコードを増やさないといけないのでしょうか？

考えた末
PictFileName = Dir(path & "*.jpg" Or path & "*.png")や
PictFileName = Dir(path & "*.jpg" Or "*.png")などとしてみましたが
型が一致しないというエラーが出てしまいました。

もっとシンプルに分かり易くしたいです、どなたかご助力お願いいたします。
当方Excel2003を使用しております。

回答No.1

keithin · ベストアンサー

＞わざわざDo White Loopを２回繰り返しさないといけいないのか…

はい，その通りです。

作成例：
sub macro1()
　dim myPath as string
　dim myFile as string
　dim a as variant
　dim i as long, n as long

　mypath = "C:\Documents and Settings\All Users\Documents\My Pictures\Sample Pictures\"
　a = array("*.jpg","*.png")

　for i = 0 to ubound(a)　
　　myfile = dir(mypath & a(i))
　　do until myfile = ""
　　　n = n + 1
　　　cells(n, "A") = myfile
　　　myfile = dir()
　　loop
　next i
end sub

お礼

なるほど！こういう時にArrayを使うといいんですね！
今まで配列の類はどんな時に使うのか全然イメージがわかなかったので、
そういう意味でも大変参考になりました。
２回Loopはするものの、この書き方ならコードがシンプルで分かり易くなりますね。
ぱっと見てすぐに理解できない部分が多少ありますが、そこは自力で調べてなんとかモノにしたいと思います。
勉強になりました、有難うございます！

回答No.2

mu2011

安直です。
pngFileName = Dir(path & "*.png")　→　pngFileName = Dir(path & "*.??g")

お礼

おぉ、なるほど！これは盲点でした！これならば曖昧であるものの、確かにjpgとpngを一度に指定できますね。有難う御座います！