Word2007 文字変換マクロのエラーを解消する方法

質問

• Word2007の文字変換マクロにおいて、特定のvbsファイルがエラーになってしまう場合、解消する方法を教えてください。
• マクロ初心者の方に向けて、Word2007の文字変換マクロで発生するエラーについて解消方法をご教授ください。
• Word2007の文字変換マクロを使用する際に、特定のvbsファイルがエラーになる場合、どのように修正すればよいのでしょうか？

回答No.3

Wendy02

こんにちは。

細かい間違いがあっても、エラーが出ますし、VBScriptは、どこに間違いがあるか、すぐに分からない部分があります。どんなエラーかという内容などいりません。最初から最後まで、エラーなく通ればそれで良いとは思います。ただ、以下のコードは、エラー解除が完全に行われているとは限りません。チェック用と書いてあるのは、ローカルウィンドウなどありませんので、要所で、ストップを入れています。

出来れば、WordのVBAのアドイン化したほうが楽かもしれません。なお、最後に、エラーは返すようにしました。

それと、2.csv ファイルは、どちらかというと、ini ファイルなど、別の名称のほうが良いかもしれません。ただ、手元に参考テキストもないので、2.csvに、2行以上あるなどの問題に対するチェックされていません。

一応、以下は、オートメーション・オブジェクトを残っていないようですが、一度は、必ず、タスクマネージャで、WINWORD.EXE が残っていないか調べてみてください。

'-------------------------------------------
'注意：全角空白は、絶対に入れないでください。

'================
''WordReplace.vbs
'=================
Const wdReplaceAll = 2
Const mFOlDER = "D:\test"
Const csvFILE = "2.csv"
Const sEXT = ".docx"
Dim tx1, tx2
Dim objWord
Dim fName
Dim objFolder
Dim cnt
cnt = 0

Set objWord = CreateObject("Word.Application")
Set fs = CreateObject("Scripting.FileSystemObject")
Set objFolder = fs.GetFolder(mFOlDER)

Call PickUpWord

If tx1 <> "" Then
On Error Resume Next
For Each objFile in objFolder.Files
If Right(LCase(objFile.Name), len(sEXT)) = sEXT Then
'チェック用
'MsgBox objFile.name
Call WordExe (tx1, tx2, objFolder.Path & "\" & objFile.Name)
End If
Next
End If
objWord.Quit
Set fs = Nothing
Set objWord = Nothing
If Err.Number >0 Then
MsgBox Err.Description,48,"Error!"
Else
MsgBox cnt & " 個処理済み。正常終了しました。",64,"終了メッセージ"
End If
On Error Goto 0

'!!Here is the End of Program.
'-------------------------------------------
Sub PickUpWord()
Const ForReading = 1
Dim f
Dim sLine
Set f = fs.OpenTextFile(mFOLDER & "\" & csvFILE, ForReading, True)
sLine = f.ReadLine()
s = Split(sLine, ",")
'MsgBox s(0) & " " & s(1)
tx1 = s(0)
tx2 = s(1)
End Sub

Sub WordExe(tx1, tx2, fName)
cnt = cnt + 1
Const wdFindContinue =1

objWord.Visible = False

Set objDoc = objWord.Documents.Open(fName)
Set objSelection = objDoc.Application.Selection

'チェック用
'Msgbox fName & " :" & cnt
With objSelection.Find
.ClearFormatting
.Replacement.ClearFormatting
.Text = tx1
.Forward = True
.MatchWholeWord = True
.Replacement.Text = tx2
.Wrap = wdFindContinue
.Format = False
.MatchCase = False
.MatchWholeWord = False
.MatchByte = False
.MatchAllWordForms = False
.MatchSoundsLike = False
.MatchWildcards = False
.MatchFuzzy = True
End With
ret =objSelection.Find.Execute(, , , , , , , , , , wdReplaceAll)
If ret Then
objDoc.Save
End If
objDoc.Close
End Sub

お礼

Wendy02さん、貴重な回答ありがとうございます。道が開けました。

内容を見て問題なく動くと思って、VBSファイルに貼り付けて実行してみましたところ、自動的にWordファイルが開いて処理され正常に終了しました。

Wordファイルを開いて確認してみましたところ、2.csvファイルの一番目の行（A,B）しか処理されていません。二番目の行以降（C,D）も処理するにはどこをどのように直したらよいでしょうか。宜しくお願いいたします。

2.csvの内容
A,B
C,D
E,F

2.csvのcsvは、txtでいいと思っています。アドバイスありがとうございました。