エクセルの勤務表から日付別に出勤者と勤務を抜き出すマクロの作成方法

質問

• エクセルの勤務表から日付別に出勤者とその出勤者の勤務を抜き出すマクロを作成する方法を教えてください。
• 勤務表マスタには勤務表があり、それ以外に３０枚のシートを用意しておき、日付別に出勤者とその出勤者の勤務を抜き出します。休みの人は表示しません。作成したマクロのコードも確認しましたが、３０日分を転記する方法がわかりません。どうすれば良いでしょうか？
• 現在、エクセルのマクロを学習中であり、勤務表から日付別に出勤者とその出勤者の勤務を抜き出すマクロを作成したいです。勤務表マスタから１日分のデータを抜き出すことはできましたが、３０日分を転記する方法がわかりません。ご教示いただけますと幸いです。

回答No.1

dogs_cats · ベストアンサー

一例です。

Sub test()

Dim strSerch1 As String
Dim strSerch2 As String
Dim LastRow As Long
Dim i, j, k, m, n As Long
Dim Myday As Integer
Dim ws As Worksheet

'検索する文字を以下の二つの変数に代入
strSerch1 = "早番"
strSerch2 = "遅番"

'Sheet1に「早番」の人をリスト化するための変数を設定
'最初に入れるのが3行目なのでjに3を代入

With Worksheets("勤務表マスタ")

'月の最終日を取得（１行目の最終列-1が月の最終日)
Myday = .Cells(1, Columns.Count).End(xlToLeft).Column - 1

'.Cells(.Rows.Count, 1).End(xlUp).Rowで最後の行がどこなのか調べて
'LastRow変数に代入する。
LastRow = .Cells(.Rows.Count, 1).End(xlUp).Row

For i = 1 To Myday

'日付シート名を変数に格納
Set ws = Worksheets("sheet" & i)

'日付シートのB1に日付入力
ws.Range("B1") = Format(.Cells(1, i + 1), "m月d日")

j = 3
k = 8

For m = 2 To LastRow

'早番の場合は日付シートの３行目から順に入力
If .Cells(m, i + 1).Value = strSerch1 Then
ws.Cells(j, 2).Value = .Cells(m, 1).Value
ws.Cells(j, 3).Value = .Cells(m, i + 1).Value

j = j + 1

End If

'遅番の場合は日付シートの８行目から順に入力
If .Cells(m, i + 1).Value = strSerch2 Then
ws.Cells(k, 2).Value = .Cells(m, 1).Value
ws.Cells(k, 3).Value = .Cells(m, i + 1).Value

k = k + 1

End If

Next m

Next i

End With

End Sub

日付シートのデータをクリアする事を追加しています。本ブックを翌月使用すると前月データが残る為。B3~C10を設定していますので修正下さい。

お礼

返信遅くなってすいません。丁寧なご回答ありがとうございます。
自分の拙いマクロをそのまま使っていただいてありがとうございます。
書いていただくと「なるほど」と思うのですが、今の自分の実力では、全く思い浮かばず、とても参考になりました。ありがとうございました