VBA 文字を指定文字で区切り、セルを分けたい。

質問

WINは7、Excelは2013を使用しています。

「A、B」や「A・B」を、「、」や「・」のところで区切り、セルを分けたいと思っています。
下記、マクロの記録で作ったものを、アレンジしているのですが、
OtherChar:="、"　のところで、「・」を追加できなくて、つまづいてしまっています。
修正点をご教示頂けます様お願い致します。
-------------
Sub 区切り()

Dim i As Integer
Dim j As Integer
Dim maxrow As Integer

j = InputBox("「行」を数字で入力 " & vbCr & vbCr & "【例】A列=1、B列=2...Z列=26", _
"「行」を半角数字で入力して下さい。")

maxrow = Cells(Rows.Count, j).End(xlUp).Row

For i = 2 To maxrow
Cells(i, j).Select
If Cells(i, j) <> "" Then
Application.CutCopyMode = False
Selection.TextToColumns Destination:=ActiveCell, _
DataType:=xlDelimited, _
TextQualifier:=xlDoubleQuote, _
ConsecutiveDelimiter:=True, _
Tab:=True, _
Semicolon:=True, _
Comma:=True, _
Space:=True, _
Other:=True, _
OtherChar:="、", _
FieldInfo:=Array(Array(1, 1), Array(2, 1), Array(3, 1)), _
TrailingMinusNumbers:=True
end if
Next i

End Sub

回答No.2

watabe007 · ベストアンサー

参考に
Sub 区切り()
　　Dim i As Long, j As Long, maxrow As Long
　　Dim myStr As String, v As Variant

　　j = InputBox("「列」を数字で入力 " & vbCr & vbCr & _
　　　"【例】A列=1、B列=2...Z列=26", "「列」を半角数字で入力して下さい。")
　　maxrow = Cells(Rows.Count, j).End(xlUp).Row
　　For i = 2 To maxrow
　　　　myStr = Cells(i, j).Value
　　　　If myStr <> "" Then
　　　　　　myStr = Replace(myStr, "・", "、")
　　　　　　v = Split(myStr, "、")
　　　　　　Cells(i, j).Resize(, UBound(v) + 1).Value = v
　　　　End If
　　Next i
End Sub

お礼

watabe007様

ご回答いただきありがとうございます。
書いて下さった構文で、希望通りになりました！

回答No.1

mt2015

「、」でも「・」でも区切りたいと言う事？
だったら、区切る前に「・」を「、」に置換すればよいのでは？

お礼

mt2015様

ご回答ありがとうございました。
参考にさせて頂きます。