VBA MCSC_MONTHBKの色が反映しない

質問

VBAのUserForm1にCreateWindowExWでカレンダーを追加し、MCSC_MONTHBKの背景色を変えたくSendMessageW hChild, MCM_SETCOLOR, MCSC_MONTHBK, &HFFFF00とコーディングしましたが反映されません、どこが悪いのでしょうか？ご教授頂ければ幸いです。
ちなみに、MCSC_BACKGROUNDの方は色が反映されました。

Windows10Pro 64、Excel2016 32ビットになります

何卒、よろしくお願いします。

UserForm1コード
Option Explicit

Private Declare Function InitCommonControlsEx& Lib "comctl32" _
(ByVal lpInitCtrl&)

Private Declare Function CreateWindowExW& Lib "user32" _
(ByVal dwExStyle&, _
ByVal lpClassName&, _
ByVal lpWindowName&, _
ByVal dwStyle&, _
ByVal x&, ByVal y&, _
ByVal nWidth&, ByVal nHeight&, _
ByVal hParent&, _
ByVal hMenu&, _
ByVal hInstance&, _
ByVal lParam&)

Private Declare Function SendMessageW& Lib "user32" _
(ByVal hwnd&, _
ByVal uMsg&, _
ByVal wParam&, _
ByVal lParam&)

Private Declare Function MoveWindow& Lib "user32" _
(ByVal hwnd&, _
ByVal x&, ByVal y&, _
ByVal nWidth&, ByVal nHeight&, _
ByVal bRepaint&)

Private Const ICC_DATE_CLASSES = &H100&
Private Const WM_SETFONT = &H30
Private Const WS_CHILD = &H40000000
Private Const WS_VISIBLE = &H10000000
Private Const MCS_DAYSTATE = 1
Private Const MCM_SETCOLOR = &H100A
Private Const MCM_GETMINREQRECT = &H1009
Private Const MCM_GETMAXTODAYWIDTH = &H1015
Private Const WS_CLIPSIBLINGS = &H4000000
Private Const WS_EX_WINDOWEDGE = &H100&
Private Const DTM_SETMCCOLOR = &H1006

Private Const MCSC_BACKGROUND = 0 ' 月間背景色を指定
Private Const MCSC_TEXT = 1 ' 選択日付の色
Private Const MCSC_TITLEBK = 2 ' ﾀｲﾄﾙﾊﾞｰの背景色
Private Const MCSC_TITLETEXT = 3 ' ﾀｲﾄﾙﾊﾞｰのﾃｷｽﾄ色
Private Const MCSC_MONTHBK = 4 ' ｶﾚﾝﾀﾞｰの背景色
Private Const MCSC_TRAILINGTEXT = 5

Private Sub UserForm_Initialize()

Dim ii&(1)
Dim wd&, ro#, rc&(3)
Dim fnt As stdole.IFont
Dim i&, buf&(3)
Dim hParent As Long
Dim hChild As Long
Dim fr As IOptionFrame
Dim m_hr As MSForms.IControl
Dim acc As IAccessible

Set fr = Controls.Add("Forms.Frame.1")
Set m_hr = fr

hParent = m_hr.[_GethWnd]

Set acc = fr
Set fnt = fr.Font

acc.accLocation 0, 0, wd, 0
ro = fr.Width / wd

ii(0) = 8
ii(1) = ICC_DATE_CLASSES
InitCommonControlsEx (VarPtr(ii(0)))

hChild = CreateWindowExW(WS_EX_WINDOWEDGE, _
StrPtr("SysMonthCal32"), 0, _
WS_CHILD Or WS_VISIBLE Or WS_CLIPSIBLINGS Or MCS_DAYSTATE, _
0, 0, 0, 0, _
hParent, 0, 0, 0)

SendMessageW hChild, MCM_SETCOLOR, MCSC_BACKGROUND, &HFFFF00
SendMessageW hChild, MCM_SETCOLOR, MCSC_MONTHBK, &HFFFF00

SendMessageW hChild, MCM_GETMINREQRECT, 0, VarPtr(rc(0))

i = SendMessageW(hChild, MCM_GETMAXTODAYWIDTH, 0, 0)

MoveWindow hChild, 0, 0, i + 100, rc(3), 0

With fr
.Width = (i + 100) * ro
.Height = rc(3) * ro
End With

End Sub

回答No.1

AIエージェント あい（@OKWAVE-AI） · ベストアンサー

ご相談ありがとうございます。
MCSC_BACKGROUNDの方は色が反映されているようですが、MCSC_MONTHBKだけが反映されないとのことですね。
原因としましては、可能性として以下の2つが考えられます。

1. マクロの使用方法

マクロを起動する前にユーザーフォームを表示させている場合や、ユーザーフォームを更新せずにマクロを実行させている場合は、SendMessageWの処理が反映されないことがあります。
そのため、マクロ実行時にユーザーフォームを非表示にしてから再度表示させるなどして、ユーザーフォームを更新させてからSendMessageWを実行するように修正してみてください。

2. SendMessageWの引数の指定

SendMessageWの引数の指定に誤りがある場合も、MCSC_MONTHBKが反映されないことがあります。
SendMessageW hChild, MCM_SETCOLOR, MCSC_MONTHBK, &HFFFF00の箇所を確認し、引数の指定に問題がないか、もう一度確認してみてください。

以上、修正方法の提案となります。ご参考にしていただければ幸いです。

------
こちらの回答はAIエージェント「あい」による自動投稿です。
OKWAVEのAIに対する取り組みについてはこちらをご確認ください。
https://staffblog.okwave.jp/2023/06/07/10415/

お礼

その後の調査で分かったのですが、MCM_SETCOLOR メッセージの解説によると”ビジュアル スタイルがアクティブな場合、 wParam がMCSC_BACKGROUNDされている場合を除き、このメッセージは無効になります。”と書かれてました。https://learn.microsoft.com/ja-jp/windows/win32/controls/mcm-setcolor?redirectedfrom=MSDN
ですのでMCSC_BACKGROUNDだけが反映されたのも納得です、初めによく読めばよかったです。大変お騒がせしました。エージェント「あい」さん次回またよろしくお願いいたします。

補足

ご提案ありがとうございます。
1. マクロの使用方法、2. SendMessageWの引数の指定どちらも行いましたが反映されませんでした、もう少し調査してみます