エクセル関数について

質問

エクセル２０００を使用しています。例えばＡ１にタイム（○分○秒）を入力するとします。Ｂ１に計算式として、Ａ１が５分を超えた場合－５点とし、以後３０秒を超える毎に－５点ずつ減点する式を教えてください。５分１０秒なら－５点、５分４０秒なら－１０点というようにです。

回答No.3

taisuke555 · ベストアンサー

=-5*MAX(0,ROUNDUP((A1*2880-10),0))
でどうでしょうか？

私のも一応解説しますと、
A1セルの値を24*60*60=86400で掛けると秒になります。
（＃１さんの"00:01.00"で割っているのと同じ事だと思います。）

=ROUNDUP((A1*24*60*60-5*60)/30,0)で
５分を引いて３０秒で割って小数点以下を切り上げします。
=-5*MAX(0,ROUNDUP((A1*24*60*60-5*60)/30,0))で
それと０を比較し大きい方の値に－５を掛けます。
（５分以下の場合は負の数になるので０が取られます）

後は、計算式を簡単にして上記の式になっています。
（考え方は＃１さんと同じで、計算式を簡単にしただけだと思います。）

後で見直したときに分かりにくいので＃１さんや私の最後の式の方が、
後々のメンテはしやすいと思います。

後、この数式を入力すると書式設定が「日付」に変わってしまうと思うので
「標準」に直してください。
（私のだけかもしれませんが・・・）

回答No.2

imogasi

こういう段階型のエントリの値取得のパターンはVLOOKUPのFALSE型が良いでしょう。
（テーブル）
D1:E6に
0:00 0
5:00 -5
5:30 -10
6:00 -15
6:30 -20
7:30 -25
を作る。時刻を表す「：」を使ってD列を作ること。
B1に関数式=VLOOKUP(A1,$D$1:$E$6,2,TRUE)を入れる
＄をつけること、TRUE型であること、表の最左列について
昇順であること。
表を別シートにも出来ます。
(テスト）
（A列）　（B列）
5:01 -5
5:35 -10
3:00 0
6:20 -15
5:40 -10
5:10 -5
表の第１列は、エクセルの時刻値で、２４時間を１とする
「数値」に過ぎないことを想起して下さい。
HLOOKUPでもテーブル・式は変わるものの、可能でしょう。

回答No.1

grumpy_the_dwarf

A1が時刻だとすると、A1/"00:01.00"が秒に換算した数値になります
ので、それをふまえて
=-5*ROUNDUP((MAX(A1/"00:01.00", 300)-300)/30, 0)
とします。