actionscript 3.0 の外部リンク

質問

初めて質問させていただきます。
Flash CS3 のactionscript3.0にて、サイト内リンクのボタンを作成したのですが、
フラッシュを読み込んだ時点で、インスタンスthe URL4がポップアップで開いてきてしまいます。
そのような記述をしていないのでどうしたら良いか分からず…
何かお知恵をお貸しいただけると幸いです。
よろしくお願い致します。

- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
↓実際に書いたacitonscriptです。URLはダミーです。

//theURL1という変数に代入し、URLRequestのインスタンスを生成
var theURL1:URLRequest = new URLRequest("http://www.111/A.html");
var theURL2:URLRequest = new URLRequest("http://www.222/B.html");
var theURL3:URLRequest = new URLRequest("http://www.333/C.html");
var theURL4:URLRequest = new URLRequest("http://www.444/D.html");

navigateToURL(theURL1);
navigateToURL(theURL2);
navigateToURL(theURL3);
navigateToURL(theURL4);

// イベントリスナーの登録
A_btn.addEventListener(MouseEvent.CLICK,gotoURL1);
B_btn.addEventListener(MouseEvent.CLICK,gotoURL2);
C_btn.addEventListener(MouseEvent.CLICK,gotoURL3);
D_btn.addEventListener(MouseEvent.CLICK,gotoURL4);

// URL1へジャンプする
function gotoURL1(event:MouseEvent):void
{
var theURL1:URLRequest = new URLRequest("http://www.111/A.html");
navigateToURL(theURL1,"_self");
}

// URL2へジャンプする
function gotoURL2(event:MouseEvent):void
{
var theURL2:URLRequest = new URLRequest("http://www.222/B.html");
navigateToURL(theURL2,"_self");
}

// URL3へジャンプする
function gotoURL3(event:MouseEvent):void
{
var theURL3:URLRequest = new URLRequest("http://www.333/C.html");
navigateToURL(theURL3,"_self");
}

// URL4へジャンプする
function gotoURL4(event:MouseEvent):void
{
var theURL4:URLRequest = new URLRequest("http://www.444/D.html");
navigateToURL(theURL4,"_self");
}

回答No.2

BlurFiltan

> そのような記述をしていないのでどうしたら良いか分からず…

それは，「はぁ？」ですよ。。。

バッチリそのような記述をされているじゃないですか。
これ↓で自動的にそれぞれのリクエストURLが開きます。

navigateToURL(theURL1);
navigateToURL(theURL2);
navigateToURL(theURL3);
navigateToURL(theURL4);

この４行を消せば良いだけ(元から書かなければ良いだけ)です。

この４行で，本来４つのページが開くはずですが，
１つしか開かないのは，リクエストの乱発によって最初の３つが無効になるためです。
(＝最初の３つが開かないのはセキュリティにはばまれただけ。)

それと問題解決とは別件ですが，
２回も同じURLを登録していること自体も変ですよ。

書かれていらっしゃるスクリプトを
「１URL分だけ」に単純化して注釈行を付け直しておきます↓。
簡単なスクリプトなんですから，
１行１行何をしているのか考えてみましょう。

---１URL分だけに単純化--------------------
//★変数名「theURL1」の URLRequest のインスタンスを生成
// (リクエストURL「http://www.111/A.html」)
var theURL1:URLRequest = new URLRequest("http://www.111/A.html");

//☆そのリクエストURLを別窓で開く
navigateToURL(theURL1);

//「A_btn」にクリック時に動作するイベントリスナーを登録
A_btn.addEventListener(MouseEvent.CLICK,gotoURL1);

//クリック時に動作するリスナー関数gotoURL1の定義
function gotoURL1(event:MouseEvent):void
{
//★変数名「theURL1」の URLRequest のインスタンスを生成
// (リクエストURL「http://www.111/A.html」)
var theURL1:URLRequest = new URLRequest("http://www.111/A.html");
//
//☆そのリクエストURLを同窓で開く
navigateToURL(theURL1,"_self");
}
--------------------------------------------

↑同様のことを２回書いていますよね？

navigateToURL(theURL1); を削除するとともに
その他の場所についても，
どこをどう修正すべきかを考えてみましょう。
(修正箇所や内容は作者の意図によって変わります。)
(＝修正すべきなのは確かなことですが，どこをどう修正すべきかは私が決めることではありません。)

お礼

ご丁寧な解説をいただき、ありがとうございました！

フラッシュもプログラム初めて扱うもので実践しながら勉強してます…って言い訳ですね。
私自身、分かったような分かってないような感覚で進んでいました。

本当にありがとうございました。非常に助かりました＆参考になりました。

回答No.1

DPE

スクリプトは上から順に実行されていきます。
navigateToURL は指定された URL を開く命令ですから、var theURL4:URLRequest = new URLRequest の後に書かれているこの命令が実行されて、ページが開いてしまいます。

ボタンの名前（インスタンス名）と開く URL は違っていても、「クリックした時に URL を開く」という動作は共通しています。
少し工夫しますと、スクリプトをすっきりまとめることができます。

次のように考えます。
各リンクボタンを、ムービークリップシンボルとして作成します。
ムービークリップシンボルであれば自分の中に任意の変数を作ることができるので、リンクボタンとして使うムービークリップそれぞれに URLRequest オブジェクトを作成します。このオブジェクトの名前は、全てのリンクボタンで統一の名前にします。

イベント処理関数が呼び出された時に渡される情報を利用して、クリックされたリンクボタンで開く URL を取り出します。
変数を利用しますから、インスタンス名と URL が違うためにリンクボタンの数だけイベント処理関数を作る必要はなくなります。

問題は、ムービークリップごとに異なる URL を設定する方法ですが。
いろいろな方法がありますが、今回は簡単なところで、配列変数を作り、ボタンとして使うインスタンスの参照と URL の情報をペアにして表を作ります。
この表を for ループで順番に見ながらリンクボタンのインスタンスの参照を取り出し、それぞれの中に開く URL を記録するとともに、イベントリスナーを登録します。

＊ ＊ ＊

スクリプトの一例です。
ステージに、ムービークリップシンボルのインスタンス A_btn ～ D_btn があるとします。
このスクリプトは、メインのタイムラインに記述してください。
（↓　各行頭に全角のスペースが入っています。コピーする際は、全て半角のスペースかタブに置き換えてください）

//***

　//ムービークリップの参照とリンク先を管理する配列変数
　var link_tbl:Array =
　[
　　{ clip : A_btn , link : "○○○.html" } ,
　　{ clip : B_btn , link : "△△△.html" } ,
　　{ clip : C_btn , link : "□□□.html" } ,
　　{ clip : D_btn , link : "＊＊＊.html" }
　];

　//クリックされた時のイベント処理関数
　function gotoURL( eventObj:MouseEvent ):void
　{
　　//インスタンス内に記録されたURLを開く
　　navigateToURL( eventObj.target.link_url , "_self" );
　}

　//各インスタンスの設定
　for( var i:Number = 0 ; i < link_tbl.length ; i++ )
　{
　　//設定するムービークリップの参照を取得
　　var mc:MovieClip = link_tbl[ i ].clip;

　　//このインスタンスの中にURLRequestオブジェクトを作り、URLを記録する
　　mc.link_url = new URLRequest( link_tbl[ i ].link );

　　//ボタン化とイベントリスナーの登録
　　mc.buttonMode = true;
　　mc.addEventListener( MouseEvent.CLICK , gotoURL );
　}

//***

配列変数とは、名前が同じで管理番号だけが違う、複数の変数の集まりです。
ActionScript の配列変数は、１つの要素の中にさらに仕切りを作り、複数の情報を管理できるようになっています。
今回は１つの要素の中に clip と link という名前の仕切りを作り、clip にリンクボタンとして使うムービークリップの参照、link に開く URL の文字列を入れて、ムービークリップの参照と URL をペアで扱えるようにしています。
この配列変数を for ループで先頭から順に見ていくと、ループの中では、link_tbl[ i ].clip と link_tbl[ i ].link という共通の記述で、各リンクボタンの参照と開く URL を、それぞれ取り出すことができます。
名前が共通なので、リンクボタンが増えた時も、配列変数にリンクボタンとして使うムービークリップの参照と URL を増やすだけで対応できます。

イベント処理関数には、イベントが発生して呼び出された時に、イベントに関する様々な情報が引数として渡されてきます。
この情報の１つに、イベントを検出した対象を表す情報があります。この情報は、仮引数名.target という名前で、イベント処理関数の中で見ることができます。
上記の例ですと、イベント発生時に呼び出される gotoURL の仮引数の名前は” eventObj ”です。
つまり、gotoURL 関数の中では、同じ eventObj.target という表現でも、A_btn がクリックされた時は A_btn を、B_btn がクリックされた時は B_btn を表します。

各リンクボタンには予め、link_url という共通の名前で URLRequest オブジェクトを作り、この中に開く URL が記録してあります。
合わせますと、イベント処理関数の中では

　navigateToURL( eventObj.target.link_url , "_self" );

という、変数を利用した１行でそれぞれのリンクボタンに対応する URL に移動でき、イベント処理関数も１つだけで済みます。

－ － － － －

なお、ボタンシンボルとしてリンクボタンを作ってある場合は、「ライブラリ」パネルでシンボルを選択した状態で右クリックでメニューを開き、「タイプ」メニューから”ムービークリップ”を選ぶと、ムービークリップシンボルに変更できます。
ボタンシンボルの各フレームは、ムービークリップのタイムラインのフレームに１つずつ展開されます。
この状態のまま使うと、作品が再生された途端にムービークリップのタイムラインが連続的に再生され、チカチカしてしまいます。

簡単な変更方法としては、ムービークリップにもボタンシンボルのような機能を持たせる特殊なフレームラベルを利用する方法があります。
まず、ムービークリップのタイムラインのフレーム１に stop(); アクションを記述し、最初のフレームでタイムラインを止めます。
ボタンシンボルのアップ・オーバー・ダウンにあたるフレームにそれぞれ、 _up ・ _over ・ _down というフレームラベルを付けて、完成です。
特殊なフレームラベルによるボタンのような振る舞いは、buttonMode プロパティが true の時だけ有効になります。

シンボルをボタンからムービークリップに変更しても、ステージに既に配置したインスタンスはボタンのインスタンスになっている場合があります。
インスタンスを選択した状態で「プロパティ」パネルでタイプを確認し、ボタンになっているようであればムービークリップに変更してください。