エクセル 検索 行 列

質問

いろいろやってみたのですが、どうしてもできず質問させていただきます。

入力する項目が２つあります（A,B）
Aには１～３、Bにはあ～おまでを入れます。
　　あ　い　う　え　お
１　10　11　12　13　14
２　20　21　22　23　24
３　31　32　33　34　35
今、A=２、B=う　と入力したとします。
このとき、Cというセルに「22」と表示させたいのですが、
どうすればよろしいのでしょうか。
Vlookupなどでは対応できないような気がするのですが・・・よろしくお願いします。

回答No.3

suekun · ベストアンサー

VLOOKUPで出来ますよ。

　　A　　B　　C　　D　　E　　F
1　　　　あ　 い　 う　 え　 お
2　　1　 10　 11　 12　 13　 14
3　　2　 20　 21　 22　 23　 24
4　　3　 31　 32　 33　 34　 35
5
6　　2　 う
7

=VLOOKUP(A6,A2:F4,MATCH(B6,A1:F1,0),0)

ちなみにエラー回避は設定していません。
参照形式も相対にしてますので、フィルコピーされるときは
範囲の変動に注意して下さい。

お礼

ありがとうございました。使わせていただきました。おかげで首がつながりそうです。

回答No.5

imogasi

OFFsET関数を使う例。
例データ
Ａ１　２
Ｂ１　え
Ａ２：Ｆ５
ー あ い う え お
1 10 11 12 13 14
2 20 21 22 23 24
3 31 32 33 34 35
式
=OFFSET($A$2,$A$1,MATCH($B$1,$B$2:$F$2,0))
結果
２３
ＩＮＤＥＸ、ＶＬＯＯＫＵＰ、ＯＦＦＳＥＴはＭＡＴＣＨを使って
同様なことができる場合がある。
ＶＬＯＯＫＵＰなら
=VLOOKUP($A$1,$A$2:$F$5,MATCH($B$1,$B$2:$F$2,0)+1,FALSE)

お礼

offsetですか・・初めて知りました。今後勉強してみたいと思います。

回答No.4

may0430

VLOOKUPを使うと、

=VLOOKUP(Ａ,$A$2:$F$4,MATCH(Ｂ,$A$1:$F$1,0),FALSE)

お礼

ありがとうございました。使わせていただきました。助かりました。

回答No.2

shinchan_k

index関数とmatch関数を組み合わせるといけそうです。
=index(表示させたい数値の範囲,match(Aの値を入れるセル,1 2 3の範囲,0),match(Bの値を入れるセル,あいうの範囲,0))
のようにすればどうでしょうか

お礼

ありがとうございました。結局、Vlookupでできることを教えてもらえたので、indexは使用しませんでしたが、今後、覚えてみたいと思います。

回答No.1

himajin100000

左上をA1とする

B6に「1～3」を
D6に「あ～お」を入力するとすると

=INDEX($A$1:$F$4,MATCH($B$6,$A$2:$A$4,0)+1,MATCH($D$6,$B$1:$F$1,0)+1)

で求めることができる。使われている関数については自分で確認すること。

お礼

ありがとうございました。参考にしたいと思います。