エクセルで特定の文字のフォントサイズ・色を変更したい。

質問

質問番号：1822805を参考にエクセルで特定の文字に色付けする作業をしています。
このときに、色を変えると同時にフォントサイズとフォントスタイルを
太字にしたいのですがエラーでうまくいきません。
どなたかご教授いただければと思います。
エラー内容は『オブジェクトはこのプロパティまたはメソッドをサポートしていません』です。
ちなみに下記のような構文を書いています。
『日本』と言う文字列に色をつける場合となっています。

Sub test()
Dim rng As Range, r As Range, i As Long, colInd As Integer
With ActiveSheet
Set rng = .Range("a1:z100") '範囲の設定
txt = "日本" '文字の設定
colInd = 3 '色の設定
For Each r In rng
If InStr(r, txt) > 0 Then _
r.Characters(InStr(r, txt), Len(txt)) _
.Font.ColorIndex = colInd
.Font.Size = 12
.Font.Fontstyle = "太字"

Next
End With
End Sub

回答No.2

merlionXX · ベストアンサー

構文を間違っています。

Sub test()
Dim rng As Range, r As Range, i As Long, colInd As Integer
With ActiveSheet
Set rng = .Range("a1:z100") '範囲の設定
txt = "日本" '文字の設定
colInd = 3 '色の設定
For Each r In rng
If InStr(r, txt) > 0 Then
With r.Characters(InStr(r, txt), Len(txt))
.Font.ColorIndex = colInd
.Font.Size = 12
.Font.FontStyle = "太字"
End With
End If
Next
End With
End Sub

お礼

早速ありがとうございます。
基本的な部分が間違っていたんですね・・・

試してみたら成功しました。

ありがとうございました。

回答No.1

marbin

>With ActiveSheet

>.Font.Size = 12
>.Font.Fontstyle = "太字"

シートオブジェクトにはフォントサイズやフォントスタイル
というのは存在しないと思います。

お礼

早速ありがとうございます。

参考にさせていただきます。