Excelで入力された日付を基準に色付けする方法とは？

質問

• Excelで入力された日付を基準に、実働日でマイナスしたところを塗りつぶしたい方法を教えてください。
• 具体的には、会議のスケジュール表を作成しており、会議日のマイナス３日は赤に、マイナス６日は青に色を変えたいです。
• また、ExcelのバージョンによってはVBAを使う必要があるかもしれませんが、Excel2002でも対応可能な方法も教えていただきたいです。

回答No.4

rukuku · ベストアンサー

こんにちは

＞Excel2010移行であれば、複数の条件付き書式を使えるのでいいのですが、今回は
＞Excel2002とかも対応したいため、VBAでやる必要性があると思っています。

Excel2003までですと、条件付き書式が３つまでですので、
＞10/31 （開催日） 赤
＞10/26 （開催日▲3） 青
＞10/21 （開催日▲6） 緑
＞10/17 （開催日▲10） グレー
は無理ですね。
でも、３つまでなら条件付き書式できるので、
やってみようと思いましたが、難しかったです。
(T_T)

いずれにせよ、VBAでなければ無理なので、VBAでやってみました。
Excel2000で動作確認していますので、Excel2002でも問題ないと思います。
かなりベタな作り方ですが、その分変更がしやすいと思います。

セル番地は、ご質問の画像を出来るだけ解読してみましたが、
実際と違う部分は調整してください。
F3～IV3に日付（日付形式で入力し表示で「dd」にしてあります。）
F6～IV6に営業日なら1、休みなら0
D7～D10に開催日
という仕様で作ってあります。

Sub 実働日をカウント()
　　'変数の定義
　　Dim Line As Long
　　Dim Retsu As Long
　　Dim KaisaibiNoRetsu As Long
　　Dim NanJituroubiMae As Long

　　'6～66536行の塗りつぶしをクリア
　　Rows("6:65536").Interior.ColorIndex = xlNone '条件付き書式はクリアされません

　　For Line = 7 To 10 '行数はここで変更できます。
　　　　KaisaibiNoRetsu = 0
　　　　'開催日を探す
　　　　For Retsu = 6 To 256 'F列=6列目、IV列＝256列
　　　　　　If Cells(Line, "D") <> "" And Cells(Line, "D") = Cells(3, Retsu) _
　　　　　　　　Then
　　　　　　　　　　KaisaibiNoRetsu = Retsu
　　　　　　　　　　Cells(Line, KaisaibiNoRetsu).Interior.Color = RGB(255, 0, 0)
　　　　　　　　　　Exit For '開催日が見つかったら検索終了
　　　　　　End If
　　　　Next Retsu

　　　　'開催日から○実労日を探す
　　　　NanJituroubiMae = 0 '前の結果が残るので変数をリセット
　　　　For Retsu = KaisaibiNoRetsu - 1 To 6 Step -1 '開催日の前日から後ろ向きに検索
　　　　　　If Cells(6, Retsu) = 1 Then
　　　　　　　　NanJituroubiMae = NanJituroubiMae + Cells(6, Retsu)
　　　　　　　　If NanJituroubiMae = 3 Then Cells(Line, Retsu).Interior.Color = RGB(0, 0, 255)
　　　　　　　　If NanJituroubiMae = 6 Then Cells(Line, Retsu).Interior.Color = RGB(0, 255, 0)
　　　　　　　　If NanJituroubiMae = 10 Then Cells(Line, Retsu).Interior.Color = RGB(223, 223, 223): Exit For
　　　　　　End If
　　　　Next Retsu

　　Next Line
End Sub

お礼

回答ありがとうございます！

試して見ましたが、調整の結果、やりたかったことができました！
本当に感謝です。

週末にも関わらずありがとうございます。
これで週明けのスタートダッシュができそうです。