マクロ 条件分岐の仕方

質問

いつも回答ありがとうございます。

条件分岐について質問です。
文字に『N 』含まれている時の条件処理と、『N』が含まれていない時の条件処理を記述記述しました。一応、この記述で上手く動作しているので問題ないのですが、他に記述方法はないのでしょうか？宜しくお願い致します。

Sub 色を塗る2()
Dim b As Long '仮シートの列
Dim res As Variant '色の設定
Dim c As Variant '最後に定期をした日付のセル番地

Worksheets("仮シート").Activate
b = 2
Do While Worksheets("仮シート").Cells(2, b).Value <> ""
With Worksheets(Worksheets("仮シート").Cells(2, b).Value)
Set c = .Columns("C").Find("定期", , xlValues, 1, , 2).Offset(, -1)
If Worksheets("仮シート").Cells(2, b).Value Like "*N*" Then
If (Date - 30) <= c And c <= Date Then
res = 8
ElseIf (Date - 60) <= c And c <= (Date - 31) Then
res = 10
ElseIf c <= (Date - 61) Then
res = 3
End If
End If
If Worksheets("仮シート").Cells(2, b).Value Like "*N*" = False Then
If (Date - 10) <= c And c <= Date Then
res = 8
ElseIf (Date - 30) <= c And c <= (Date - 11) Then
res = 10
ElseIf c <= (Date - 31) Then
res = 3
End If
End If
Worksheets("仮シート").Cells(3, b).Interior.ColorIndex = res
End With
b = b + 1
Loop
End Sub

回答No.1

keithin · ベストアンサー

If Worksheets("仮シート").Cells(2, b).Value Like "*N*" Then
’Ｎなら
　If (Date - 30) <= c And c <= Date Then
　　res = 8
　ElseIf (Date - 60) <= c And c <= (Date - 31) Then
　　res = 10
　ElseIf c <= (Date - 61) Then
　　res = 3
　End If

else
’そうでないなら
　if c <= date - 31 then
　’３１日以前なら
　　res = 3
　elseif c <= date - 11 then
　’そうではなく１１日以前なら
　　res = 10
　elseif c <= date then
　’そうではなく今日以前なら
　　res = 8
　end if
End If

お礼

Nでない時を、If～Then で記述しながら変だなぁと思っていました。やっぱり変だったと分かって良かったです。それぐらい分かれよって言う質問でしたが、回答して頂きありがとうございました。

回答No.2

MarcoRossiItaly

Else については、No.1 さんのご回答を参照してください。その他について書きます。

「(Date - 30) <= c」などは、本来、括弧を取って、「date - 30 <= c.value」です。セルの場合は「.value」が省略できることになっているので、これはこれで許されるのですが。

この場合、c は、セルというオブジェクトを入れる変数として定義されていることになります。オブジェクトだと set する必要があり、お示しのコードでもそのように記述されていますね。

しかし、c の代わりに「Dim d As Date」と宣言すると、set しないで「d = .Columns("C").Find("定期", , xlValues, 1, , 2).Offset(, -1).value」とすることができます。この「.value」も省略が可能です。そして if 文の中では、勿論、「date - 30 <= d」と書き、d はオブジェクト型ではないので「.value」を付けないですね。

いや、やはり variant 型の c を使うという場合は、「End Sub」の 1 行前に、「set c = nothing」の記述を挿入しましょう。

また、今回の条件分岐は if のほかに、select case という構文でもできます。可能なときは select case にしておいたほうが、コードがスッキリして読みやすくなります。

そうすると、次のとおり書き換えることとなります。「Is」が 1 か所のみに使われていることに注意。

If (Date - 30) <= c And ……
……
res = 3
End If

↓

Select Case d
　　Case Is <= Date - 61
　　　　res = 3
　　Case Date - 60 To Date - 31
　　　　res = 10
　　Case Date - 30 To Date
　　　　res = 8
End Select

お礼

回答が遅くなって申し訳ありません。
色々書いて下さり感謝しています。
variant 型の c を使うという場合は、「End Sub」の 1 行前に、「set c = nothing」の記述を挿入しましょう。
とありますが、何故でしょうか？Set cを無効にしないと不都合が発生するのでしょうか？あまり意味も分からず、ここで教えてもらった記述を、自分の都合のいいように少しかえて作っているもので・・・。よかったら教えて頂けないでしょうか？宜しくお願い致します。