ログデーターの並び替え

質問

ログデーターの並び替え

5月1日<>30<>http://com/<>mail@mail
5月5日<>12<>http://com/<>mail@mail
5月7日<>25<>http://com/<>mail@mail
5月10日<>50<>http://com/<>mail@mail
5月23日<>14<>http://com/<>mail@mail

上記のログデータは以下の形式で保存されています。
$date<>$no<>$url<>$mail

このログの$noの部分で数値の小さい順、または大きい順に並び替えしたいのですが、
どのようにすればいいのでしょうか？

open(IN, "< $logfile");
my $list = <IN>;
while(<IN>){
my ($date,$no,$url,$mail) = split(/<>/);
if(条件){処理}
push(@data, "$_");
}
close(IN);

#ここで関数 sort を使って並び替えするのだと思うのですが、実際どのようにすればいいかわかりません。

open(OUT,">$logfile");
print OUT $list;
print OUT @data;
close(OUT);

perlは簡単な改造程度しかできなくて、ここのみなさんのように専門的な知識を持っていないので、どうしてもこの並び替えがわからずに困り果てております。お手数ですが、よろしくお願いいたします。

回答No.2

kumoz · ベストアンサー

No が重複する場合は、ハッシュの配列などを使い複数格納する必要があります。
前回のコードを修正したので、試してみてください。

open(IN, "< $logfile") or die "$!";
my $list = <IN>; # ヘッダ行がある？
my %data;

while (<IN>) {
my ($date, $no, $url, $mail) = split(/<>/);
push @{$data{$no}}, $_;
}
close(IN);

# $html_data をハッシュに追加
my ($date, $no) = split /<>/, $html_data;
push @{$data{$no}}, $html_data;

open(OUT,">$logfile") or die "$!";
print OUT $list;
print OUT @{$data{$_}} foreach sort { $a <=> $b } keys %data; # 降順 { $b <=> $a }
close(OUT);

補足に書かれているコードで並び替えを行う場合は、次のようにするとうまく行くかも知れません。

> ...
> if($content=~/<!--mail\/\/-->(.+)<!--mail_end\/\/-->/){$html_data.=$1 . "\n";}
> }
> push(@data, "$html_data");
> #新たにデーターが追加された@dataの並び順を変更して、以下ログに書き込みを行いたいと思っています。

@data = map { $_->[1] } sort { $a->[0] <=> $b->[0] } map { [(split(/<>/,$_))[1], $_] } @data;

> open(OUT,">$logfile");
> ...

お礼

ありがとうございます。

おかげさまで並び順の変更ができました。恥ずかしながら、今の自分の知識では、教えていただいたコードを理解できないのですが、今後の為にも理解出来るように精進したいと思います。
自分では到底実装不可能だった機能拡張だったので、本当に助かりました。感謝感激です。

回答No.1

kumoz

No に重複がなければ、No を配列の添字かハッシュのキーに割り当てる方法があります。
以下はハッシュを用いた一例です。

open(IN, "< $logfile") or die "$!";
my $list = <IN>; # ヘッダ行がある？
my %data;

while (<IN>) {
my ($data, $no, $url, $mail) = split(/<>/);
$data{$no} = $_;
}
close(IN);

open(OUT,">$logfile") or die "$!";
print OUT $list;
print OUT $data{$_} foreach sort { $a <=> $b } keys %data; # 降順 { $b <=> $a }
close(OUT);

お礼

追記。
補足で提示したソースの処理の順番は、多分、自分の知識では変えようがないように思います。

$logfileを読み込んでから、処理の部分でログの内容と追加内容が重複していないかチェックを行い、
重複していなければ、foreachで複数データーが$html_dataに格納されるようになっています。

補足

大変勉強になりました。ありがとうございます。

$noの数値は重複することがあるのですが、重複した行の並び順は特に指定する必要はありません。ただ、重複した行は上書きされてしまったようです。
それと、以下のソースに適用してみようとして試行錯誤してみましたが、何度やってもうまくいきませんでした。かなり複雑なソースのログの並び順を変更する必要があるため、必要な情報をうまく提示できなくて申し訳ございません。

use LWP::Simple;
my $content = get($html);

open(IN, "< $logfile");
my $list = <IN>;
while(<IN>){
my ($date,$no,$url,$mail) = split(/<>/);
push(@data, "$_");
}
close(IN);

if(条件){
if($content=~/<!--data\/\/-->(.+)<!--data_end\/\/-->/){$html_data.=$1 . "<>";}
if($content=~/<!--no\/\/-->(.+)<!--no_end\/\/-->/){$html_data.=$1 . "<>";}
if($content=~/<!--url\/\/-->(.+)<!--url_end\/\/-->/){$html_data.=$1 . "<>";}
if($content=~/<!--mail\/\/-->(.+)<!--mail_end\/\/-->/){$html_data.=$1 . "\n";}
}
push(@data, "$html_data");
#新たにデーターが追加された@dataの並び順を変更して、以下ログに書き込みを行いたいと思っています。
open(OUT,">$logfile");
print OUT $list;
print OUT @data;
close(OUT);