ダブルクリックで自動入力

質問

初心者です。教えて下さい。
一つのBOOKに二つのSheetがあります。
Sheet”データ”のA列に番号が入力してあり、そのセルをダブルクリックすると
Sheet”印刷”の（A18）にダブルクリックした番号が入力され、
2回目からは前に入力したセルの一つ下に入力されるようにしたいのですが・・

下記を自分で作ってみましたが、何度やっても（A18）にしか自動入力されません。
どのようにしたら最終行の下に入力されるようになるのでしょうか？
色々調べてみましたが分かりませんでした・・・宜しくお願い致します。

Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
If Target.Count > 1 Then Exit Sub
If Target.Column <> 1 Then Exit Sub
Cancel = True
With Worksheets("印刷")
MyRange = Range("A18").End(xlUp).Offset(1).Address
.Range(MyRange).Value = Target.Value
Application.Goto .Range(MyRange)
End With
End Sub

回答No.1

myRange · ベストアンサー

＞ダブルクリックで自動入力

といいながら、提示のコードは、"右クリック"イベントになってますが。。。。

ま、それは置いといて、ダブルクリックイベントでやると。

'------------------------------------------------------
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
　If Target.Count > 1 Then Exit Sub
　If Target.Column <> 1 Then Exit Sub
　Cancel = True

　Dim LastRow As Long

　LastRow = Sheets("印刷").Cells(Rows.Count, "A").End(xlUp).Row
　If LastRow < 18 Then
　　　　LastRow = 18
　Else
　　　　LastRow = LastRow + 1
　End If

　Sheets("印刷").Cells(LastRow, "A") = Target.Value

　MsgBox "印刷シートのセルＡ" & LastRow & " へ転記しました"
End Sub
'-----------------------------------------------

見ればわかるとおもいますが、
印刷シートのセルＡ１７に、見出し、でもあると
If LastRow < 18 then　の部分は不要です。

以上です。

お礼

早速ありがとうございました。
右クリックにするか・・・悩んでいたので質問内容と相違があり失礼しました。
助かりましたっ<(_ _)>ありがとうございました。