他フォームのチェックボックスを参照した条件付書式

質問

OS WinXP
ACCESS 2000

■[フォームＡ]にチェックボックスを設置して
条件付書式にてチェックボックスのＯＮで任意フィールドに色を点けています。
※チェックボックスは連結チェックボックスです。

　条件付書式の式　[チェックボックス名]=True

この方法で問題なく[フォームＡ]の任意のフィールドに色を点けることはできました。

■ここからが質問です。

この[フォームA]に設置してあるチェックボックスがＯＮの時
[フォームＢ]に設置してある非連結テキストボックスにも色を点けたいです。
※[フォームA]に設置したチェックボックスは、どのレコードがＯＮの状態でも
[フォームＢ]のテキストボックスに色を点けたいです。

目的は
[フォームＡ]の任意フィールドに重要なコメントが入力されている場合
[フォームＢ]を開いている時に一目で分かる様にしたいので…。

一応、[フォームＢ]の非連結テキストボックスに
条件付書式の式に
　[Forms]![フォームＡ名]![チェックボックス名]=True
としましたがうまくいきませんでした…。

※フォームは[フォームＡ][フォームＢ]ともに単票形式です。

宜しくお願い致します。

回答No.2

DexMachina · ベストアンサー

No.1です。
まず、前回の補足から(汗)

背景色(BackColor)プロパティを使用する場合は、フォームAのチェックボックスの
更新後だけでなく、フォームAの「開くとき」イベント(または「読み込み時」イベント)
でも、同様のコードが必要でしたので、こちらを使う場合はご注意下さい。
(前回の回答のみだと、開いただけでは背景色が正しく表示されず、チェックボックス
を更新して初めて反映されることになります)

※コード内で「DCount("*", "tbl", "CheckBox=True") > 0」としていましたが、
　 これは「DCount("*", "テーブル名", "[フィールド名]=True") > 0」の誤記です。
　 失礼致しました(テスト時のコードのCopy＆Paste後、修正し忘れました)。

> [フォームA]である任意の顧客(顧客ID)が表示された状態で、
> 設置されている任意のチェックボックスがＯＮの場合、
> 同じ顧客(顧客ID)が表示されている[フォームB]を開いたときに、
> [フォームA]で入力されたどのレコード(日付)に関係なく任意の
> テキストボックスに色を点けたいです。

この場合は、「チェックボックスがTrue」という条件に加えて、「顧客IDがフォームAのそれと
一致」という条件を満たすものをカウントすればよい、ということになるので、DCount関数
の第3引数に、その条件([顧客ID]=[Forms]![フォームB]![txt顧客ID])を追加します。
(今回の件では「双方の条件を同時に満たすもの」の確認となるので、「And」で接続)

<現在>
　DCount("*","テーブル名","[フィールド名]=True") > 0
<修正>
　DCount("*","テーブル名","[フィールド名]=True And [顧客ID]=[Forms]![フォームB]![txt顧客ID]") > 0

※テーブル上のフィールド名が「顧客ID」、フォームB上で顧客IDを表示しているテキスト
　 ボックスの名前が「txt顧客ID」の場合です。
　 (どちらも同じ「顧客ID」という名前なら、「txt顧客ID」は「顧客ID」でOK)

お礼

DexMachina
こんばんは！
お礼のご連絡が遅くなりました。

先ほどアドバイスをいただいた方法で出来ました！
感激です！！

まだまだ勉強不足ですので、将来はDexMachinaさんのように
アドバイスできるよう日々精進していきます。

この度は本当にありがとうございました。
また、お礼が遅くなりましたことは改めてお詫びいたします。

m(_ _)m

回答No.1

DexMachina

条件付き書式のいいところは
　・帳票フォームのレコード間で、データに基づいた変更が可能
　　(プロパティシートからの設定では、レコードによらず一律にしかできない)
　・マクロやVisual Basic for Applications(VBA)を使用しなくても対応可能
といったところかと思いますが、今回ご質問の件では、残念ながらマクロやVBAが
必須になります。
なお、本件ではレコードごとの書式変更でもないので、条件付き書式以外に
背景色(BackColor)プロパティなどの切替でも対応可能です。
以下、双方について説明しますので、やりやすいと思われる方をお選び下さい。

【共通の説明】
「どのレコードがONの状態でも」という場合は、テーブル全体を確認する必要が
あります(→「Forms!～=True」では確認できない)。
確認方法には幾つかありますが、「定義域集計関数」の1つのDCount関数を
使用するのが最も簡単かと思います。

　DCount("*","テーブル名","[フィールド名]=True") > 0

※「テーブル名」にはフォームAのレコードソースにしているテーブル/クエリの名前
　 を、「フィールド名」＝フォームAのチェックボックスのコントロールソースにしている
　 フィールドの名前を、それぞれ指定します。
　(角括弧とダブルクォートは上記のまま残し、「テーブル名」「フィールド名」だけを
　　実際の名前に置き換えます)

また、関数でテーブルのデータを確認する場合、確認対象は「保存済みレコード」
になります。
編集中のレコードについては、編集前のデータが参照されますので、フォーム上の
コントロール(チェックボックスなど)の更新時にテーブル データの確認を行う場合は、
先にレコードを保存しないと、そのレコードについての編集が反映されないことに
なるので注意が必要です。

【条件付き書式を使用する場合】
条件付き書式の式に上記の式を設定した上で、フォームAのチェックボックスの
更新後イベントに、フォームBのテキストボックスに更新を反映するコードを記述
します。

1)フォームAをデザインビューで開く
2)チェックボックスをダブルクリックするなどして、当該チェックボックスのプロパティ
　シートを開く
3)プロパティシートの『イベント』タブの『更新後処理』を選択し、右端に表示
　される「...」(ビルド)ボタンをクリック
4)初期設定では『ビルダの選択』ダイアログが開くはずなので、そこで「コード
　ビルダ」を選択し、Okボタンをクリック
5)VBAの編集画面(VBE)が開くので、以下のようなコードを記述：
　(チェックボックス名を「チェック1」、テキストボックス名を「テキスト0」とした場合)

Private Sub チェック1_AfterUpdate()
'エラー発生時は「エラー処理」に飛ばします。
On Error GoTo エラー処理

　　'レコードを保存します。
　　DoCmd.RunCommand acCmdSaveRecord

　　'フォームBのテキストボックスに条件付き書式の設定を反映させます。
　　Forms!フォームB!テキスト0.Requery

終了処理:
　　'このSubを終了します。
　　Exit Sub

エラー処理:
　　Select Case Err
　　　　Case 2450
　　　　　　'フォームBが開いていなかった場合
　　　　　　'→特に何もしません(MsgBoxを出しても可)
　　　　Case Else
　　　　　　MsgBox Err & "：" & Error$, , Me.Name & " チェック1"
　　End Select
　　'「終了処理」に飛ばします。
　　Resume 終了処理

End Sub

6)フォームを保存して閉じる

【BackColorプロパティで切り替える場合】
条件付き書式が設定されていると正しく動作しなくなりますので、テキスト
ボックスの条件付き書式は削除した上で、以下の操作を行います。

1)上記の「1～4」を実行します。
2)VBAの編集画面で、以下のようなコードを記述：
　※上と共通となるコードについてはコメントを省略しています。

Private Sub CheckBox_AfterUpdate()
On Error GoTo エラー処理

　　'変数の宣言(→色指定の際に使用します)
　　Dim BkClr As Long

　　DoCmd.RunCommand acCmdSaveRecord

　　'チェックボックスがTrueのレコードの有無を確認し、色を決定します。
　　'(「RGB」は色指定の関数です。これについてはヘルプを確認下さい(汗))
　　If DCount("*", "tbl", "CheckBox=True") > 0 Then
　　　　BkClr = RGB(255, 0, 0)　　　　　　　'該当あり→赤
　　Else
　　　　BkClr = RGB(255, 255, 255)　　　　'該当なし→白
　　End If

　　'テキストボックスの背景色を設定します。
　　Forms!フォームB!テキスト0.BackColor = BkClr

終了処理:
　　Exit Sub

エラー処理:
　　Select Case Err
　　　　Case 2450
　　　　Case Else
　　　　　　MsgBox Err & "：" & Error$
　　End Select
　　Resume 終了処理

End Sub

3)フォームを保存して閉じる

・・・長くなりましたが(汗)、以上です。

補足

DexMachinaさん
こんばんは。

早速のアドバイスありがとうございます。
また、大変丁寧なアドバイスで感無量です。

アドバイス内容どおり設定をしたら
どちらの方法でもきちんとフィールドに色が点きました。
ありがとうございます。
※今回は【条件付き書式を使用する場合】を採用しました。

■もう1点だけお力をお借りできればと幸いです。

初めの質問で
　※[フォームA]に設置したチェックボックスは、
　　どのレコードがＯＮの状態でも
と記載しておりましたが、
この考え方ですと、[フィールドB]で表示されている
全ての主キー（顧客ID）に対して適用されてしまいました。
★これは私が初めに質問した時の書き方が完全に間違っておりました。
申し訳ございません。

■改めてご質問を致しますと

[フォームA]である任意の顧客(顧客ID)が表示された状態で、
設置されている任意のチェックボックスがＯＮの場合、
同じ顧客(顧客ID)が表示されている[フォームB]を開いたときに、
[フォームA]で入力されたどのレコード(日付)に関係なく任意のテキストボックスに色を点けたいです。

つまり、
伊藤さんの販売履歴フォーム[フォームＡ]で、任意フィールドに重要なコメントが入力されたので、チェックボックスをＯＮにしてフィールドに色を点けます。
別の[フォームＢ]で、同じ伊藤さんの情報を開いている時に販売履歴フォーム[フォームＡ]で入力した日付に関わらず、チェックボックスがＯＮになっていれば、必ず[フォームＢ]に設置してあるテキストボックスに色が点いてほしい。
となります。

条件付書式の式に入力している
　DCount("*","テーブル名","[フィールド名]=True") > 0
の*印がワイルドカードかと思ったので、[顧客ID]を入力してみましたが、
やはり全ての顧客に対して色が点いてしまいました。

よろしくお願いいたします。