エクセル2000のセルの色の塗りつぶし設定方法

質問

マイクロソフトエクセル2000を利用しています。
ＶＢについては全く利用したことがないのですが、
とあるセルでＳＵＭをした値が0～9なら赤、10～19なら緑、20～29なら青のような設定をしたいと考えています。
「条件付き書式」で設定してみましたが、これでは3つまでしか設定できませんでした。
現在7通りの設定を必要としています。
これまでの質問も参照してみましたが、うまくいきませんでした。

おわかりになる方がいればよろしくお願いいたします。

回答No.2

fumufumu_2006

モジュールで自作関数を作る方法です。
モジュールがいやなら読み飛ばしてください。

ユーザ関数内でプロパティを変更できないので、情報を保存しておいて、Worksheet_Calculate()イベントで設定します。
標準モジュールと自作関数を使用するシート（例えばsheet1）のモジュールに以下をコピーします。

---標準モジュール ここから---
Public co As New Collection

'インテリアカラー情報保存
Function getInteriorColor(r As Range) As Variant
Dim c As Integer
Select Case r.Value
'以下に条件と背景色を記述
Case Is < 10: c = 5 '青
Case Is < 20: c = 4 '緑
Case Is < 30: c = 8 '水色
Case Is < 40: c = 3 '赤
Case Is < 50: c = 7 '紫
Case Is < 60: c = 6 '黄色
Case Is < 70: c = 2 '白
Case Else: c = 1 '黒
End Select
co.Add Array(r, c) '情報を保存
getInteriorColor = "" '戻り値が必要なので""を返す
End Function

'インテリアカラー情報設定（Worksheet_Calculateイベントで呼ぶ）
Function setInteriorColor()
Dim i As Integer
For i = 1 To co.Count
co.Item(1)(0).Interior.ColorIndex = co.Item(1)(1)
co.Remove 1
Next
End Function
---標準モジュール ここまで---

---自作関数を使用するsheetのモジュール ここから---
Private Sub Worksheet_Calculate()
setInteriorColor
End Sub
---自作関数を使用するsheetのモジュール ここまで---

以上でB1（実際はどこでもいい）に
=getInteriorcolor(A1)
とすると、A1の値（計算式でも良い）によってA1の背景色が変わります。

最初に「条件と背景色を記述」の部分を設定しておけば、普通の関数のように使えます。

[注意]
getInteriorcolorを使用するsheetに、忘れずにWorksheet_Calculate()イベントをコピーしてください。
複数のシートがある場合は、各シートに必要です。

お礼

早々のご回答ありがとうございます。

モジュールを操作する、という手もあるのですね。
残念ながら自身がコードの記述についてはからきしなので内容は殆ど理解できませんが、試行錯誤して利用させていただこうかと思います。

短文になってしまいましたが、ありがとうございました。