vbaで新規フォルダ作成時の名前の指定

質問

「あいいうえお」フォルダの中に年が変わったら「2015年」という名前でフォルダの作成を行いたいのですが、下記のコードでは「あいうえお2015年」という名前のフォルダを作成してしまいます。フォルダの作成で、「あいうえお」を除いたものを作成するにはどう変えればよいでしょうか？

（12月のファイルで実行した時に例えば「2015年」フォルダを作成して、その中に「あいうえお2015-1月.xlsm]ファイルを作成します。同じ年なら「あいうえお11月.xlsm]などファイルのみを作成します。）

お手数をおかけしますがどうぞよろしくお願いいたします。

Sub ブックコピー自動翌月分作成()
Dim i As Integer
Dim wb As Workbook
Dim myDir_path As String, myNew_path As String
'フォルダパスとファイルパスを作成
myDir_path = Left(ThisWorkbook.FullName, InStrRev(ThisWorkbook.FullName, "\") - 1)
myNew_path = "あいうえお" & Format(DateAdd("m", 1, Replace(Replace(ThisWorkbook.Name, "あいうえお", ""), "月.xlsm", "")), "yyyy-m") & "月.xlsm"
myDir_path = Left(myDir_path, InStrRev(myDir_path, "\")) & Left(myNew_path, 9) & "年\"
'フォルダの有無を確認、なければ作成
With CreateObject("Scripting.FileSystemObject")
If Not .FolderExists(myDir_path) Then
MkDir myDir_path
'MsgBox myDir_path & "を作成しました"
'MsgBox Left(myDir_path, InStrRev(myDir_path, "\")) & "に" & vbNewLine &
MsgBox Left(ThisWorkbook.FullName, InStrRev(ThisWorkbook.FullName, "\") - 12) & "に" & vbNewLine & _
Left(myNew_path, 9) & "年" & "フォルダを新たに作成しました"
End If
End With
'ファイルの有無を確認、なければ保存,あれば処理中止
If Dir(myDir_path & myNew_path) = "" Then
ThisWorkbook.SaveCopyAs myDir_path & myNew_path
MsgBox myNew_path & "のファイルを新たに作成しました"
Else
MsgBox "翌月分のファイルはすでに存在するので処理を中止します", vbOKOnly, "処理中止"
Exit Sub
End If
'新規作成したブックを開く,既に開いていれば処理中止

For Each wb In Workbooks
If wb.Name = myNew_path Then
MsgBox myNew_path & "は既に開いているので処理を中止します", vbOKOnly, "処理中止"
Exit Sub
End If
Next

Workbooks.Open myDir_path & myNew_path
Workbooks(myNew_path).Activate

End Sub

回答No.2

mt2008 · ベストアンサー

自ブックがフルパスで↓の時、マクロを動かすと
　\\192.168.1.100\工作\生産\あいうえお\2014年\あいうえお2014-12月.xlsm

新たにフォルダを作って以下の様に保存されれば良いのですね
　\\192.168.1.100\工作\生産\あいうえお\2015年\あいうえお2015-1月.xlsm

ようやくパスが解りました。
コードの中で自ブックのパスと名前を使っているのですから、質問の際にはその情報も最初からつけてください。
修正はコレだけで良いです。

myDir_path = Left(myDir_path, InStrRev(myDir_path, "\")) & Left(myNew_path, 9) & "年\"
　↓
myDir_path = Left(myDir_path, InStrRev(myDir_path, "\")) & Mid(myNew_path, 6, 4) & "年\"

お礼

質問の情報が不足していたようで、お手数をおかけしました。
修正したら理想通りにできました。
ほんの少しの違いで結果に差がでますね。

どうもありがとうございました。これだけのことですがやっと解放されました。
ありがとう。

回答No.1

mt2008

自ブック名やパスが不明なので思い違いをしている可能性は有りますが、とりあえず以下の様な変更でどうでしょう？

myDir_path = Left(myDir_path, InStrRev(myDir_path, "\")) & Left(myNew_path, 9) & "年\"
　↓
myDir_path = Left(myDir_path, InStrRev(myDir_path, "\")) & "あいうえお\" & Mid(myNew_path, 6, 4) & "年\"

補足

ありがとうございます。
試してみたのですが、新規フォルダ作成の、

MkDir myDir_path

の所でパスがみつかりません、となります。元に戻すと「あいうえお2014年」フォルダを作成してくれます。

教えていただいたものは、近いところにはきている感じはしますがうまくいきません。

実際の具体的なパスは以下のような感じになります。現在のファイルがあるファルダ名を例えば「2015年」にしたいところが「あいうえお2015年」という名前で作成されます。

\\192.168.1.100\工作\生産\あいうえお\2014年\あいうえお2014-11月.xlsm