Excel VBA 他のシートに演算結果を入れたい

質問

例えば、A～Dというシートのいずれかのo1セルに数値を入力すると、演算結果がp1に入る場合。

A～Dのどのシートでもo1に入力したら、Z!p1にp1の値を放り込みたいのです。
で、以下のようなコードを書いたのですが、上手くいきません。
因みに、セルの移動方向はオプションで「右方向」に設定してあります。

※結果としてセルの移動を認識していないのか、まったく無反応です。
※Range("Z!$P$1") =… の行にブレークポイントを設定しても、引っかかりません。

何が悪いのかお教え頂ければ幸甚です。
>違うシートには代入できない… ってことでしょうか?

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

If Target.Address = "$P$1" Then
Range("Z!$P$1") = Range("$P$1")
End If
End Sub

※なお、出典元のSubは以下の様なもので、正常に動作していました。

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

If Target.Address = "$A$1" Then
Range("B1") = Range("B1")+1
End If
End Sub

回答No.5

WindFaller · ベストアンサー

#1の回答者です。

>Target.Address = "$O$1"→Target.Address = "$P$1"　とすると
>今度はp1から抜けないと転送できませんでした。
あくまでも、O1に入力したら、の条件ですが、

前：Worksheets("Z").Range("P1").Value = Target.Value
　　　　　↓
Worksheets("Z").Range("P1").Value = Range("P1").Value
と変えればよいでしょう。

お礼

返答が遅くなりました。

午後から色々やってみたのですが…
あっ、本来の質問の件はクリアになりました。皆さん有難うございました。

ただ動作が不安定…と言うか、起動時は正常なんですが、"P1"を"Q1"に変更したりすると反応しなくなります。

この件はもう少し検証した後、別スレッドで質問します。　色々有難うございました。

回答No.4

tom04

No.3です。

間違いがありました。

＞ 今のSheet名!P1
の部分は
＞=今のシート名!P1
です。

「=」を入れないと数式になりません。m（_ _）m

回答No.3

tom04

こんにちは！

＞Range("Z!$P$1") = Range("$P$1")
の行を
＞ Worksheets("Z").Range("P1") = Range（"P1")
とか
＞Worksheets("Z").Range("P1").Formula = "今のSheet名!P1"
（「今のSheet名」はコード記載しているシート名です。）

ではどうでしょうか？m（_ _）m

お礼

回答有難うございました。
残念ながら上手くいきませんでした(-_-;)

補足

WindFallerさん,keithinさん,tom04さん　いろいろアドバイス有難う御座いました。

ひとつ気になる事があるのですが…
動作を確認するためにブレークポイントを設定すると、その後「継続」(F5)を押しても、ちゃんと動いていない様なのです。

ブックを閉じ再度開くと基本的に1回目は良いのですが、連続して作動しません。
なぜなんでしょうかねぇ(>_<)

回答No.2

keithin

こんにちは。
マクロにおける「シート名！セル番地」の指定の方法が全く間違っています。
また，自動起動マクロについても不適切な使い方です。

方法１：
シートＡのシート名タブを右クリックしてコードの表示を選ぶ
今記入しているマクロを全て綺麗に削除し，改めて下記をコピー貼り付ける

private sub Worksheet_Change(byval Target as excel.range)
　if application.intersect(target, range("O1")) is nothing then exit sub
　worksheets("Z").range("P1").value = range("P1").value
end sub

同様に，シートＢ，Ｃ，Ｄそれぞれのシートモジュールにも，同じマクロを記入しておく

方法２：
方法１で記入したシートモジュールのマクロは全て綺麗に消去する
ＶＢＥ画面でプロジェクトエクスプローラを確認し，当該ブックのVBAProjectに含まれているThisWorkbookシートをＷクリックして開く
現れたシートに下記をコピー貼り付ける

private sub Workbook_SheetChange(byval Sh as object, byval Target as range)
　if sh.name = "A" or sh.name = "B" or sh.name = "C" or sh.name = "D" then
　if not application.intersect(target, sh.range("O1")) is nothing then
　　worksheets("Z").range("P1").value = sh.range("P1").value
　end if
　end if
end sub

特に，シート，セルの指定方法などはマクロの基本中の基本なので，あまり独学だけでなく，簡単な参考書の最初のページだけでも勉強して頂いた方が良いでしょう。

お礼

早速のご回答ありがとうございました。
出来ました(*^^)v
worksheets("Z")という表現があったんですね。

補足

worksheets(～～)の後dotに続けて記述できるものはどんなものがあるのでしょう?
参考書を見てもその辺が曖昧でよく理解していません。

回答No.1

WindFaller

こんにちは。

ThisWorkbook モジュールに貼り付けてください。

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
　If Sh.Name Like "[ABCD]" Then 'A-D
　　If Target.Address = "$O$1" Then
　　　Application.EnableEvents = False
　　　Worksheets("Z").Range("P1").Value = Target.Value
　　　Application.EnableEvents = True
　　End If
　End If
End Sub

お礼

早速のご回答ありがとうございました。
これですと、o1からカーソルが移動した時にo1を転送してしまいました。

Target.Address = "$O$1"→Target.Address = "$P$1"　とすると
今度はp1から抜けないと転送できませんでした。