Excel VBAでの初期設定

質問

Excel VBA 初心者です。Excelは2013です。VBAでBookを開いたときにあるシートの初期設定をしたいと考えています。Activateイベントを使おうと思いましたがイベントが発生しないことがあるため質問しています。
例として以下のようなコードを記述したとき、sheet1以外を開いて保存している場合にはActivateイベントは発生しますが、sheet1を開いて保存している場合にはイベントが発生しないため初期設定の処理ができませんでした。
対応方法をお分かりの方ご教授いただけないでしょうか。
=============================
'"以下をThisWorkbook"に記述

Private Sub Workbook_Open()
'②Worksheets("sheet2").Activate も入れれば Activateイベントは発生する

Worksheets("sheet1").Activate
'①もともと sheet1がActiveで保存されていた場合、Activateイベントは発生しなかった
End Sub
=============================
'"以下をsheet1"に記述

Private Sub Worksheet_Activate()
'初期設定処理
MsgBox "sheet1の初期設定をしました"
End Sub
=============================
宜しくお願いします。

回答No.1

kkkkkm · ベストアンサー

Private Sub Workbook_Open()
Worksheets("sheet1").Activate
Sheet1に記載している
'初期設定処理
End Sub

とするのは駄目なのでしょうか。

念のためにセル指定部分はSheet1指定して
With Sheets("Sheet1")
.Range("A1")とか.Cells(1,1)など
End With

もしくはSheet1のコードに
Private Sub Worksheet_Activate()
を
Sub Init()
'初期設定処理
End Sub
にして
Private Sub Worksheet_Activate()
Call Init
ENd Sub
とし、それで
Private Sub Workbook_Open()
Sheets("Sheet1").Init
End Sub

などありそうです。

お礼

早々のご回答ありがとうございました。
おかげで解決できました。
補足説明ですが、sheet1にはActiveコントロールを配置しておりその初期化もあります。
以下sheet1にテキストボックスを追加して状況説明致します。
-------------------
【回答その１】：一部NG
'以下は"ThisWorkbook"に記述

Private Sub Workbook_Open()
Worksheets("sheet1").Activate

Txt初期値.Value = 23.4 '★「変数が定義されていません」エラー
Worksheets("sheet1").Range("A1") = 10 '★これはOK
End Sub
======================================
【回答その２】：OK
'以下は"ThisWorkbook"に記述

Private Sub Workbook_Open()
Worksheets("sheet1").Activate
Sheets("sheet1").Init
End Sub
-------------------
'以下は"sheet1"に記述

Sub Init()
Txt初期値.Value = 23.4
Worksheets("sheet1").Range("A1") = 10
End Sub
======================================

回答No.6

imogasi

№2のお礼に関して、気になったこと。
コントロールのことが出ていますが、
（１）ユーザーフォームに置く
（２）シートに置く
（３）その他　どういう場合か思い出さないが。
の３つが、考えられるが、（１）に置くのが、正統的な使い方のように見える。
本やWEB記事や実際やってみての経験から、そういうものかと思う。
この点をいつも意識して、勉強されるとよいと思う。
それに
（１）手動で貼り付け
（２）VBAで動的にコントロールを作成
の２つがあり得るが、（１）が主流で、（２）のVBAによる方法を使わざるを得ない場合は、書籍などでは、あまり想定されてない。

お礼

お礼が遅くなりました。
貴重なアドバイスありがとうござました。
ご意見を今後の参考にさせていただきたいと思います。
・コントロールをシートに置いたのは、オートシェイプを使って外枠の形や中のデザインなどを自由に作成したかったためです。ユーザーフォームに置くことについては今後検討していきたいと思います。
・またコントロールの作成をVBAで動的に作成する点につきましては、貼り付けや削除をプログラム上で自由にできそうなので、そういう使い方をするときには有効かと思いますが、掲載されている参考書も見当たらず、別の機会に考えることにしたいと思います。

回答No.5

kkkkkm

No1のお礼を見ないままNo4を回答してしましました。
No４の説明はいらなかったですね。

回答その２】：OK

でいいと思います。個々のシートの操作はThisWorkbookに書くよりシートモジュールに書いた方がいいですね。
ThisWorkbookに書いたら駄目なのでしょうかといった本人が言うなという感じですが…。

お礼

お礼が遅くなりました。
今回の質問でいろいろな方法があることがわかりました。
１点、基本的に私が間違っていた点をお伝えしておきます。

回答No.1のお礼の中で

『【回答その１】：一部NG』と書いたのは私の間違いでした
=========================
'以下は"ThisWorkbook"に記述

Private Sub Workbook_Open()
Worksheets("sheet1").Activate

Txt初期値.Value = 23.4 '★「変数が定義されていません」エラー
Worksheets("sheet1").Range("A1") = 10 '★これはOK
End Sub
=========================
『Txt初期値.Value = 23.4』については
『Worksheets("sheet1").Txt初期値.Value = 23.4』とすべきでした。
『Range("A1") = 10』の場合は『Worksheets("sheet1").』を省略しても正常動作でしたが、ActiveXコントロールの場合はNGのようです。よくわかりませんが、他のモジュールから参照する場合は直前にシートをアクティブにしていてもシート名が必要のようです。
ともかくご丁寧なフォロー、ありがとうございました。

回答No.4

kkkkkm

No1の追加です。
もし初期設定処理でSheet1がActiveじゃないとエラーになるようなコードだとしたら

Private Sub Workbook_Open()
Sheets("Sheet1").Init
End Sub

は

Private Sub Workbook_Open()
Application.EnableEvents = False
Sheets("Sheet1").Activate
Application.EnableEvents = True
Sheets("Sheet1").Init
End Sub

にしてください。

ただ思うのですが、Sheet1がActiveになるたびに初期化するようですがそのような仕様なのでしょうか。
他のシートからSheet1を選択するたびに初期化されます。

開いた時だけなら
Private Sub Worksheet_Activate()
はいらないですし

Private Sub Workbook_Open()
Sheets("Sheet1").Activate
Sheets("Sheet1").Init
End Sub

でいいです。

お礼

再度のご教授ありがとうございました。
最初のご回答のお礼が遅れたために行き違いになったかもしれません。
・イベントの発生を停止する手法
・Activeになるたびに初期化されることに気を付ける点
など、いろいろ勉強になりました。
最初のお礼に書きましたが、今回ご教授の最後のように記述しており、正常動作を確認しました。
ありがごうございました。

回答No.3

chie65536（@chie65535）

＞Activateイベントを使おうと思いましたが
わざわざActivateイベントを使おうと思った理由は、たぶん「Sheet1がアクティブ状態じゃないと正しく初期化できないから」だと思います（Sheets1が選ばれてる状態を想定して書かれている）

Sheet1がアクティブなのが前提で書かれた初期化処理を現状のまま使うには「Sheet1をアクティブにしてから呼び出す」必要があります。

以下のようにして下さい。

=============================
'"以下をThisWorkbook"に記述

Private Sub Workbook_Open()
Dim sn As String
sn = ActiveSheet.Name '開いた瞬間のワークシート名を取得
If Worksheets(1).Name = sn Then ’snが１番のワークシートなら
Call 初期化処理 '初期化処理を呼び出す
MsgBox "sheet1の初期設定をしました"
Else ’snが１番のワークシートじゃないなら
Worksheets(1).Activate 'Sheet1をアクティブにする。イベント発生
Worksheets(sn).Activate '開いた瞬間のワークシートに戻す
End If
End Sub

=============================
'"以下をsheet1"に記述

Private Sub Worksheet_Activate()
Call 初期化処理
MsgBox "sheet1の初期設定をしました"
End Sub
=============================

'"以下を標準モジュールのModule1"に記述

Sub 初期化処理()
'初期設定処理
End Sub

お礼

お礼が遅くなりました。
いろいろな点で大変参考になり、望んでいた動作を確認することができました。
ありがとうございました。

回答No.2

imogasi

WorkBook_Openのイベントの中で、Workshees(”Shee1”）.Activateを書けばよいはず。
改めてWorksheets("sheet2").Activateをイベントとして、（質問程度のことなら、）独立させる必要はないのでは。
それよりＢｏｏｋなりＳｈｅｅｔを開いたとき、どういう作業をする必要があるのか、が質問に説明されていない。
ただ形式的に解説書に載っているコードをいじくっているだけのようだ。
エベントの考えは、また利用は、難しい点もあり、初心者には、後の学習課題だろう。
もっとデータを扱う点の勉強をすべきだろう。
どちかというと、他人に使わせるブック・シートを作った時に、使うべき時が多く、
他人に使わせるブック・シートを作っるのは、だいぶ先の課題だ。
自動的誘導（Activateイベントもこれかな？）や処理（選択を助けるコントロールの利用など）のほかに、エラー処理を丁寧にしたり、操作者の操作を制約する、コードを入れないといけないから、いろいろ学ばないといけない。
ーー
改めてシートのActivateイベントをGoogleで「Sheet Activateイベント　使い道」で照会したが
、あまりこれ（が用途）だという記事は見つからなかった。
ーー
セルデータの計算や代入・取得だけで済む処理などは、Activateさせなくても、Worksheets（”Sheet1”）.Range( ).・・
で済む場合も多い、と感じる。

お礼

ご回答ありがとうござました。
『どういう動作』について、なるべく簡単に書こうと思い、
・初期設定処理
・MsgBox "sheet1の初期設定をしました"
としか書かず、逆にわかりにくくなり申し訳ありませんでした。
内容はsheet1に配置したActiveXコントロールの初期化や演算です。
イベントを使うにはいろいろ学ぶことがあるとの助言ありがとうございました。
おっしゃる通り『ただ形式的に解説書に載っているコードいじくっているだけ』で、独学でやっている自分にはそれ以外に良い方法が見つかっておりません。
VBAは解説書はたくさん出ていますが、やってみるとうまく動かすのが大変と感じております。
またいろいろ調べていただきありがとうございました。