Excel 点数配分の方法について

質問

Excelの処理について教えてください。
下記の表に『○』の付け方によって『点数』を決めたいと
思っています。良い方法は有りませんか？？
出来ればVBAは使いたくないので、関数で出来る方法を
教えてください。宜しくお願いします。
※ちなみにExcel 2003使っています。

【条件】
監査 = 2点
代行 = 3点
会計 = 1点
特殊 = 4点

【点数表】
名前,監査,代行,会計,特殊,点数計
A社,○,○,　,○,9点
B社,○,　,○,○,7点
C社,　,　 ,　,○,4点

以上です。宜しくお願いします。

回答No.4

keithin · ベストアンサー

Ｂ，Ｃ，Ｄ，Ｅ列に監査から特殊の○が並ぶとすると
Ｆ２：
=SUMPRODUCT((B2:E2="○")*{2,3,1,4})
のように計算できます。

お礼

回答、有難うございます。
なんか私にとって一番分かりやすい
処理方法だったので『ベストアンサー』に
選びたいと思います。色んな方法で処理できる
ことに凄くビックリしています。有難うございました。

回答No.7

kagakusuki

例えば、

　　　　　 Ａ 列　　Ｂ 列　　Ｃ 列　　Ｄ 列　　Ｅ 列　　Ｆ 列
1行目　　名前　　監査　　代行　　会計　　特殊　　点数計
2行目　　配点　　　2　　　　3　　　　1　　　　4
3行目　　A社　　　○　　　　○　　　　 　　　　○
4行目　　B社　　　○　　　　 　　　　○　　　　○
5行目　　C社　　　　　　　　　　　　　　　　　　　○

という様に入力しておいた上で、F3セルに次の関数を入力してから、F3セルをコピーして、F4以下に貼り付けると良いと思います。

=IF($A3="","",SUMIF($B3:$E3,"○",$B$2:$E$2))

お礼

回答、有難うございます。
No6．の『mike_g』と似た方法ですね。
この方法（点数欄を設ける）は他にも
応用が利きそうな感じがしますね。
有難うございました。

回答No.6

noname#204879

添付図参照

F3: =SUMPRODUCT((B3:E3="○")*(B$1:E$1))

お礼

回答、有難うございます。
配点欄を別に設ける方法ですか！
配点が変わった場合などには凄く便利な方法だと
思います。参考になります。有難うございました。

回答No.5

Versailles123

点数計のセルだけに式を入れることも可能ですが、
かなり複雑になります。

そこで、、点数計の右の方のセルに4列計算用のセルを設けます。

　　A　　　B　　C　　D　　　E　　　F
1　名前　監査　代行　会計　特殊　点数計
2　A社　　○　　　○　　　　　○
3　B社　　○　　　　　　○　　○
4　C社　　　　　　　　　　　○

例えば上記のように入力されている場合、

　G列に監査の点数（○だったら2）、
　H列に代行の点数（○だったら3）、
　I列に会計の点数（○だったら1）、
　J列に特殊の点数（○だったら4）
の計算式を入れます。

例：［G2］セルに「=IF(B2="○",2,0)」
　　［H2］セルに「=IF(C2="○",3,0)」…など

そして点数計にはG～J列の合計を指定してあげればいいです。

例：［F2］セルに「=sum(G2:J2)」

こんなんでお分かりいただけたでしょうか？？？

お礼

早速の回答有難うございます。
実は、私が最初に思いついた方法がこれでした。
それで計算用の列（G列・H列・I列・J列）の文字色を
白色のにして力業のようにやっていました。
もうちょっと関数とかで上手い具合に出来ないものかと
相談してみた所存です。（笑）
自分の方法も１つの手段として上がってきたので
嬉しい気分になりました。有難うございました。

回答No.3

mu2011

NO1です。
数式のセルが誤っていましたので訂正します。
=(B2="○")*2+(C2="○")*3+(D2="○")*1+(E2="○")*4

お礼

ばっちり処理できました。
色んな方からアドバイスを頂き、すごく勉強になりました。
やりたい事が同じでも、幾通りの方法があるという事に
驚いています。有難うございました。

回答No.2

last_shishi

合計の計算式ですよね
F2のセルに
=IF(B2="○",2,0)+IF(C2="○",3,0)+IF(D2="○",1,0)+IF(E2="○",4,0)

後は、オートフィルでＦのセルを設定すれば計算できると思います。

お礼

回答、有難うございます。
No1．の『mu2011』と似た方法でのやり方ですね。
参考にさせていただきます。
有難うございました。

回答No.1

mu2011

一例です。
F2に=(B12="○")*2+(C12="○")*3+(D12="○")*1+(E12="○")*4として下方向にコピー
F2はセルの書式設定→表示形式→ユーザ定義で0点;;として下さい。

お礼

有難うございます。追記のほうでお礼を入れておきます。