マクロ IF分岐 結果がうまく表示されない

質問

I列J列、M列N列、Q列R列の、それぞれ2列ともに水色と紫色のフォントが両方あったら、U、V、W列に、う、キ、ち、とそれぞれ入力する、というマクロを作ってみたのですが、入力結果が指定した列に表示されません。添付のように「キ」がU列にきたり、「ち」がU列にきたりしています。何をどうすればいいでしょうか？
Sub test()
'
For nRow = 7 To 233
If Cells(nRow, 9).DisplayFormat.Font.ColorIndex = 33 And Cells(nRow, 10).DisplayFormat.Font.ColorIndex = 47 Then
Cells(nRow, 21) = "う"
ElseIf Cells(nRow, 10).DisplayFormat.Font.ColorIndex = 33 And Cells(nRow, 9).DisplayFormat.Font.ColorIndex = 47 Then
Cells(nRow, 21) = "う"
Else
Cells(nRow, 21) = ""
End If
Next nRow
For nRow = 7 To 233
If Cells(nRow, 13).DisplayFormat.Font.ColorIndex = 33 And Cells(nRow, 14).DisplayFormat.Font.ColorIndex = 47 Then
Cells(nRow, 21) = "キ"
ElseIf Cells(nRow, 14).DisplayFormat.Font.ColorIndex = 33 And Cells(nRow, 13).DisplayFormat.Font.ColorIndex = 47 Then
Cells(nRow, 22) = "キ"
Else
Cells(nRow, 22) = ""
End If
Next nRow
For nRow = 7 To 233
If Cells(nRow, 17).DisplayFormat.Font.ColorIndex = 33 And Cells(nRow, 18).DisplayFormat.Font.ColorIndex = 47 Then
Cells(nRow, 21) = "ち"
ElseIf Cells(nRow, 18).DisplayFormat.Font.ColorIndex = 33 And Cells(nRow, 17).DisplayFormat.Font.ColorIndex = 47 Then
Cells(nRow, 23) = "ち"
Else
Cells(nRow, 23) = ""
End If
Next nRow
End Sub

回答No.1

SI299792 · ベストアンサー

赤丸部分のミスだと思います。

お礼

イージーミスでした。。。すみません、ありがとうございました。

回答No.2

SI299792

プログラムが無駄に長いから、ミスを犯します。
私ならこうするというサンプルを載せます。
'
Option Explicit
'
Sub test()
'
Dim nRow As Long
Dim C1 As Long
Dim C2 As Long
'
[U7:W233].ClearContents
'
For nRow = 7 To 233
C1 = Cells(nRow, "I").DisplayFormat.Font.ColorIndex
C2 = Cells(nRow, "J").DisplayFormat.Font.ColorIndex
If C1 = 33 And C2 = 47 Or C1 = 47 And C2 = 33 Then
Cells(nRow, "U") = "う"
End If
'
C1 = Cells(nRow, "M").DisplayFormat.Font.ColorIndex
C2 = Cells(nRow, "N").DisplayFormat.Font.ColorIndex
If C1 = 33 And C2 = 47 Or C1 = 47 And C2 = 33 Then
Cells(nRow, "V") = "キ"
End If
'
C1 = Cells(nRow, "Q").DisplayFormat.Font.ColorIndex
C2 = Cells(nRow, "R").DisplayFormat.Font.ColorIndex
If C1 = 33 And C2 = 47 Or C1 = 47 And C2 = 33 Then
Cells(nRow, "W") = "ち"
End If
　　next nRow
End Sub
変数は必ず定義しましょう。定義しない変数はVariant になります。Variant はメモリーを食う上、実行速度が遅いのでなるべく使わない方がいいです。
Option Explicit をつければ変数の綴りミスを防ぐことができます。
列は数字より直接文字で指定した方が間違いないです。(変数を使う場合はこの限りではない）
２か所以上で使うセルは、変数に入れた方がいいです。エクセルの表にアクセスするのは時間がかかります。バグを減らすのと、実行速度を上げる効果があります。

お礼

大変勉強になりました。いつもありがとうございます。