VBAで教えてください。

質問

データがないときはExitSubしたいのですが、何処に記述すれば良いでしょうか？

Sub 削除()

Dim i As Long

If MsgBox("データを削除します。よろしいですか？", vbYesNo) = vbYes Then

Sheets("リスト").Select
i = 5
Do Until i = 200

If Cells(i, 5).Value = Sheets("マスタ登録").Range("D5") Then
Cells(i, 1).EntireRow.Delete
End If

i = i + 1

Loop

Else

Exit Sub

End If

End Sub

回答No.3

WindFaller · ベストアンサー

こんばんは。

#2さんのおっしゃるように、下から削除するというのが一般的です。

なお、範囲が数値で数えられるものは、For i =1 ～　To ... Next のスタイルのほうが良いです。Do ～ Loopは、また、別の時に使います。

'//
Sub DeleteRowsCount()
　Dim sVal As Variant
　Dim i As Long
　sVal = Worksheets("マスタ登録").Range("D5").Value
　If sVal = "" Then MsgBox "マスタ登録のデータがありません。", 48: Exit Sub
　Application.ScreenUpdating = False
　With Worksheets("リスト")
　　If Application.CountIf(.Columns("E"), sVal) = 0 Then MsgBox sVal & "はありません。", 24: Exit Sub
　　If MsgBox("データを削除します。よろしいですか？", vbYesNo) = vbNo Then Exit Sub
　　For i = .Cells(Rows.Count, "E").End(xlUp).Row To 5 Step -1
　　　If .Cells(i, "E").Value = sVal Then
　　　　.Cells(i, "E").EntireRow.Delete
　　　End If
　　Next i
　End With
　Application.ScreenUpdating = True
End Sub

回答No.2

mt2008

Sheets("リスト").Select
の後にでも↓を入れてみて下さい。
If WorksheetFunction.CountIf(Range(Cells(5, 5), Cells(200, 5)), Sheets("マスタ登録").Range("D5")) = 0 Then Exit Sub

でも、今のままのコードでは削除対象の行が連続していた場合、1つ目の行を削除したことで行がずれるので、2つ目の行は削除できませんよ。
行の削除は下から上に行いましょう

回答No.1

FEX2053

単純に「先頭セルがブランクかどうか」のチェックで良いんじゃ？

Sheets("リスト").Select

IF Cells(5, 5).Value = "" Then Exit Sub

i = 5

これでいいと思いますけど・・・。