全てのコマンドボタンの名前を変更したい

質問

先日質問した「オブジェクト（コントロール）の名前を変更したい」
http://okwave.jp/qa/q7896863.html?by=datetime&order=DESC
の応用で、
前回はDexMachina様にご回答いただいて解決したのですが今度は違う部分で詰みました。

フォームに乗っかっているコマンドボタンの名前を変更しつつ、
インデックスを付けていこうと思うのですが
**************************************
Sub オブジェクト名変更()
Dim ctl As Control
Dim i As Long
Dim f As String

f = "フォーム1"
i = 1
DoCmd.OpenForm f, acDesign 'デザインビューで開く
For Each ctl In Forms(f).Controls
If ctl.ControlType = acCommandButton Then
Forms(f)!Controls(ctl.Name).Caption = i
Forms(f)!Controls(ctl.Name).Name = i
End If
Next ctl
DoCmd.Close acForm, "フォーム1", acSaveYes '保存する
End Sub
**************************************
のControls(ctl.Name).でエラーになります。

エラー内容は
実行時エラー2465
指定した式で参照されている’ Controls’フィールドが見つかりません。
です。

イミディエイトで?ctl.Nameして見ると
コマンド0となるので問題ないと思うのですが文法がおかしいのでしょうか？

Forms(f)!コマンド0.Caption
にすると問題なく動作します。

ご回答よろしくお願いします。

回答No.3

DexMachina · ベストアンサー

先日のご質問の回答者です。
18～21日は新潟の親戚宅(ネット接続環境なし)で雪下ろしの手伝いをしておりました(汗)

> 指定した式で参照されている’ Controls’フィールドが見つかりません。

先日の回答で提示したURLから、更にその前へ、その前へ・・・と辿っていった先のQ&A：
http://okwave.jp/qa/q7778972.html

で提示したこちらのサイト：
http://www.f3.dion.ne.jp/~element/msaccess/AcTipsVbaDotVsBangOperator.html

に、「.」と「!」の意味の違いについての詳細な説明がありますので、時間と気持ちに余裕が
あれば、目を通してみてください。
(期限を切られた業務などでは、そうもいかないことも多いかとは思いますが(汗))

要は、
　　「Forms(f).Controls」と、「.」を使用した場合は、Controlsコレクション(又はプロパティ)を、
　　「Forms(f)!Controls」と、「!」を使用した場合は、Controlsという名前のコントロールを、
それぞれ参照していることになるため、実際に「Controls」という名前のコントロールがなければ
ご質問のようなエラーになる、ということです。

ですので、既にpirion654さんから回答がある通り、構文としては
　　Forms(f).Controls(ctl.Name).Caption = i
が正しい形となります。

また、これも既出ですが、せっかく「For Each ～ Next」により「Forms(f).Controls」のメンバを
変数「ctl」で受けているのですから、
　　ctl.Caption = i
とした方が、(今回の例で体感できるかは別として、ですが(汗))処理速度も向上します。
(「Controls(ctl.Name)」だと、既に「ctl」として参照しているコマンドボタンを、改めてControls
　コレクションの中で名前が一致するものを探すという、余計な動作をしていることになります)

なお、今回のコードは動作確認用のサンプルということで簡略化されているのだとは思いますが、
コントロール名を「数字のみ」にするのは、避けた方が無難です。
(例えば、コマンドボタンの名前を「1」とした場合、VBA上では、数値の「1」と区別するために、
　同コマンドボタンは「Ctl1」という形で参照する必要が生じます：
　クリック時のサブプロシージャは、「Private Sub 1_Click()」ではなく「Private Sub Ctl1_Click()」
　になる、と)

※更に既出の、「i = i + 1」による「同名重複の回避」もお忘れなく・・・

【余談(前回の補足)】

> これは、該当フォームから実行してる事にはならないのですか？

「当該フォームから実行」とは、「ボタン名の変更を行うフォームのコマンドボタンのクリック時イベント
などに、提示したコードを記述して実行」という意味です。
(標準モジュールにSubまたはFunctionとして記述した上で、コマンドボタンからそれを呼び出す
　場合も含みます)

> 要するに
> Form_フォーム1
> と
> Forms("フォーム1")
> は別物のようですね。

はい。

「Form_フォーム1」は、VBA上で定義された「フォーム1」を参照します。
(「Form_フォーム1.Name」などを参照すると、インスタンスが生成され(≒メモリに読み込まれ)ます)

一方、「Forms("フォーム1")」は、「表示/非表示を問わず、展開済みのフォーム群を格納する
Formsコレクション」から、キー(≒フォーム名)が一致するフォームを参照します。

前者は「定義」なので、同名フォームがあれば(但し『コード保持』(HasModule)プロパティが
「はい」(True)である必要あり)、いつでも参照可能ですが、
後者は「(『コード保持』の値に関係なく、展開済みのフォームを格納する)Formsコレクション」に
追加済みでない場合、参照するとエラーになる、といった違いがあります。

お礼

ありがとうございました。

補足

雪下ろし御苦労様です＾＾

回答No.2

piroin654

No1です。
最初の部分の、
'Forms(f)!Controls(ctl.Name).Caption = i
'Forms(f)!Controls(ctl.Name).Name = i
としている部分はコメントアウトしています。
したがってこの部分は使わないということです。
お間違えのないように。

お礼

ありがとうございました。

回答No.1

piroin654

以下のように。

For Each ctl In Forms(f).Controls
If ctl.ControlType = acCommandButton Then
'Forms(f)!Controls(ctl.Name).Caption = i
'Forms(f)!Controls(ctl.Name).Name = i
ctl.Caption = i
ctl.Name = i
i = i + 1
End If
Next ctl

以下簡単な説明。

＞If ctl.ControlType = acCommandButton Then
の部分でctlはフォーム1のボタンとしているので

＞Forms(f)!Controls(ctl.Name).Caption = i
＞Forms(f)!Controls(ctl.Name).Name = i

ではなく、

ctl.Caption = i
ctl.Name = i

とします。それに
＞Forms(f)!Controls
という参照の仕方は違います。本来は
Forms(f).Controls
のようにドットで参照します。

それから、iを加算しないと新たなるエラーが生じるはずです。

お礼

ありがとうございました。