excel2007 数値の種類をランク付けしたいのですが…m（_ _）m

質問

はじめまして
excel初心者で実はこまっております。
仮に下記のようなランクデータがあるとします。

商品の値段　ランク
１００　　　　　　１
１２０　　　　　　３
１３０　　　　　　５
１００　　　　　　１
１２０　　　　　　３
１５０　　　　　　６

これを
(1)何段階に分かれているのか？（整数の種類が何個あるのか？）
　　＝この場合は100と120と130と150の４つとなります。
(2)その階層内で何位にあたるのか？
　　＝仮に130円の商品であれば、その4階層に対して3番目となります。
を出したいのですが私には出来ません。
出来れば↓こんな風に作りたいのです。

商品の値段　ランク　整数の種類　整数の階層
１００　　　　　　１　　　　　４　　　　　　１
１２０　　　　　　３　　　　　４　　　　　　２
１３０　　　　　　５　　　　　４　　　　　　３
１００　　　　　　１　　　　　４　　　　　　１
１２０　　　　　　３　　　　　４　　　　　　２
１５０　　　　　　６　　　　　４　　　　　　４

商品比較をする際に値段の階層を調べその商品がどの位置にいるのかを調べる為にこのような方法をと思っております。
どなたか教えて頂ければ幸いです。
何卒宜しくお願い申し上げます　m(_ _)m

回答No.1

mt2008 · ベストアンサー

整数の種類は範囲をA2:A7とした場合
　=SUM(IF(FREQUENCY(A2:A7,A2:A7)>0,1))　で、でます。

整数の階層は、
D2に　=SUMPRODUCT(($A$2:$A$7<=A2)/COUNTIF($A$2:$A$7,$A$2:$A$7))
と、入れてD7までコピー

これでどうでしょう。

お礼

…素晴らしい^^;
ぴったりです。
本当にありがとうございます！確認遅れましたが、今後も宜しくご指導下さい。
助かりました！

あとでじっくり読解してみます…けど私では無理だろうなぁ。。。

回答No.2

noname#204879

失礼ながら、初心者は作業列を設けた方が理解しやすいかと。

　　　 A　　　　 B　　　　 C　　　　　 D　　　 E　　F
1　商品の値段　ランク　整数の種類　整数の階層　　 作業列
2　　　　 100　　　 1　　　　　 4　　　　　 1　　　　100
3　　　　 120　　　 3　　　　　 4　　　　　 2　　　　120
4　　　　 130　　　 5　　　　　 4　　　　　 3　　　　130
5　　　　 100　　　 1　　　　　 4　　　　　 1
6　　　　 120　　　 3　　　　　 4　　　　　 2
7　　　　 150　　　 6　　　　　 4　　　　　 4　　　　150

B2: =RANK(A2,A$2:A$7,1)
F2: =IF(COUNTIF(A$2:A2,A2)=1,A2,"")
C2: =COUNT(F$2:F$7)
D2: =RANK(A2,F$2:F$7,1)

お礼

たしかに作業列設けて一度やってみます。
自分で理解する事が大切＆今後にも繋げられそうです。
ありがとうございました！

上記の式も、まだ理解出来ない私です。。。がんばります。