weekday関数で月曜、水曜、金曜のみ閉店時間を変えて表示したい

質問

こんばんは
weekday関数を使い、月曜、水曜、金曜の終了時間を21時とし、これ以外の曜日を22時終了と表示させたいのですが、私の頭では以下の関数しか思い浮かびません
=IF(WEEKDAY($A3,2)=1,"21時終了","22時終了")

一つの関数で月曜、水曜、金曜のみ閉店時間を変えて表示するにはどの様にすればよろしでしょうか？

使っているのはエクセル2000です

よろしくお願いいたします

回答No.1

mshr1962 · ベストアンサー

=IF(OR(WEEKDAY($A3)=2,WEEKDAY($A3)=4,WEEKDAY($A3)=6),"21時終了","22時終了")
または
=IF(MOD(WEEKDAY($A3),2)=0,"21時終了","22時終了")
または
=IF(FIND(TEXT($A3,"aaa"),"月水金日火木土日")<4,"21時終了","22時終了")
または
=CHOOSE(WEEKDAY($A3),22,21,22,21,22,21,22)&"時終了"

お礼

mshr1962様
一番速い回答にもかかわらず
4つも回答していただき
誠にありがとうございました

おかげで問題も解決しました
本当にありがとうございました。

補足

mshr1962さん
回答ありがとうございます
再度、質問させてください
weekday関数で出たシリアル値を「２」で割り算すると言うことですが、「＝0」の意味はなんでしょうか?

回答者Ｎｏ．2の方は「＝0」無しでも同じ結果になります

よろしくお願いします

=IF(MOD(WEEKDAY($A3),2)=0,"21時終了","22時終了")にあります

回答No.5

BLUEPIXY

=IF(OR(WEEKDAY($A3,2)={1,3,5}),"21時終了","22時終了")

回答No.4

NCU

=21+MOD(WEEKDAY(A1),2)&"時終了"

汎用性度外視。

回答No.3

imogasi

2006/7/1 7 22時
2006/7/2 1 22時
2006/7/3 2 21時
2006/7/4 3 22時
2006/7/5 4 21時
2006/7/6 5 22時
2006/7/7 6 21時
B列は　=WEEKDAY(A1)
C1は　=IF((B1=2)+(B1=4)+(B1=6),"21時","22時")
という表現方法もあります。B,C列は１つにできますが、分けてます。
ーーー
G1:H7に
1 22時
2 21時
3 22時
4 21時
5 22時
6 21時
7 22時
E1に　=VLOOKUP(WEEKDAY(A1),$G$1:$H$7,2,FALSE)
なんていうのもあります。どうにも設定できる、自由度が増します。

回答No.2

noname#204879

=IF(MOD(WEEKDAY(A3),2),"22時終了","21時終了")