サブルーチンの使い方

質問

こんにちは

以前 このサイトでサブルーチンを教えて頂いたのですが
今回は、このサブルーチンを使って
Commandbuttonに
Sheets("20年7月度").Cells(2, 6).Value = Cells(2, 6) & Mojiを
入れたいのですが、どのようにすれば いいですか？
宜しくお願い致します。

Private Sub mySub(Moji) '数字
If Me.MultiPage1.Value = 0 Then
TextBox3.Value = TextBox3 & Moji
Else: TextBox1.Value = TextBox1 & Moji
End If
End Sub

Private Sub CommandButton1_Click() 'サブルーチン
Call mySub("1")
End Sub
Private Sub CommandButton2_Click()
Call mySub("2")
End Sub
Private Sub CommandButton3_Click()
Call mySub("3")
End Sub
Private Sub CommandButton4_Click()
Call mySub("4")
End Sub
Private Sub CommandButton5_Click()
Call mySub("5")
End Sub
Private Sub CommandButton6_Click()
Call mySub("6")
End Sub
Private Sub CommandButton7_Click()
Call mySub("7")
End Sub
Private Sub CommandButton8_Click()
Call mySub("8")
End Sub
Private Sub CommandButton9_Click()
Call mySub("9")
End Sub
Private Sub CommandButton10_Click()
Call mySub("0")
End Sub
Private Sub CommandButton11_Click()
Call mySub("00")
End Sub
Private Sub CommandButton12_Click()
Call mySub("000")
End Sub

回答No.1

Wendy02 · ベストアンサー

こんばんは。

本来、コマンドボタンの代わりに、ComboBox などのほうが、便利だと思いますが、ご質問者さんは、同じような質問をずっと繰り返しているようですから、一度、以下のようなテクニックを紹介しておきます。

'-----------------------------------

'UserForm モジュール

Dim clsBtn(11) As New Class1
Private Sub UserForm_Initialize()
Dim cn As Object
Dim i As Integer
Dim j As String
myMonth = "20年7月度"
　For Each cn In Me.Controls
　　 If TypeName(cn) = "CommandButton" Then
　　　　Set clsBtn(i).myBtn = cn
　　　　If i > 8 Then
　　　　　　j = String(i - 8, "0")
　　　　Else
　　　　　　j = i + 1
　　　　End If
　　　　clsBtn(i).mIndex = j
　　　 i = i + 1
　　 End If
　Next cn
End Sub

'-----------------------------------
'標準モジュール
Public myMonth As String

'-----------------------------------
'クラスモジュール　(Class1)
Public WithEvents myBtn As MSForms.CommandButton
Public mIndex As String

Public Property Get Index() As String
　　　　Index = mIndex
End Property

Private Sub myBtn_Click()
　With UserForm1
　　If .MultiPage1.Value = 0 Then
　　　 .TextBox3.Value = .TextBox3.Value & mIndex
　　Else
　　　 .TextBox1.Value = .TextBox1.Value & mIndex
　　End If
　End With
　　With Worksheets(myMonth)
　　　　.Cells(2, 6).Value = Cells(2, 6).Value & mIndex
　　End With
End Sub

お礼

有り難うございました。