エクセルマクロで外部ファイルを開きたい

質問

エクセルマクロで外部ファイルを開きたい
エクセルのマクロをまだ詳しく知らないため、
ここで教えていただき一連の作業の最後にデータをクリップボードに
納めるところまでのマクロを作っていただきました。
そしてこのクリップされたデータをエディタソフト(Em-Editor)をその都度起動して張り付けています。
ついては使用中のマクロの中に外部ファイル（エディタ）を呼び出すところまでできれば
都合がいいのですが、手元にある解説書などを見ると
ファイルの呼び出しマクロはエクセルのワークブックのことしか記述してありません。
外部ファイル（エディタ・新規）をマクロで呼び出すことは可能でしょうか。
WindowsXP-SP3/Excel2003/

回答No.15

DOUGLAS_

Sub Macro1()
'//Microsoft Forms 2.0 Object Libraryを参照設定

'//変数の宣言
　Dim wshShell As Object　　'WshShell オブジェクト
　Dim rng As Range　　　　　'データセル範囲
　Dim n As Integer　　　　　'データセル範囲の列数
　Dim i As Integer　　　　　'ループカウンター
　Dim x As Integer　　　　　'オフセット量
　Dim c As Range　　　　　　'データセル
　Dim buf As String　　　　 '書込用バッファ
　Dim CB As New DataObject　'クリップボード

'//「WshShell オブジェクト」と「初期スタート位置」の準備
　Set wshShell = CreateObject("Wscript.Shell")
　Range("R1").End(xlDown).Select

'//グループ ごとの繰り返し作業開始
　Do

'//データ表示数式セル範囲の取得（エラー表示セルはそのまま表示）
　　Set rng = Range("M" & ActiveCell.Row, "R" & ActiveCell.End(xlDown).Row)
　　n = rng.Columns.Count

'//データ抽出（空白セルは抽出しない）
　　For i = n To 1 Step -1
　　　Select Case i
　　　　Case 2: x = 1
　　　　Case 1: x = 2
　　　　Case Else: x = i
　　　End Select
　　　For Each c In Range(rng.Columns(x).Address)
　　　　If c.Text <> "" Then _
　　　　　buf = buf & vbCrLf & c.Text
　　　Next
　　Next i
　　buf = Replace(buf, vbCrLf, "", 1, 1)

'//クリップボードに格納
　　With CB
　　.SetText buf
　　.PutInClipboard
　　.GetFromClipboard
　　End With

'//書込用バッファ を解放
　　buf = ""

'//EmEditor を起動
　　wshShell.Run """C:\Program Files\EmEditor\EmEditor.exe"" /i", 1, False
　　MsgBox "「" & Selection.Value & "」から始まる グループ について" & vbCrLf & _
　　　vbCrLf & "EmEditor での作業が終わったら OK してください。"

'//次の「スタート位置」を選択
　　Selection.End(xlDown).End(xlDown).Select

'//ワークシート最終行まできたら、
'//グループ ごとの繰り返し作業終了
　Loop Until Selection.Row = Rows.Count
　Set rng = Nothing
End Sub

--------------------------------

　なお、「スタート位置」の文字列の件、つまり後々の「ファイル名」の件ですが、R3 に入っている
=IF(K3="A","MB"&F3&"="&A3,IF(K3="","",FIXED(L3,0,TRUE)&"."&Q3))
という式の
"MB"&F3&"="&A3
の部分を弄れば何とかなりませんかね？

お礼

なお、EMEDITORで行っているマクロは次の通りです。
（VBでなく自動記録で作成したものです）
------------------------------
EmEditoマクロ（貼り付け、空白行削除、１行目
------------------------
●EmEditor起動（新規作成）手動
------------------------
※クリップボードからの貼り付け→カーソルを先頭行に→
置き換えメニューから「空白行」を「空欄ツメ」に置き換え→カーソルを先頭文字から10文字移動→
そこからうしろをエンドキーでハイライトさせる。
document.selection.Paste(eeCopyUnicode);
document.selection.StartOfDocument(false);
document.selection.Replace("^$\\n","",eeFindNext | eeFindReplaceEscSeq | eeReplaceAll | eeFindReplaceOnlyWord | eeFindReplaceRegExp);
document.selection.CharRight(false,1);
document.selection.CharRight(false,1);
document.selection.CharRight(false,1);
document.selection.CharRight(false,1);
document.selection.CharRight(false,1);
document.selection.CharRight(false,1);
document.selection.CharRight(false,1);
document.selection.CharRight(false,1);
document.selection.CharRight(false,1);
document.selection.CharRight(false,1);
document.selection.EndOfLine(true,eeLineView);
------------------------------

●ここで消去部分がハイライトされているので追記文字を書き込む。（手動）
------------------------------
１行目の先頭文字～最後文字までを選択クリップボードへ
→保存メニューの呼び出し
document.selection.StartOfLine(false,eeLineView);
document.selection.EndOfLine(true,eeLineView);
document.selection.Copy(eeCopyUnicode);
document.ReadOnly=false;
editor.ExecuteCommandByID(4100);
-------------------
以下手動
●保存メニューのファイル名がハイライトされているので
クリップボードからファイル名を貼り付け、エンター（保存）
-------------------
このうち最初のマクロはデータ貼り付けと空白行の削除の部分は今回エクセルで取り込まれましたので
割愛することにしています。