文字列を指定して，別のファイルでその文字列が存在する行を出力する

質問

いつもお世話になっております．
環境はWindows XP Pro でActiveperlを用いてプログラムをしております．

この度，皆様にご意見をうかがいたいのは，「文字列を指定して，別のファイルでその文字列が存在する行を出力する」という内容です．

まず，以下のテキストファイルがあります．

data.txt
----------------------
A
BA
C
DA
E
FA
G

sansyo.txt
-----------------------------
B
D
F

-------------------------------
処理として，data.txtでsansyo.txtの行が "含まれる"行数を出力する
-------------------------------

output.txt
-------------------------------
2
4
6

ここで自分なりにプログラムを組んでみました．
-----------------------------------

open(FILE, "sansyo.txt");
open(FILE2,"data.txt");

@file = <FILE>;
close(FILE);
@file2 = <FILE2>;
close(FILE2);
foreach $line (@file) {
foreach $line2 (@file2) {
if ($line =~ $line2){
$hit = $.;
}
open(NEWFILE, " >> output.txt") or die "$!";
print NEWFILE $hit;
close(NEWFILE);
}
}

#ここまで

-------------------------------------
ですが，永久ループに入ってしまったようにファイルはできるのですが，
出力されてきません．

間違っている点をご指摘ください．

回答No.2

sakusaker7 · ベストアンサー

>どのようにしたら2つのファイルのうち，1つのファイルについて読み込んだ行数を出力できるのでしょうか．

スクリプトの先頭で一気読みをしなければ良いと思うのですが、
一気読みの必要性はあるのですか?

use strict;
use warnings;

use feature ':5.10';

open my $file2, '<', 'sansyo.txt' or die "can't open input $!";
chomp(my @subjects = <$file2>);
close $file2;

open my $newfile, '>>', 'output.txt' or die "can't open output $!";
open my $file, '<', 'data.txt' or die "can't open input $!";

while (my $line = <$file>) {
chomp $line;
foreach my $subject (@subjects) {
if ($line =~ $subject){
say {$newfile} $.;
}
}
}
close $file;
close $newfile;

output.txt の内容
2
4
6

お礼

ありがとうございました．無事解決することができました．foreachで2重ループをみたことがあったのでそれしか思いつきませんでした．

回答No.1

sakusaker7

とりあえず気がついたのは
@file = <FILE>;
close(FILE);
@file2 = <FILE2>;
close(FILE2);

chomp していないので改行コードがついたまま。

>if ($line =~ $line2){
右辺と左辺が逆。

>$hit = $.;
このループの時点で特殊変数 $. を参照しても期待する値はありません

open(NEWFILE, " >> output.txt") or die "$!";
print NEWFILE $hit;
close(NEWFILE);

ifの外にあるので、ループの度に出力している。

くらいですか。

お礼

ご回答ありがとうございました．

>$hit = $.;
>このループの時点で特殊変数 $. を参照しても期待する値はありません

この点以外解決できました．行数を使いたいのはdata.txtの方なのですが，
どのようにしたら2つのファイルのうち，1つのファイルについて読み込んだ行数を出力できるのでしょうか．