ワードで作成した表の一部をエクセルに貼り付け

質問

MSWord2010の一つのファイルに作成した200以上の表の一部をエクセル2010に貼り付けます。
各表の１行１列目と３行２列目をエクセルのA列とB列にそれぞれ一つ目の表から順に１行目から貼り付けていきます。
最初はコピペでいこうと思いましたが、ミスが怖いので、自動的に貼り付けていきたいのです。
ほとんど素人なのですが、マクロとかで貼り付けられるのでしょうか。マクロを使う場合は少し丁寧に教えてください。

回答No.2

keithin

だいぶ不細工ですが。

手順：
オリジナルのワード文章を開く
ＡＬＴ＋Ｆ１１を押す
現れた画面で挿入メニューから標準モジュールを挿入する
現れたシートに下記をコピー貼り付ける

Sub Macro1()
　Dim h As Table
　Dim d As Document
　Dim o As Variant

　Set d = Documents.Add(documenttype:=wdNormalDocument)

　For Each h In ThisDocument.Tables
　　Set o = h.Cell(1, 1).Range
　　o.End = h.Cell(3, 2).Range.End
　　o.Copy
　　d.Content.Collapse direction:=wdCollapseEnd
　　Selection.PasteAndFormat wdFormatOriginalFormatting
　Next
End Sub

ファイルメニューから終了してワードに戻る
ＡＬＴ＋Ｆ８を押してマクロを実行する

新しいワード文章に各表の所定のセル範囲が連続表として転記されるので、必要に応じてコピーしてエクセルに持って行ってください。

ん？？
＞各表の１行１列目と３行２列目を

もしかしてこれって、各表から「２個のセルだけを」コピーしたいって意味ですかね？？？

手順は同じ：
Sub macro2()
　Dim objXl As Object
　Dim h As Table
　Dim n As Long

　Set objXl = CreateObject("Excel.Sheet")
　objXl.Application.Visible = True

　For Each h In ThisDocument.Tables
　　n = n + 1
　　objXl.worksheets(1).Cells(n, 1) = h.Cell(1, 1)
　　objXl.worksheets(1).Cells(n, 2) = h.Cell(3, 2)
　Next

　objXl.SaveAs ThisDocument.Path & "\res"
　objXl.Application.Quit
　Set objXl = Nothing
End Sub

ワード文章の隣にエクセルブックを保存して終了します。

お礼

keithinさんへ
各表から「２個のセルだけを」コピーしたいという意味でした。
2つ目の方法できれいにエクセルに貼り付けることができました。
大変助かりました。
ありがとうございました。

回答No.1

masamasa74

『表』を『表作成ソフト』で作らずに、『文章作成ソフト』で『表』を作成し、『文章作成ソフト』で出来た『表』を『表作成ソフト』に貼り付けるのですか？？？

この時点で何がしたいのかがわかりませんが、画像として貼り付けるのかデータとして貼り付けるのかがわかりません。

補足

説明が不足しており、申し訳ございません。
文章作成ソフトで表で作りました（修正履歴が文章作成ソフトのほうが作り易かったためです）。
ワードで作成した表の一部をデータとしてエクセルのセルに貼り付けます。