エクセルで上から○個の加算

質問

エクセルで下記の様な表があり、その中で不特定数を手入力した数値を"A1"から下に向かい(下記表では"A1+A2+A3)足し算を行いたいのですが良い方法は無いでしょうか?
出来たら関数を用い計算したいのですが?無理でしょうか?
A B C
1 1
2 1
3 1
4 1
5 1
.
.
.
10 3←不特定数

初心者なので説明不足がありましたらお詫びします。

回答No.2

Cupper · ベストアンサー

ごめん
＞不特定数を手入力した数値を"A1"から下に～
これが何を言っているのか分からない
質問の例ではA1セルから下へ、A10セルに入力した数のセルまでの合計をしたいというのでしょうか？

OFFSET関数や、INDIRECT関数で参照するセル範囲を指定することができるので、それを SUM関数に渡せばよい

　OFFSET(基準セル,基準からずれる行数,基準からずれる列数,基準を含める行数,基準を含める列数)
と指定するので
　OFFSET(A1,0,0,A10,1)
とすればよい

　=SUM(OFFSET(A1,0,0,A10,1))

結果こんなふうになる

INDIRECT関数は引数に入力された文字列をセルとしめす範囲として認識する関数なので
　INDIRECT("A1:A"&A10)
とすると質問の例において A10は 3なので
　"A1:A"&"3"
　　↓
　"A1:A3"
の文字を範囲として使うことができます
　※ ＆で項目を繋ぐと数値も文字として扱われ、結果 文字列になります

　=SUM(INDIRECT("A1:A"&A10))

結果こんなふうになる

他にもいろいろなやり方がありますが、この２つがスタンダードな方法でしょう

質問をするときのアドバイス

例題と結果を示しましょう
　今回の質問の例では結果が示されていません

また、誤解しないような例題を示しましょう
　今回の質問の例では３がキーになると思いますが、合計が３と捉えることも可能です

お礼

私の説明不足で分りにくい内容になってしまい
申し訳有りませんでした。

A10に5と入力した場合には
A1+A2+A3+A4+A5と計算したいのです。

以後、質問をする際は気を付けます。

回答No.4

某HN クロメート(Chromate)（@CoalTar）

#3です。慣れたらINDEX関数の方法も習得してくださいね
OFFSETやINDIRECTは揮発性関数なので、多用すると計算速度が遅くなる一因になります。

揮発性関数は計算対象以外のセルに入力したり、削除したりした場合も計算する関数です。
揮発性関数の例として NOWやTODAY、RANDです。
参考まで

回答No.3

某HN クロメート(Chromate)（@CoalTar）

人気がないけど、INDEX関数はセル参照を返す関数なので
=SUM(A1:INDEX(A1:A9,A10)) とすることも可能です。参考まで

お礼

回答ありがとうございました。
一つの計算でも様様な計算式があるんですね。

少しずつ勉強していきます。ありがとうございました。

回答No.1

mshr1962

A1からの加算なら下記のように範囲の前を絶対参照にして下方にコピー
B1=SUM($A$1:$A1)

○個を指定しての加算なら
B1=3 ←計算するセルの個数
B2=SUM(OFFSET($A$1,,,B1,1))

OFFSET(基準位置,行移動,列移動,行数,列数)
で基準位置のセル座標を起点にしたセル範囲を指定できます。

お礼

私の分かりにくい質問を理解してもらい回答して頂いて
ありがとうございました。

「○個の指定しての加算」の方法で私の行いたい計算が出来ました。
本当にありがとうございました。