エクセルで列Ａの同じ値のものを15行ずつ表示したい

質問

「エクセルで同じ列の値のものを15行ずつ表示したい」というタイトルではきちんと表現できませんでしたが、
以下のことはできますでしょうか？
　　　Ａ　　　Ｂ　　　Ｃ
１　りんご　　１　　　100　　・・・
２　りんご　　９　　　100　　・・・
３　みかん　　４　　　70　　・・・
４　なし　　　３　　　110　　・・・
５　なし　　　１　　　110　　・・・
６　なし　　　５　　　110　　・・・

といったシートがあるとします。
これを「Ａ」の列を基準に15列ずつに分けたいと思います。

　　　Ａ　　　Ｂ　　　Ｃ
１　りんご　　１　　　100　　・・・
２　りんご　　９　　　100　　・・・
・・・15まで空白
16　みかん　　４　　　70　　・・・
・・・30まで空白
31　なし　　　３　　　110　　・・・
32　なし　　　１　　　110　　・・・
33　なし　　　５　　　110　　・・・
・・・45まで空白

何かよい方法があれば教えてください。

よろしくお願いいたします。

回答No.1

mu2011 · ベストアンサー

次の方法は如何でしょうか。
・シート３にデータ表
・シート１のＡ１、Ａ１６、Ａ３１に数式を設定し、下方向に１５行分、右方向に必要列分コピーして下さい。
・配列数式を使用していますので、入力完了時にshift＋ctrl＋enterキーを同時押下して下さい。
Ａ１セルに=IF(ROW($A1)-1<COUNTIF(Sheet3!$A$1:$A$200,"りんご"),INDEX(Sheet3!A$1:A$200,SMALL(IF(Sheet3!$A$1:$A$200="りんご",ROW(Sheet3!$A$1:$A$200),999),ROW($A1))),"")
Ａ１６セルに=IF(ROW($A1)-1<COUNTIF(Sheet3!$A$1:$A$200,"みかん"),INDEX(Sheet3!A$1:A$200,SMALL(IF(Sheet3!$A$1:$A$200="みかん",ROW(Sheet3!$A$1:$A$200),999),ROW($A1))),"")
Ａ３１セルに=IF(ROW($A1)-1<COUNTIF(Sheet3!$A$1:$A$200,"なし"),INDEX(Sheet3!A$1:A$200,SMALL(IF(Sheet3!$A$1:$A$200="なし",ROW(Sheet3!$A$1:$A$200),999),ROW($A1))),"")

回答No.4

NNAQ

X列が空いているとして、
X1セルに 1 を入力。
X2=IF(A1=A2,X1,X1+1)
データの最終行までコピー。
ご質問の例だと6行目（X6）まで。
　　↓
X7=MATCH(1,INDEX((COUNTIF(X$1:X6,ROW(INDIRECT("A1:A"&MAX(X$1:X6))))<15)*1,),)
X6の値を15倍した行（X6が3なら3*15=45行目）までコピー。
　　↓
X列をコピーして[形式を選択して貼り付け]-[値]。
X列をキーに昇順で並べ替え。
X列を削除。

※データが多いと再計算に時間がかかります。

※#3のmaron--5さんの式は
Y2=IF(A2<>"",X2,IF(ROW(A1)=COUNTA(A:A),1,IF(COUNTIF($Y$1:Y1,Y1)<15,Y1,IF(Y1=MAX(X:X),"",Y1+1))))
ですかね？

お礼

#4さんのご回答へのお礼でみなさまへのお礼にかえさせていただきますことをお許し下さい。

さらに、お返事が遅れてしまい申し訳ありません。

みなさまの方法で検討してみます。
わたくしオリジナルのものは結局データ件数が多すぎてかえってきませんでした（泣

いろんな方法がありますね。
ありがとうございました。

回答No.3

maron--5

◆補助列を２列設けます
◆補助列（何処でもいいのですが、使用している次の列とし仮にX列とします）
X1=IF(A1="","",COUNT(INDEX(1/(MATCH($A$1:A1,$A$1:A1,)=ROW($A$1:A1)),)))
★下にコピー
Y1=1
Y2=IF(A2<>"",D2,IF(ROW(A1)=COUNTA(A:A),1,IF(COUNTIF($E$1:E1,E1)<15,E1,IF(E1=MAX(D:D),"",E1+1))))
★Y2の式を下にコピー

◆Y列をキーに昇順で並び替えします

回答No.2

noname#204879

Sheet1
　　 A　　　B　　　 C　…
1　種類　　個数　単価　…
2　りんご　　 1　 100　…
3　りんご　　 9　 100　…
4　みかん　　 4　　70　…
5　なし　　　 3　 110　…
6　なし　　　 1　 110　…
7　なし　　　 5　 110　…
8　…　　　　…　　…　…

Sheet2
　　A　 B　　 C　　 D　　 E　　　F　　　G　　 H
1　 5　tmp1　tmp2　tmp3　tmp4　種類　　個数　単価
2　　　　 2　　 2　　 1　　 1　りんご　　 1　 100
3　　　　 2　　　　　 1　　 2　りんご　　 9　 100
4　　　　 1　　 4　　 1　　 3　　　　　
5　　　　 3　　 5　　 1　　 4　　　　　
6　　　　 3　　　　　 1　　 5　　　　　
7　　　　 3　　　　　 2　　 1　みかん　　 4　　70
8　　　　 0　　 8　　 2　　 2　　　　　
9　　　　 0　　　　　 2　　 3　　　　　
10　　　　0　　　　　 2　　 4　　　　　
11　　　　0　　　　　 2　　 5　　　　　
12　　　　0　　　　　 3　　 1　なし　　　 3　 110
13　　　　0　　　　　 3　　 2　なし　　　 1　 110
14　　　　0　　　　　 3　　 3　なし　　　 5　 110
15　　　　0　　　　　 3　　 4
16　　　　0　　　　　 3　　 5
17　　　　0　　　　　 4　　 1

Sheet2 において、…
１．セル A1 には何行ずつ表示するかの数値を入力
　　ここでは 5 にしているが、貴方の場合は 15 にされたい
２．次の左端に示す各セルに、それぞれ該当する式を入力
　　B2: =COUNTIF(Sheet1!A:A,Sheet1!A2)
　　C2: =IF(B2<>B1,ROW(),"")
　　D2: =INT((ROW()-2)/A$1)+1
　　E2: =MOD(ROW()-2,A$1)+1
３．範囲 B2:E2 を下方に必要なだけ、あるいはそれ以上ズズーッと複写
４．セル F2 に次式を入力し、此れを右方に必要なだけズズーッと複写
　　=IF(ISERROR(INDEX($B:$B,SMALL($C:$C,$D2))),"",IF($E2>INDEX($B:$B,SMALL($C:$C,$D2)),"",OFFSET(INDIRECT("Sheet1!A$"&SMALL($C:$C,$D2)),$E2-1,COLUMN(A1)-1)))
５．セル F2 以右の範囲を下方にズズーッと複写
６．列Ｆ以右全体を選択して[コピー]→[値の貼り付け]を実行
７．列Ａ～Ｅを削除