エクセルVBA 無駄な部分をおしえてください

質問

VBA初心者です。
多数のシートを条件によって二つのブックに分ける、というVBAを作ろうとしています。
なにぶん素人なので、無駄な文章が多いのではないかと心配で、
お知恵を拝借できればと思い投稿いたしました。どうぞよろしくお願いいたします。

やりたいこと：Book1のA列に100程度の文字列があり、そのいずれかと一致するシート名（Book1のSheets(2)以降）を持つシートはBook2の最終シートの後ろへ、どの文字列ともシート名が一致しないシートはBook3の最終シートの後ろへ移動。（「最終シートの後ろへ移動」がうまくいっていません）

VBAの内容：Book1のH1に「=countif(A:A,G1)」と入力しておき、G1にシート名を入力させ
H1>0ならば該当シートをBook2へ、それ以外はBook3へ移動　の繰り返し

　　Application.ScreenUpdating = False

Dim j As Integer, k As Integer
j = Workbooks("Book2.xls").Worksheets.Count
k = Workbooks("Book3.xls").Worksheets.Count

Do While Workbooks("Book1.xls").Sheets.Count > 1
Range("G1").Value = Worksheets(2).Name
If Range("H1").Value > 0 Then
Worksheets(2).Move after:=Workbooks("Book2.xls").Sheets(j)
Else
Worksheets(2).Move after:=Workbooks("Book3.xls").Sheets(k)
End If

Loop

回答No.3

myRange

▲Range("G1").Value = ●Worksheets(2).Name
If ▲Range("H1").Value > 0 Then
●Worksheets(2).Move after:=Workbooks("Book2.xls").Sheets(j)
Else
●Worksheets(2).Move after:=Workbooks("Book3.xls").Sheets(k)
End If

▲や●の部分にブック名やシート名が省略されてるので
それぞれはアクティブブック、アクティブシートを扱っていることになる
よって、２回目以降はうまくいかない。

Workbooks("Book1.xls").Sheets(1)　　　'▲部分に付加
Workbooks("Book1.xls")　　　　　　　　　'●部分に付加

---------------------------------------

ブック名、シート名を付加しないのなら
Do Whileの次か、最後のLoopの前に、

Workbooks("Book1.xls").Activate

を入れてBook1.xlsをいちいちアクティブする必要がある。
---------------------------------------------

ふつうはG1,H1を使用しないで。。。
--------------------------------------------
Sub test()
　Application.ScreenUpdating = False
　Dim Cnt As Integer
　Dim BK1 As Workbook

　Set BK1 = Workbooks("Book1.xls")

Do While BK1.Worksheets.Count > 1
　If WorksheetFunction.CountIf(BK1.Sheets(1).Range("A:A"), BK1.Sheets(2).Name) Then
　　　Cnt = Workbooks("Book2.xls").Sheets.Count
　　　BK1.Sheets(2).Move after:=Workbooks("Book2.xls").Sheets(Cnt)
　Else
　　　Cnt = Workbooks("Book3.xls").Sheets.Count
　　　BK1.Sheets(2).Move after:=Workbooks("Book3.xls").Sheets(Cnt)
　End If
Loop

Application.ScreenUpdating = True
End Sub
'----------------------------------------

以上です。

お礼

スマートですねー。
わざわざコードを書いていただき、本当にありがとうございます。
今回の問題のためだけでなく、勉強になりました。
自力でここまで書けるようになるよう精進いたします！
また何かありましたら相談させてください。
ありがとうございました！！