Excelで月を入力すると日と曜日を一覧表示する方法

質問

Excel初心者なのでどなたかお詳しいかたお願い致します！

Excelで月を入力するとその月の日と曜日を一覧で表示させたいのです。
たとえば、”２月”と入力すると、以下のような一覧を自動的にだす計算式が知りたいです。

お手数をかけますが、何卒よろしくお願い致します

　　　Ａ　　Ｂ
１　　２月　←　入力
２
３　　１　　日
４　　２　　月
５　　３　　火
　・
　・
　・
３１　２８　土

回答No.5

9der-qder · ベストアンサー

これでいかがでしょう？

これなら、小の月（31日までない月）にも対応します。
なお、C列はユーザー定義で表示を日のみ（d）にしてあります。
C1：=IF($A$2=MONTH(DATE($A$1,$A$2,ROW())),DATE($A$1,$A$2,ROW()),"")
D1：=CHOOSE(WEEKDAY(C1),"日","月","火","水","木","金","土")
です。
C列を手入力にすると、D列を自動にすることは出来ますが、小の月は自分で考慮する必要があります。

↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓

お礼

探していたのはこれです！！
ありがとうございました！
助かりました

回答No.4

marbin

#2です。
B3の式は↓に変えてください。
=IF(A3="","",TEXT(DATE(YEAR(TODAY()),$A$1,ROW()-2),"aaa"))

でないと無い日付けまで曜日が表示されてしまいます。

お礼

できました！！
ありがとうございました！！

回答No.3

web2525

A3セルに
=DATE(YEAR(TODAY()),VALUE(LEFT(A1,FIND("月",A1,1)-1)),1)
書式設定を d
B3セルに
=A3
書式設定を aaa
下方向にフィル
A４セルに
=A3+1
書式設定　d
下方向にフィル

29日以降はif関数で月が変わったら表示しないなどの設定で

お礼

できました！
ありがとうございました！

回答No.2

marbin

いろんな方法があると思います。
一例です。
A1には
2
などと入力し、ユーザー定義書式で
0"月"
とします。
A3=IF(MONTH(DATE(YEAR(TODAY()),$A$1,ROW()-2))<>$A$1,"",ROW()-2)
B3=TEXT(DATE(YEAR(TODAY()),$A$1,ROW()-2),"aaa")
A3、B3を33行までコピペ

お礼

できました！！
ありがとうございました！

回答No.1

noname#99913

すべて自動で入力できる関数はありません。日にちは自分で入力してください。オートフィルを使えば簡単にできます。

そのあと、
(1)A1に、「2」、B1に「月」と入力
(2)Ｂ３に「=DATE(2009,A$1,A3)」と入力し、下へコピー
(3)曜日欄の表示書式を、ユーザー定義で「aaa」とする。

お礼

早速のご回答ありがとうございました