Excelで複数セルからの文字の結合

質問

B列からF列までのセルの内容を結合してH列に表示させるため、
以下のVBAを使用したのですが、結果が上手くいきません
原因など分かりましたら、指摘をお願いします

マクロの内容
Sub test01()
Dim c As Range
Dim i As Long
With ActiveSheet
i = 1
Do While .Cells(i, "A") <> ""
If .Cells(i, "A") <> "" Then
For Each c In .Range(.Cells(i, "B"), .Cells(i, "B").Cells(i, "F"))
.Cells(i, "H") = IIf(.Cells(i, "H") = "", c, .Cells(i, "H") & "/" & c)

Next c

Else
.Cells(i, "H") = .Cells(i, "B")
End If
i = i + 1
Loop
End With
End Sub

シートの内容
　ＡＢＣＤＥＦＧＨ
1 １あいうえお
2 ２か　くけこ
3 ３さし　せそ

実行の結果
あ/い/う/え/お/
か/き/く/け/こ//さ/し//せ/そ/
さ/し//せ/そ/////////////

上記のようになってしまいます
２行目の「か/き/く/け/こ」の後に１行下の「さ/し//せ/そ」
が入っている状態です

よろしくお願いします

回答No.4

Trick--o-- · ベストアンサー

で、このソースを使うとすると

For Each c In .Range(.Cells(i, "B"), .Cells(i, "B").Cells(i, "F"))
を
For Each c In .Range(.Cells(i, "B"), Cells(i, "F"))
と直せばうまくいくと思います

#2でも指摘されている
.Cells(i, "B").Cells(i, "F")
ですが、これは
.Cells(i, "B")を基点（A1）としたときの.Cells(i, "F")
という意味になります
そのため、i=1のときは
.Range(.Cells(1, "B"), .Cells(1, "B").Cells(1, "F"))
⇒ .Range(.Cells(1, "B"), .Cells(1, "G"))
i=2のときは
.Range(.Cells(2, "B"), .Cells(2, "B").Cells(2, "F"))
⇒ .Range(.Cells(2, "B"), .Cells(3, "G"))
i=3のときは
.Range(.Cells(3, "B"), .Cells(3, "B").Cells(3, "F"))
⇒ .Range(.Cells(3, "B"), .Cells(5, "G"))
と解釈され、ごらんの有様になるわけです

お礼

ありがとうございます

実は、元々拾い物のソースを改造していたのですが
その際は、"B"の部分が"A"になっていました
A列に連番（空白が無いセル）を付け加えた事を考慮してなかったです

回答No.5

Trick--o--

追記：致命的ではない問題点

Do While .Cells(i, "A") <> ""
If .Cells(i, "A") <> "" Then

Do While の条件で .Cells(i, "A") <> "" としているのだから
その直後の If .Cells(i, "A") <> "" Then は常に真となる（If文の意味が無い）と思いまし。

回答No.3

Trick--o--

Sub セル内容の連結()
　Dim r As Long, c As Long
　Dim txt As String
　' A列の一番下までループする
　For r = 1 To Cells(65536, 1).End(xlUp).Row
　　txt = ""
　　' B列～F列でループする
　　For c = 2 To 6
　　　txt = txt & Cells(r, c).Value & "/"
　　Next c
　　' H列に書き込む
　　Cells(r, 8).Value = txt
　Next r
End Sub

……？
何か、複雑なこと考えてる？

お礼

ありがとうございます
サンプル用のシートでは問題なさそうなので、
本番用のシートで試してみます

回答No.2

akina_line

こんにちは。

　>For Each c In .Range(.Cells(i, "B"), .Cells(i, "B").Cells(i, "F"))
　このRangeはどの範囲を得ようとしているのでしょうか。.Cells(i, "B").Cells(i, "F")が変なのでは？

では。

回答No.1

yucco_chan

Sub test()
Dim rowc As Long
Dim colc As Long
rowc = 1
Do While Cells(rowc, 1) <> ""
　　For colc = 2 To 6
　　　　Cells(rowc, 8) = Cells(rowc, 8) + Cells(rowc, colc) + "／"
　　Next colc
rowc = rowc + 1
Loop
End Sub

これでいいですか？
セルに数字が入っているとエラーになりますが。。