ＷＭＩによるネットワーク接続の有効無効化方法

質問

ＷＭＩによるネットワーク接続の有効無効化方法がわからないため
下記VBScriptの「Array("192.168.9.999")」の部分のＩＰアドレスを
有効化のVBScriptには割り当てているアドレスを
無効化のVBScriptにはでたらめなアドレスを設定し
有効無効化らしきことを実現させています。
実際にはネットワーク接続は有効のままでネットワークアドレスが
ちがうために接続できないだけです。
どなたか有効無効化(IPEnabledをTRUEorFALSEにするMethod)方法を
教えていただけないでしょうか？

strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colNetAdapters = objWMIService.ExecQuery _
("Select * from Win32_NetworkAdapterConfiguration where IPEnabled=TRUE")
strIPAddress = Array("192.168.9.999")
strSubnetMask = Array("255.255.255.0")
For Each objNetAdapter in colNetAdapters
errEnable = objNetAdapter.EnableStatic(strIPAddress, strSubnetMask)
If errEnable = 0 Then
WScript.Echo "The IP address has been changed."
Else
WScript.Echo "The IP address could not be changed."
End If
Next

回答No.1

notnot · ベストアンサー

WMIは使いませんが、ネットワーク接続をオフオンするVBScriptです。

Const ssfCONTROLS = 3
Const sConPaneName = "ネットワークとダイヤルアップ接続"
Const sConnectionName = "ローカル エリア接続"
Const sDisableVerb = "無効にする(&B)"
Const sEnableVerb = "有効にする(&A)"

set shellApp = createobject("shell.application")
set oControlPanel = shellApp.Namespace(ssfCONTROLS)
set oNetConnections = nothing
for each folderitem in oControlPanel.items
if folderitem.name = sConPaneName then
set oNetConnections = folderitem.getfolder: exit for
end if
next
if oNetConnections is nothing then
wscript.quit
end if
set oLanConnection = nothing
for each folderitem in oNetConnections.items
if lcase(folderitem.name) = lcase(sConnectionName) then
set oLanConnection = folderitem: exit for
end if
next
if oLanConnection is nothing then
wscript.quit
end if

for each verb in oLanConnection.verbs
if verb.name = sDisableVerb then
verb.DoIt
WScript.Sleep 2000
end if
next
for each verb in oLanConnection.verbs
if verb.name = sEnableVerb then
verb.DoIt
WScript.Sleep 3000
end if
next

お礼

回答ありがとうございます。
試してみます。

補足

「ネットワークとダイヤルアップ接続」の部分を
「ネットワーク接続」に変えて実行するとできました。
ありがとうございました。