エクセルVBAの文字列操作について

質問

エクセルVBAの文字列操作について
例えば、[１－１０,12,15-20,22-38]と入っているセルがあるとします。
各数字は","で区切られています。このセルに数を足したり引いたりしたいのです。
例えば、このセルから”5”を引いて[１-4,6-１０,12,15-20,22-38]と表示したり、
"21"を足して[１－１０,12,15-38]と表示したいのですが
どなたかご教授いただけないでしょうか？

回答No.3

DOUGLAS_ · ベストアンサー

#1 DOUGLAS_ です。
＞この煩雑な コーディング をご覧になって、
＞もっと スマート なご回答の付くことを
　もう少し スマート な ヤリカタ が見付かりましたのでお知らせいたします。

　使い方は、#1 と同じです。

Function NUMORDER(myStr As String, num As Integer) As String
　Dim strRng As Range
　Dim myRng As Range

'文字列を セルアドレス に変換
　myStr = "$A" & myStr
　myStr = Replace(myStr, " ", "")
　myStr = Replace(myStr, "-", ":$A$")
　myStr = Replace(myStr, ",", ",$A$")

'アドレス を Range オブジェクト に代入し
'「数を足した」場合は、Union メソッド で セル範囲 の集合を求める
　Set strRng = Range(myStr)
　If num > 0 Then
　　Set myRng = Application.Union(Range("$A$" & num), strRng)

'「数を引いた」場合は Intersect メソッド で共有セル範囲を求める
　Else
　　Set strRng = strRng.Offset(1)
　　num = num - 1
　　Set myRng = Application.Intersect(strRng, _
　　　Application.Union(Range("$A$1:$A$" & -num - 1), _
　　　　Range("$A$" & -num + 1 & ":$A$" & Rows.Count)))
　　If myRng Is Nothing Then Exit Function
　　Set myRng = myRng.Offset(-1)
　End If

'求められた セル範囲 の アドレス を文字列に変換
　myStr = myRng.Address
　myStr = Replace(myStr, "$", "")
　myStr = Replace(myStr, "A", "")
　NUMORDER = Replace(myStr, ":", "-")
End Function

お礼

ありがとうございます！解決しました。