VBAの時間設定について教えてください

質問

質問1：
VBAで、ある一定の時間だけ指定したマクロが実行されることは出来ますか？
(例えば毎日16時30分～21時だけ"マクロA"が実行されるというような）
ただ、16時30分にエクセルが開いているとは限らないので、もし開始される時間に開いてない場合でも、指定した時間内に1度でも開けば必ず実行されるのでしょうか？
マクロAには
Sub マクロA()
If sheets("1").Range("A1").Value <>"" Then
msgbox"このシートは使えません"
Else
End If
End sub
という命令を作っています。

質問2：
SUB()
EndSub　で
Private Sub Worksheet_SelectionChange(ByVal 　　　　　　　　　　Target As Range
を開くことは出来ないのでしょか。
色々やってみたのですが出来ません。

すいません。初心者なので色々本を見ながら勉強していますが、なかなかうまく出来ません。
どなたか、教えてください。

回答No.5

merlionXX · ベストアンサー

> このシートモジュールを2つのシートで使いたいのですが、

merlionXXです。
使いたいシートのシートモジュールにそれぞれ記述してください。

> もしセルA2の日付が今日であれば、作動する。

日付のセルA2は2つのシートの、それぞれにあるのですね？
A2の日付が本日だった場合のみ、指定時間帯にA1セルに入力があったらメッセージをだすんですね？

以下のような記述となります。

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Address <> "$A$1" Then Exit Sub 'A1セル以外なら作動せず
If Date <> Range("A2").Value Then Exit Sub 'A2セルが本日以外なら作動せず
tm = Time() '現在時間を取得
If tm < TimeValue("16:30:00") Then Exit Sub '16:30前なら作動せず
If tm > TimeValue("21:00:00") Then Exit Sub '21:00を過ぎたら作動せず
If Target.Value <> "" Then '何か入力があったら作動
MsgBox "この時間帯にこのシートは使えません！", vbCritical, "Σ（￣ロ￣lll) " '警告
End If
End Sub

もしかして、警告が出た場合、A1への入力を無効にして元通りにしたいのなら、上記ではなく以下のようにします。

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Address <> "$A$1" Then Exit Sub 'A1セル以外なら作動せず
If Date <> Range("A2").Value Then Exit Sub 'A2セルが本日日付以外なら作動せず
tm = Time() '現在時間を取得
If tm < TimeValue("16:30:00") Then Exit Sub '16:30前なら作動せず
If tm > TimeValue("21:00:00") Then Exit Sub '21:00を過ぎたら作動せず
If Target.Value <> "" Then '何か入力があったら以下を作動
MsgBox "この時間帯にこのシートは使えません！", vbCritical, "Σ（￣ロ￣lll) " '警告
With Application
.EnableEvents = False 'イベントを無効に
.Undo '元通りに
.EnableEvents = True 'イベントを有効に
End With
End If
End Sub

お礼

本当にありがとうございました。
とても勉強になりました。

回答No.4

merlionXX

No3 merlionXXです。

> それを『もしA1に何か入力されればメッセージが表示される』という命令にしたいと考えてます。
> Private Sub Worksheet_Activate()にすればそれが出来るのですが、標準モジュールではうまくいきません。

ますますわかりません。
何か入力されたら自動実行されるマクロを組みたいのなら標準モジュールの通常のマクロではだめです。
シートモジュールでイベントを拾うしかありません。
そのイベントも
お書きになったPrivate Sub Worksheet_Activateではなく、、
Private Sub Worksheet_SelectionChangeでもなく、
Private Sub Worksheet_Change　です。
そして、そのマクロ指定時間内にしか働かせたくないなら、
標準モジュールのマクロA（）も、先ほどの予約（）も消去し、該当するシートのシートモジュールに以下のように記述してみてください。

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Address <> "$A$1" Then Exit Sub 'A1セル以外なら作動せず
tm = Time() '現在時間を取得
If tm < TimeValue("15:30:00") Then Exit Sub '15:30前なら作動せず
If tm > TimeValue("21:00:00") Then Exit Sub '21:00を過ぎたら作動せず
If Target.Value <> "" Then '何か入力があったら
MsgBox "この時間帯にこのシートは使えません！", vbCritical, "Σ（￣ロ￣lll) " '警告
End If
End Sub

お礼

ありがとうございます！！
もうひとつ質問いいでしょうか。
このシートモジュールを2つのシートで使いたいのですが、
もしセルA2の日付が今日であれば、作動する。
それ以外は作動しない。
これを先程教えて頂いたモジュールを応用して作れますか？

回答No.3

merlionXX

Sub マクロA() は標準モジュールにあるんですよね？
同じ標準モジュールに

Sub 予約()
Application.OnTime TimeValue("16:30:00"), "マクロA"
End Sub

を記述して、一旦このマクロ Sub 予約() を実行してください。
これで、指定時間の16:30に マクロA() が走ります。

あとは、Thisworkbookモジュールに

Private Sub Workbook_Open()
If Time() < TimeValue("16:30:00") Then
Call 予約
ElseIf Time() <= TimeValue("21:00:00") Then
Call マクロA
End If
End Sub

を記述してください。
これで、指定時間の16:30前にひらかれれば、Sub 予約()　を作動させ、16:30～21:00までの間に開かれると、即　マクロA() が作動します。
(テストしてませんが・・・)

質問2は、シートのセル選択で作動するマクロを、いったい何をしたいのか意味不明です。

補足

質問2ですが、質問1にある『マクロA』は『もしA1に値があればメッセージが表示される』という命令にしてますが、
それを『もしA1に何か入力されればメッセージが表示される』という命令にしたいと考えてます。
Private Sub Worksheet_Activate()にすればそれが出来るのですが、標準モジュールではうまくいきません。

質問がへたですいません・・・・

回答No.2

n-jun

１）

実行した際の時間を拾って判断するとか？

Sub try()
Dim i

i = TimeValue(Now())

If i < "16:30:00" Or i > "21:00:00" Then Exit Sub

' ～やりたい処理～
End Sub

違うかな？

回答No.1

A88No8

こんにちは
　Excelでは、Auto_open手続きで起動したときにマクロ実行する手続きがあります（セキュリティで止まらないように設定が必要）。
excel.exe パス名\ファイル名.xls

　指定時刻にExcelを起動するには、ＯＳのタスク（システム ツール←デフラグとかがあるところ）を使うのが普通です。

　Excelで作業しているときに自動実行タスクと衝突しないようにね！