エクセルで画像をこのように表示は可能ですか？

質問

エクセルに画像をはりつけて表示させたいのですが、

貼り付けた画像は普段は消えていて（閉じていて）、表示させたいときだけタブをクリックしたら表示されるか、カーソルを持っていったら表示されるようにしたいです。

例えば「J1」に画像を貼り付けたら、普段は消えていて、見たい時だけ上記のような方法で表示させたいですが可能でしょうか？

ハイパーリンクも試しましたが、少しちがいました。

コメントの挿入で画像を貼り付けた時が、こういう風にしたいとおもっていたやり方に近かったのですが、画像を開いた時に、画像が右の方に切れてしまいます。

モニター全体をキャプチャした画像を表示させたいので、画像はできればモニター全体に表示させたいのですが、無理でしょうか？

回答No.1

eden3616

お望みのような形ではないかもしれませんが、VBAにて。
わかりにくそうな所は添付画像を参考願います。

(1)シートタブを右クリックし「コードの挿入」からVBEを開き、
以下のVBAコードを貼り付ける。

Private Sub Worksheet_FollowHyperlink(ByVal Target As Hyperlink)
　　UserForm1.Caption = Target.Range.Text
　　UserForm1.PictureSizeMode = fmPictureSizeModeZoom
　　UserForm1.Picture = LoadPicture(Target.ScreenTip)
　　UserForm1.Show
End Sub

(2)VBEのメニューより「挿入」→「ユーザーフォーム」でフォームを作成し、
フォームを右クリックしてコードの表示を選択。
初期で入力されているコードを全て削除したのちに、以下のコードを貼り付け。
VBEを「×」で閉じる。

Option Explicit
'Windows API宣言
Private Const GWL_STYLE = (-16)
Private Const WS_THICKFRAME = &H40000
Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long) As Long
Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Private Declare Function GetActiveWindow Lib "user32" () As Long
Private Declare Function DrawMenuBar Lib "user32" (ByVal hwnd As Long) As Long
' フォームをリサイズ可能にするための設定
Public Sub FormSetting()
　　　　Dim result As Long
　　　　Dim hwnd As Long
　　　　Dim Wnd_STYLE As Long
　　　　hwnd = GetActiveWindow()
　　　　Wnd_STYLE = GetWindowLong(hwnd, GWL_STYLE)
　　　　Wnd_STYLE = Wnd_STYLE Or WS_THICKFRAME Or &H30000
　　　　result = SetWindowLong(hwnd, GWL_STYLE, Wnd_STYLE)
　　　　result = DrawMenuBar(hwnd)
End Sub
Private Sub UserForm_Activate()
　　　　Call FormSetting
End Sub

(3)任意のセル（例えばA1セル）に任意の文字を入力し、ハイパーリンクを作成します。
セル参照の入力はリンクを挿入したセルのアドレス「A1」とし、
ヒント設定にて表示させたい画像のパスを設定します。
対応しているファイル形式は（bmp・dib・gif・jpg・wmf・emf・ico・cur）になります。

作成したリンクをクリックするとウィンドウで画像が開きます。
リサイズ可能にしているため、大きさは変更できますが、開いた時の初期サイズは
(2)で作成したユーザーフォームのサイズになります。

補足

ありがとうございます。やってみたのですが、うまくて出来てないかもしれないです。フォトビューアーも開いていいのでしょうか？
現状を画像を貼り付けて投稿しなおしてみますので、よかったらまた教えてください。回答ありがとうございました