UTF-8のデータを複数開いて編集したい

質問

皆様のお力をお貸しください
基本がわかってないために所々おかしなところがあるかも知れませんが宜しくお願いします。
UTF-8で書かれたxmlデータをエクセルで開いて編集して保存したいのですがうまくいきません。

Sub test1()
Dim xmlFileName As Variant
Dim F_Filter As String
Dim i As Integer
F_Filter = "データ,*.txt"
xmlFileName = Application.GetOpenFilename(filefilter:=F_Filter, MultiSelect:=True, Title:="ファイル選択")
If IsArray(xmlFileName) Then
For i = 1 To UBound(xmlFileName)
Workbooks.OpenText Filename:=xmlFileName(i), _
Origin:=932, StartRow:=1, DataType:=xlDelimited, TextQualifier _
:=xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=True, Semicolon:= _
False, Comma:=False, Space:=False, Other:=False, FieldInfo:=Array(1, 1), _
TrailingMinusNumbers:=True
MsgBox xmlFileName(i)
ActiveWorkbook.Close
Next
End If
End Sub

Origin:=932は
Origin:=-535
だと思ってください。(家だとなぜかエラーのため)
一つはこんな感じです。
これだと連続編集できるのですが拡張子がxmlだとスクリプトエラー
となってしまうため
まず拡張子を手で.txtに変えています。

二つ目は
Sub OpenFile()
Dim xmlFileName As Variant
Dim F_Filter As String
Dim NewName As String
F_Filter = "データ,*.xml"
xmlFileName = Application.GetOpenFilename(filefilter:=F_Filter, MultiSelect:=False, Title:="ファイル選択")
If xmlFileName = False Then
MsgBox "キャンセルしました"
Else
NewName = Left(xmlFileName, InStrRev(xmlFileName, ".", -1, vbTextCompare)) & "txt"
Name xmlFileName As NewName
Workbooks.OpenText Filename:=NewName, _
Origin:=932, StartRow:=1, DataType:=xlDelimited, TextQualifier _
:=xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=True, Semicolon:= _
False, Comma:=False, Space:=False, Other:=False, FieldInfo:=Array(1, 1), _
TrailingMinusNumbers:=True
MsgBox xmlFileName
ActiveWorkbook.Close
Name NewName As xmlFileName
End If
End Sub
これだと拡張子を変更してくれるのですが連続編集できません。
拡張子を自動で変更しつつ連続編集できないものでしょうか。
というのも自作なのですがすべてつぎはぎでできているためうまくできないのです。どうぞ宜しくお願いします。

あわせて編集したあとUTF-8で保存したいのですがこちらのコード
もわかりましたら宜しくお願いします。

回答No.6

Wendy02

補足：空のシートを一つ使います。また、今回の場合は、保存の際には、ファイル名o.xml という名称になります。上書きはしないようにしました。

回答No.5

Wendy02

こんにちは。

>結果的に取り込むとメモリ不足と表示されて取り込めませんでした。
>2万行程度で数メガほどのデータだからでしょう。減らせは動いてくれます。
>しかし名前の名など一部が文字化けしてしまいます。

最初の方が示したように、直接、ソースを扱うとなると、Office は向かないような気がします。StreamEditor(SE)や、Grep など、TextStream 系のツールほうが便利なような気がしますね。あえて、Excelを使うなら、Excel 2007 や Excel 2003 Professional で加工したほうが早いとは思いますが、今、手元にないので、こういうVBAのコードを作ってみました。

'標準モジュール
'-------------------------------------------

Sub TestUTF8xml()
　　Dim F_Filter As String
　　Dim xmlFileName　As Variant
　　Dim fn As Variant
　　Dim sText As String
　　Dim oADO As Object 'ADODB.Stream
　　Dim i As Long
　　Dim fn1 As String '出力ファイル名
　　F_Filter = "xmlファイル,*.xml"
　　xmlFileName = Application.GetOpenFilename( _
　　filefilter:=F_Filter, MultiSelect:=True, Title:="ファイル選択")
　　If IsArray(xmlFileName) = False Then
　　　　MsgBox "キャンセルしました"
　　　　Exit Sub
　　End If
　　Set oADO = CreateObject("ADODB.Stream")

　　For Each fn In xmlFileName
　　　　Cells.Clear
　　　　fn1 = Mid(fn, 1, InStrRev(fn, ".") - 1) & "o.xml" '出力ファイル
　　　　i = 1
　　　　With oADO
　　　　　　.Open
　　　　　　.Charset = "UTF-8"
　　　　　　.Type = 2 'adTypeText
　　　　　　.LoadFromFile fn
　　　　　　.Position = 0
　　　　　　Do While Not .EOS
　　　　　　　　Cells(i, 1).Value = .ReadText(adReadLine)
　　　　　　　　i = i + 1
　　　　　　Loop
　　　　　　.Close
　　　　　　'**************
　　　　　　'ここで加工するコードを入れる
　　　　　　'**************
　　　　　　.Charset = "UTF-8"
　　　　　　.Type = 2 'adTypeText
　　　　　　.Open
　　　　　　For i = 1 To Range("A65536").End(xlUp).Row
　　　　　　　　.WriteText Cells(i, 1).Value, adWriteLine
　　　　　　Next
　　　　　　.SaveToFile fn1, adSaveCreateOverWrite
　　　　　　.Close
　　　　End With

　　Next fn
　　Set oADO = Nothing
End Sub

回答No.4

Wendy02

こんにちは。

>勉強自体も3行マクロを始めたばかりですのでここまで言われると落ち込んでしまいます。

別に、ご質問者さんに対して直接言っているわけではありません。分からないからお聞きになっているのでしょうから、そういうことに、あまりナーバスに取らないでください。ただ、質問のコードは、ご自身の作られたものですか？もし、どこかで見つけたコードでしたら、それをおっしゃっていただいたほうがよいです。

こうしたらどうか、というアドバイスをしたのですが、それを受け付けないということになると、回答者側では困ってしまいます。

もし、VBAを勉強するなら、初歩から一歩一歩、段階的に学習することをお勧めします。一足飛びには、自分の思ったようには使えないのです。VBAは、一つの流れの中で覚えないと、なかなか、できるようになりません。

元のコードの直接の要望はに対しては、

xmlFileName = Application.GetOpenFilename(filefilter:=F_Filter, MultiSelect:=False, Title:="ファイル選択")　ここを、MultiSelect:=True　に換えて、xmlFileName が、配列になりますから、その配列変数を、ループで取り出せば可能です。

私がOpenステートメントで考えた方法は、以下のようにすることです。このレベルは初級の範囲ですが、もし、文字化けするなら、方法を変えなくてはならないのですが、この方法が気に入らなかったら、別の方のコメントをお待ちになったほうが良いかと思います。

xml は、Officeでは、高度な処理方法がありますが、Office 2003 では、Professional バージョンが必要になってしまいますし、Office 独特のフォーマットになってしまいます。

テキスト処理するなら、あまり、Office としての利点が得られません。エディタや専用ツールのほうがよいかもしれません。

以下は、マルチセレクトになっていますから、複数ファイルを選ぶことが可能です。また、途中でマクロを解除するとファイルを削除していますから、ファイルがなくなっています。最後までマクロを実行してください。ファイルを削除する代わりに、別名で保存してもよいです。

　'Kill fn
　nFname = Left$(fn, InStrRev(fn, ".") - 1) & "o.xml"　'加える
　'nFname = fn　'必要に応じて、ファイル名を変更する

'--------------------------------------

'標準モジュールのみ
'空のシートをひとつ用います。

Sub Test1()
　　Dim FName() As Variant
　　Dim nFname As String
　　Dim fn As Variant
　　Dim FNum As Integer
　　Dim TextLine As String
　　Dim i As Long
　　Dim c As Variant

　　i = 1
　　'新規のシートを作る
　　With ThisWorkbook
　　　.Worksheets.Add After:=.Worksheets(.Worksheets.Count)
　　End With
　　FName = Application.GetOpenFilename("xml ファイル(*.xml),*.xml", , , , True)

　　If FName(1) = "False" Then Exit Sub
　　For Each fn In FName

　　　　FNum = FreeFile()
　　　　Open fn For Input As #FNum
　　　　Do While Not EOF(FNum)
　　　　　　Line Input #FNum, TextLine
　　　　　　Cells(i, 1).Value = TextLine
　　　　　　i = i + 1
　　　　Loop
　　　　Close #FNum
　　　　Kill fn　'ファイル削除
　　　　'ここに処理を書く

　　　　MsgBox fn & "User処理中...."

　　　　nFname = fn　'必要に応じて、ファイル名を変更する

　　　　FNum = FreeFile()
　　　　Open nFname For Output As #FNum
　　　　For Each c In Range("A1", Range("A65536").End(xlUp))
　　　　　　Print #FNum, c.Text
　　　　Next c
　　　　Close #FNum
　　　　Cells.Clear
　　　　i = 1
　　Next
End Sub

お礼

ありがとうございます
コードは最初に書いてある通りつぎはぎです。
調べて書いてはF8で一行ずつ実行しては書き直すなどして書きました。
>こうしたらどうか、というアドバイスをしたのですが、それを受け付けないということになると、回答者側では困ってしまいます。
自分にとってはまだ記録の延長線上です。そのためにがっかりすることを書いたかもしれません。受け入れなかったのではなく意味がわからなかったのです。ごめんなさい

そしてコードを示してくれましてありがとうございます。
結果的に取り込むとメモリ不足と表示されて取り込めませんでした。
2万行程度で数メガほどのデータだからでしょう。減らせは動いてくれます。
しかし名前の名など一部が文字化けしてしまいます。

回答No.3

Wendy02

#2の回答者です。

もうしわけないけれども、今回の全体のコードの流れがしっくりしていないのです。

MsgBox の時で処理するのは分かりましたが、xmlを、勉強されているのでしょうか。あまり、VBAの勉強をされているようには思えないです。

もし、VBA自体を学ぶなら、もう少し、VBAの処理範囲というものを学ばれたほうがよいです。質問のOpenTextで処理すること自体は、記録マクロの延長ですが、それは、VBAでは、便宜的なもので、特別なものだと思います。通常、そのようなことはしません。

コードの内容は、OpenTextのテキスト・オープンで、拡張子をtxt にし、テキスト・コードをワークシート上で広げて行って、それを処理し、テキストで保存（書かれていないが）して、拡張子を変えるというものだと思います。スキルの低い人でないと、この質問そのものを答える人はいないように思います。わざわざ、ワークシートに表示する必要がないと思うのです。

そういうのは、テキストストリームの中で、処理すればよいのですから、以下のようにすればよいです。
Open filename For Input As #1 のように、オープンステートメントでインポートとして、
Open filename For Output As #1 で出力すればよいのです。

ここで、一行のテキストラインが得られますから、修正・置換程度なら、Repalce 関数を使えばよいです。一行書き加えるとなれば、面倒ですが、それも可能です。

お礼

>コードの内容は、OpenTextのテキスト・オープンで、拡張子をtxt にし、テキスト・コードをワークシート上で広げて行って、それを処理し、テキストで保存（書かれていないが）して、拡張子を変えるというものだと思います。スキルの低い人でないと、この質問そのものを答える人はいないように思います。わざわざ、ワークシートに表示する必要がないと思うのです。

そもそもこのコードはUTF-8で書かれたxmlをエクセルで開き編集処理をしたあとxmlに戻してUTF-8で保存したかったので書いたコードです。

そのままではエラーとなり開けず、テキストでは文字化けするためにこの形となっています。
そして保存が書かれていないのはそのまま保存してしまうとShift JISで保存してしまうためです。そもそもUTF-8にして保存する方法がわかりませんでした。

処理自体もこのマクロを含むブックに書かれたことをxmlデータに追加、変更、削除などをすることです。

book1
A 　　 B 　　　　　　 C 　　　 　　　　 D
追加　山田太郎　090-xxxx-xxxx 住所xxxxxxxx
～
削除　山田花子 090-xxxx-xxxx 住所XXXXXXXX
このようなシートがありこれによりxmlデータを編集していく処理です。

レベルが低いと感じておられるようですが私にとってはまだそれは当然だと思っています。

勉強自体も3行マクロを始めたばかりですのでここまで言われると落ち込んでしまいます。
今は自分のしたい事をできる様になるその過程です
初心者であることを逃げ口上には使いたくはないですが始めたばかりですのでコードは歪に見えるかもしれません。

回答No.2

Wendy02

こんばんは。

>自分のスキルアップのためにもエクセルである必要があると考えています。

コードからすると、xml の生のコードがそのままになっているような気がします。xml ファイルを開いて、拡張子を変更して　ActiveWorkbook.Close　しています。

それでいいなら、

Name テキストファイル名 As xmlファイル名

だけでよいのではありませんか？

もちろん、Excelでは、エディタではできない　高度なxml（Excel2003の場合は、Professional版) の編集が可能ですが、それは、別段、マクロで行う必要はありません。

お礼

ありがとうございます。
>コードからすると、xml の生のコードがそのままになっているような気がします。xml ファイルを開いて、拡張子を変更して　ActiveWorkbook.Close　しています

処理はここでは割愛して
MsgBox xmlFileName
としています。
しかし
'ここで処理内容を記載
としておけばよかったですね。
ここのコードでは.xmlをまず.txtに変更した後ブック名を表示して
閉じて.xmlに戻しています
ブック名の表示を簡易的に処理と見立てています。

回答No.1

t_nojiri

エクセルじゃないと駄目なんですかね？

UTF-8エンコード出来るテキストエディッタ探して編集した方が簡単そうな気がしますが。

http://www3.coara.or.jp/~tarariko/utf8.html

お礼

返信ありがとうございます。
誰から教えてもらっているというわけではありませんが今年から勉強を始めました。
自分のスキルアップのためにもエクセルである必要があると考えています。