ExcelVBA TextBoxの値を取得できない

質問

Excel2010です。
2つのUserFormがあり（UserForm1・UserForm2とします）、UserForm1にはTextBox1～100を配置し、UserForm2にもTextBox1～150を配置しています。
それぞれのUserFormにおいて、そのUserForm名を変数に格納しておき、TextBoxの値を取得するコードを別のプロシージャ（「TextBoxチェック」）に書き、それを呼び出してTextBoxの値を格納しようとしましたができませんでした。
該当箇所のコードは以下のとおりです。

Public UFName As String 'UserFormの名前

Sub UserForm1処理()
Const Num = 100
UFName = "UserForm1"
Call TextBoxチェック(Num)
End Sub

Sub UserForm2処理()
Const Num = 150
UFName = "UserForm2"
Call TextBoxチェック(Num)
End Sub

Sub TextBoxチェック(Num As Integer)
Dim i As Integer
Dim Con As Control
With UserForms.Add(UFName)
For i = 1 To Num
Set Con = .Controls("TextBox" & i)
Debug.Print Con.Name
Debug.Print .Controls("TextBox" & i).Value
　　（その他の処理のコードは省略）
Next i
End With
End Sub

上のコードでは1つ目のDebug.Printの結果（TextBox名）は取得できていますが、2つ目のDebug.Printの結果（TextBoxの値）は空欄になってしまいます。

つまり、
With UserForms.Add(UFName)が、
Set Con = .Controls("TextBox" & i)
では反映されているのに、
.Controls("TextBox" & i).Value
では反映されていないということだと思います。

また、
Debug.Print .Controls("TextBox" & i).Value
を
Debug.Print UserForm1.Controls("TextBox" & i).Value
とすると、UserForm1の値を取得できます。

また、
With UFName_UF
を
With UserForm1
にすると、
Debug.Print .Controls("TextBox" & i).Value
の値は取得できます。

UserForm1とUserForm2において、TextBoxの値を取得する部分は共通しているため、その部分を別プロシージャにして呼び出して処理したいのですが、うまくいきません。
TextBoxの値を取得できない理由や、対処法が分かれば教えていただきたいです。

回答No.2

watabe007 · ベストアンサー

>対処法が分かれば教えていただきたいです。
参考に
Option Explicit
Dim myForm1 As UserForm1
Dim myForm2 As UserForm2
Sub UserForm1起動()
　　Set myForm1 = UserForms.Add("UserForm1")
　　myForm1.Show (vbModeless)
End Sub
Sub UserForm2起動()
　　Set myForm2 = UserForms.Add("UserForm2")
　　myForm2.Show (vbModeless)
End Sub

Sub UserForm1処理()
　　Const Num = 100
　　Call TextBoxチェック(myForm1, Num)
End Sub
Sub UserForm2処理()
　　Const Num = 150
　　Call TextBoxチェック(myForm2, Num)
End Sub

Sub TextBoxチェック(ByVal UserFormObj As Object, Num As Integer)
　　Dim i As Integer
　　Dim Con As Control
　　With UserFormObj
　　　　For i = 1 To Num
　　　　　　Set Con = .Controls("TextBox" & i)
　　　　　　Debug.Print Con.Name
　　　　　　Debug.Print .Controls("TextBox" & i).Value
　　　　Next i
　　End With
End Sub

お礼

できました！ありがとうございました。

回答No.1

watabe007

こんにちは
まず下記のコードを実行してください。
Private Sub CommandButton1_Click()
　　Dim myForm As UserForm1
　　Set myForm = UserForms.Add("UserForm1")
　　myForm.Show (vbModeless)
End Sub
コマンドボタンを押す毎にUserForm1が作成されるのが
確認できたかと思います。
>With UserForms.Add(UFName)
>For i = 1 To Num
>Set Con = .Controls("TextBox" & i)
>Debug.Print Con.Name
>Debug.Print .Controls("TextBox" & i).Value
ここでUserForms.Add(UFName)を実行することで
TextBoxに値の無い新たなUserForm1を参照しているのでは