アップロードができない

質問

ローカルHDDにあるファイルをネット上にアップロードしたいため下記コードを作成したのですがコピーする事ができませんでした。
PC環境：WindowsXP ProSP1、VB6.0SP6です。
どうすればアップーロードできるのでしょうか？
どなたか御願い致します。
/////////////////////////////////////////////////////
Private InetState As Boolean
Private InetError As String

Private Sub Command1_Click()
Inet.RequestTimeout = 2
Inet.UserName = "*"
Inet.Password = "***"
Inet.Execute "*", "PUT c:\11.txt 11.txt"
Do
DoEvents
Loop Until InetState
If InetError <> "" Then MsgBox InetError
InetState = False
Inet.Execute "*", "CLOSE"
Do
DoEvents
Loop Until InetState
InetState = False
Inet.Execute "*", "QUIT"
Do
DoEvents
Loop Until InetState
Inet.Cancel
Unload Me
End Sub
///////////////////////////////////////////////

回答No.2

1050 円（@1050YEN） · ベストアンサー

たぶんここを見たのかな？
http://homepage2.nifty.com/sak/w_sak3/doc/sysbrd/vb_t10.htm

この方法はExecuteした後、ステータスの変化をその都度取得する非同期アップロードの方法ですね。

参考URLのは、取得も兼ねて書いてあるようなので、チコッとばかり変更して張っておきます。

Option Explicit

Private InetState As Boolean
Private InetError As String
Private InetData As String

Private Sub Command1_Click()

　　Call PutFile( _
　　　　"ftp://お台場.混む", _
　　　　"菊○", _
　　　　"職場復活の呪文", _
　　　　"c:\11.txt", _
　　　　"/public_html/11.txt" _
　　)
End Sub

Private Function PutFile( _
　　　　ByVal p_strURL As String, _
　　　　ByVal p_strUID As String, _
　　　　ByVal p_strPWD As String, _
　　　　ByVal p_strFILE_Local As String, _
　　　　ByVal p_strFILE_Server As String, _
　　　　Optional ByVal p_intTimeOut As Integer = 2 _
) As Boolean
On Error GoTo PGMERR

　　'接続
　　Inet.URL = p_strURL
　　Inet.RequestTimeout = p_intTimeOut
　　Inet.UserName = p_strUID
　　Inet.Password = p_strPWD
　　Inet.Protocol = icFTP

　　'アップロード開始
　　Inet.Execute , "PUT " & p_strFILE_Local & " " & p_strFILE_Server

　　'ステータスの状態が変わるまで待機
　　Do
　　　DoEvents
　　Loop Until InetState

　　If InetError <> "" Then
　　　　MsgBox InetError
　　End If

　　'接続を閉じる処理
　　Inet.Execute , "CLOSE"
　　Do
　　　DoEvents
　　Loop Until InetState
　　'接続終了処理
　　Inet.Execute , "QUIT"
　　Do
　　　　DoEvents
　　Loop Until InetState

　　PutFile = True

PGMEND:
　　Exit Function
PGMERR:
　　Call MsgBox("エラー番号:" & Err.Number & vbCrLf & vbCrLf & Err.Description, vbCritical)
　　GoTo PGMEND
End Function

Private Sub Inet_StateChanged(ByVal State As Integer)
　Dim w As String

　Select Case State
　　Case icError
　　　InetError = Inet.ResponseCode & " - " & Inet.ResponseInfo
　　　InetState = True
　　Case icResponseCompleted
　　　Do
　　　　w = Inet.GetChunk(1024, icString)
　　　　DoEvents
　　　　If Len(w) = 0 Then
　　　　　InetError = ""
　　　　　InetState = True
　　　　Else
　　　　　InetData = InetData & w
　　　　　InetState = False
　　　　End If
　　　Loop Until InetState
　 End Select
End Sub

お礼

わかりました。ありがとうございますした。

補足

早速試してた所アップロードされました。有難うございます。
Inet.Execute , "PUT " & p_strFILE_Local & " " & p_strFILE_Server
を変えただけで、なぜアップロードできたのか理解できません。
Inet.Execute
"ftp://お台場.混む", "PUT c:\11.txt /public_html/11.txt"
でも一緒だと思うのですが・・・

回答No.1

1050 円（@1050YEN）

http://www.mitene.or.jp/~sugisita/vb6_net.html
WININET
FTPクライアント (WININET使用)

を参考にしてはいかがですか？

補足

internetTransferコントロールを使用してアップロードできないかのかと探しています。