ExcelVBAマクロ『並べ替え』⇒『重複の削除』

質問

ExcelVBAマクロにについて確認させて下さい。
いくつかの値をエクセルの一つの行に並べてあり、 これをExcelの機能である『並べ替え』⇒『重複の削除』をExcelVBAマクロで同様に実行したいのですがどのようにすれば良いでしょうか。

以上よろしくお願いいたします。

回答No.2

imogasi · ベストアンサー

エクセルのバージョンを書いて質問すること。
エクセル２００３以前だと、「重複の削除」が無いのでは。エクセル２０１０？
ーー
こんな単品リクエストなら、一例の操作をして、「マクロの記録」を取ればコードが出てくるでしょう。
データ範囲は操作したときの選択したセル範囲（決定・固定）になっているから、
＞一つの行に並べてあり
エクセルの通常使用法と違うと思う（普通は列方向にデータを増やすが）
行方向に増やしたものなら
Sub test02()
r = Range("IV2").End(xlToLeft).Column
MsgBox r
End Sub
でデータの存在する一番右の列がとらえられる。
ーー
これを使ってソート対象は
下記は２００３以前用で　IV2　となっているが一般的書き方ではMsgBox Columns.Countで示される数です。
Sub test02()
r = Range("IV2").End(xlToLeft).Column
MsgBox r
d = Range("A65536").End(xlUp).Row
MsgBox d
Range(Cells(2, "A"), Cells(d, r)).Select
End Sub
を参考にして。結果確認はシートタブのクリックで確認しないと選択範囲がくづれるの出注意。
Ｍｓｇｂｏｘ　は納得できたら削除。
ーー
そのほかにも、データの在る範囲をとらえるＶＢＡコードの方法は数種在る。

お礼

遅くなって申し訳ございません。
早速のご回答ありがとうございます。

分かりやすいご説明、誠にありがとうございます。
ご参考にさせていただきました。

また機会ありましたらよろしくお願いいたします。

回答No.1

temtecomai2

マクロの記録で記録されたコードで勉強するのが基本かと。
記録されたコードを見てみると、記録した時のデータ件数（行数）の部分に柔軟性がないので、件数が何件あろうと柔軟に対応できるように書き換える必要が出る。

実際に質問者が想定しているデータ入力状態がわからないので、以下のように勝手に想像してみた。
・ セル A1 にタイトルがあり、A2 から下に向かって途切れなくデータが入っている。
・ セル A1 がアクティブになっている状態でマクロを実行する。
・ Excel 2007 または 2010 を使っている。(2003 以前ではコードが違う)

Dim startCell As Range ' 起点となるセル
Dim endCell As Range ' データの最終セル

Set startCell = ActiveCell ' アクティブになっているセルを起点とする。(セル A1 を想定)
Set endCell = startCell.End(xlDown) ' A1 から下に向かってデータが途切れるセルを最終セルとする

Dim currentSheet As Worksheet ' 対象シート
Set currentSheet = ActiveSheet ' 現在アクティブなシートを対象とする

' 現在のソート条件をクリアし、新たに設定する。
' A2 から最終セルまでを範囲とし、値を昇順で並び替える。
currentSheet.Sort.SortFields.Clear
currentSheet.Sort.SortFields.Add _
　　Key:=Range(startCell.Offset(1, 0), endCell), _
　　SortOn:=xlSortOnValues, _
　　Order:=xlAscending, _
　　DataOption:=xlSortNormal

' ソートを実行する。
' 起点セルから最終セルまでを対象とし、先頭行をタイトル行とし、大文字小文字を区別せず、行方向へ、振り仮名を使って並び替えを実行する。
With currentSheet.Sort
　　.SetRange Range(startCell, endCell)
　　.Header = xlYes
　　.MatchCase = False
　　.Orientation = xlTopToBottom
　　.SortMethod = xlPinYin
　　.Apply
End With

' 起点セルから最終セルまでの間で、ダブっているデータを削除する。
currentSheet.Range(startCell, endCell).RemoveDuplicates Columns:=1, Header:=xlYes

お礼

お礼

遅くなって申し訳ございません。
早速のご回答ありがとうございます。

分かりやすいご説明、誠にありがとうございます。
ご参考にさせていただきました。

また機会ありましたらよろしくお願いいたします。