オンマウスでモーションを停止させるには？

質問

たびたびの質問ですみません。よろしくお願いいたします。

http://soudan1.biglobe.ne.jp/qa3658780.html

こちらのURLを参考に、外部XMLを読み込んで
画像とリンク先を切り替えるフラッシュを作っています。
フェードインとフェードアウトの効果はモーショントゥイーンで
作成しているのですが、
フェードインが完了(自分は11フレーム目にしています)してから
フェードアウトが始まる(自分は26フレーム目にしています)までの間、
オンマウスするとモーションが止まるように設定するにはどうし
たらよいですか？
つまり、フェードイン・フェードアウト中は、アルファが100になるまで動作を続けて、アルファが100のうちはオンマウスするとモーションが止まるようにです。

ボタンを設置したりしてみたのですがどうしてもうまくいきません。
よろしくお願いいたします。

回答No.1

BlurFiltan · ベストアンサー

ご質問内容そのままの回答を書くと
書かれているページの
フレーム2 のスクリプトの次の部分を

-----------
// JPEG ロード完了時
myObj.onLoadInit = function(target_mc) {
// load_mc にリンクを設定
target_mc.onRelease = function() {
getURL(myXML.childNodes[0].childNodes[cnt].attributes.linkURL, "_blank");
};
// 再生開始
_root.play();
};
-----------

次のように変えれば良いと思います。

-----------
//JPEGロード完了時
myObj.onLoadInit = function(target_mc) {
//ロールオーバー時の動作
target_mc.onRollOver = function() {
//再生フレームが11以上26以下であれば
if (_currentframe >= 11 && _currentframe <= 26) {
//再生停止
stop();
}
};
//ロールアウト＆外で放した時の動作
target_mc.onRollOut = target_mc.onReleaseOutside = function () {
//再生フレームが11以上26以下であれば
if (_currentframe >= 11 && _currentframe <= 26) {
//再生開始
play();
}
};
//load_mcにリンクを設定
target_mc.onRelease = function() {
getURL(myXML.childNodes[0].childNodes[cnt].attributes.linkURL, "_blank");
};
//再生開始
_root.play();
};
-----------

しかし
実際にやってみるとこれは変なんです。
フレーム11未満でオンマウスすると
そのままフェードインして勝手にフェードアウトしてしまいます。
（そうなるように書いているので当たり前ですが。。。）

上のような感じではなくて
したいことは次のような感じではないでしょうか？

-----------
//JPEGロード完了時
myObj.onLoadInit = function(target_mc) {
//ロールオーバー時の動作
target_mc.onRollOver = function() {
//再生フレームが11未満の時
if (_currentframe < 11) {
//毎フレーム時間実行するメソッドを定義
target_mc.onEnterFrame = function() {
//再生フレームが11の時
if (_currentframe == 11) {
//再生停止
stop();
//毎フレーム時間実行するメソッドを削除
delete target_mc.onEnterFrame;
}
};
//それ以外で再生フレームが 26以下の時
}else if (_currentframe <= 26) {
//再生を停止
stop();
}
};
//ロールアウト＆外で放した時の動作
target_mc.onRollOut = target_mc.onReleaseOutside = function () {
//毎フレーム時間実行するメソッドを削除
delete target_mc.onEnterFrame;
//再生開始
play();
};
// load_mc にリンクを設定
target_mc.onRelease = function() {
getURL(myXML.childNodes[0].childNodes[cnt].attributes.linkURL, "_blank");
};
// 再生開始
_root.play();
};
-----------

お礼

お世話になっております！
前回も回答くださった方ですね！
本当にありがとうございます。。。
実現したかったのはおっしゃるとおり後者のスクリプトのほうでした！
完璧です！！！！
なんとお礼を言ったらよいかわからないのですが、今後ともよろしくお願いいたします。