エクセルVBA セルの値、書式を貼り付けしたい

質問

エクセル2002を使っています。

Workbooks("名簿.xls").Worksheets("ALL") には、職員全員の情報があります。
　　　　　　（名前、住所、出身地、誕生日）
Workbooks("名簿.xls").Worksheets("KAIGAIFUNIN") には、職員の中でも海外赴任経験がある人の情報があります。
　　　　　　（名前、赴任地、滞在年数）

エクセルVBAで、Worksheets("KAIGAIFUNIN") に名前がある人をWorksheets("ALL") で検索し、該当したらWorksheets("ALL") の名前の横のセルに赴任地と滞在年数を貼り付けしたい。
その際、セルの値はもちろんですが、書体、文字サイズ、文字の色、セルの塗りつぶしをコピーをそのまま貼り付けしたく、以下の様にマクロを書きました。

－－－－－－－－－－－－－－－－－－－－－－－－－－－

SUB 海外赴任者チェック（）

Set A = Workbooks("名簿.xls").Worksheets("ALL")
Set B = Workbooks("名簿.xls").Worksheets("KAIGAIFUNIN")

For tateA = 2　to 400

　tateB = 2
　Do Until B.Cells(tateB, 1) = ""

　　If B.Cells(tateB, 1) = A.Cells(tateA, 1) Then
　　　　A.Cells(tateA , 5) = B.Cells(tateB, 2) '赴任先の入力
　　　　A.Cells(tateA , 6) = B.Cells(tateB, 3)　'赴任年数の入力
　　END IF
　tateB = tateB + 1
　Loop

Next

END SUB

－－－－－－－－－－－－－－－－－－－－－－－－－－－

上記の場合だと、文字サイズや色など書式は反映されません。
セルの塗りつぶしは色を複数使っていますので、人によっては青だったり緑だったりします。
R1C1形式でなく、A1形式だと書式の設定をそのまま反映する事が出来るので

Range("B2").Select
Selection.Copy
Range("E11").Select
ActiveSheet.Paste

と言ったA1形式にしたいのですが、
海外赴任者の名前の一覧は、Worksheets(ALL)の中でも名前の順になっていますが退職者や新入社員も入ってきたりしますので、固定ではなく前後します。

そういった中で、検索した該当者のtateの位置　A.Cells(tateA , 5)　を　R1C1形式にする方法を教えてください。
よろしくお願いします。

回答No.1

ushi2015 · ベストアンサー

こんにちは
R1C1形式、A1形式は関係無いのでは？
Sub 海外赴任者チェック()
　　Dim A　　 As Worksheet
　　Dim B　　 As Worksheet
　　Dim tateA As Long
　　Dim tateB As Long

　　Set A = Workbooks("名簿.xls").Worksheets("ALL")
　　Set B = Workbooks("名簿.xls").Worksheets("KAIGAIFUNIN")

　　For tateA = 2 To 400
　　　　tateB = 2
　　　　Do Until B.Cells(tateB, 1) = ""
　　　　　　If B.Cells(tateB, 1) = A.Cells(tateA, 1) Then
　　　　　　　　B.Cells(tateB, 2).Copy A.Cells(tateA, 5) '赴任先の入力
　　　　　　　　B.Cells(tateB, 3).Copy A.Cells(tateA, 6) '赴任年数の入力
　　　　　　　　Exit Do
　　　　　　End If
　　　　　　tateB = tateB + 1
　　　　Loop
　　Next
End Sub

お礼

返事が遅くなりまして、すみません。

悩んでいた事が簡単に解決できました!!
どうもありがとうございました。m(_ _)m

回答No.2

SI299792

IFの中を
B.Cells(tateB, 2).Resize(1, 2).Copy A.Cells(tateA, 5)
にすれば、コピーは１回で済みます。

お礼

返事が遅くなりまして、すみません。

お忙しいところご回答いただき、ありがとうございました。m(_ _)m

Resizeは知らなかったので参考になりました。