EXCEL参照列の数値によって表示列の表示内容が自動表示されるには

質問

B列の数値によってA列にAからDを自動表示させたい：

A列（文字）　　　　B列
A　　　　　　　　２１以上３０未満
B　　　　　　　　１５以上２０以下
C　　　　　　　　１０以上１４以下
D　　　　　　　　１０未満

※A列に何らかの関数を設定する事で可能ですか？

回答No.2

hirumin · ベストアンサー

B1に数値があるなら

=IF(AND(B1>=21,B1<30),"A",IF(AND(B1>=15,B1<20),"B",IF(AND(B1>=10,B1<14),"C",IF(B1<10,"D","-"))))

A～Dに当てはまらない場合、「-」にしています。

IF文で
＝IF（　【条件】　，　【条件に合う場合】　,　【合わない場合】　）
となるわけですが、【合わない場合】にまたIF文をいれて条件分岐させるわけです。
ANDは2つの条件を満たす場合に用います。

回答No.6

imogasi

これはＶＬＯＯＫＵＰ関数のＴＲＵＥ型の典型的な例です。
－１０から３０までとして
Ａ１に
=VLOOKUP(B6,{0,"D";10,"C";15,"B";20,"B";21,"A";30,""},2,TRUE)
と入れて下方向に式を複写する。
小数点つき数をＢ列に入れると、小数点部は無視（切捨て）して判断されます。

回答No.5

noname#204879

D　　E　F
1　 0　 D　0以上10未満
2　10　 C　10以上15未満
3　15　 B　15以上20未満
4　20　 A　20以上

何処か空いた範囲、例えば範囲 D1:E4 に上に示すデータを事前に入力しておけば、
セル A1 に式 =VLOOKUP(B1,D$1:E$4,2) をすると、セル B1 の値に応じて A～D の何れかの記号を「自動表示」してくれます。
どうしても、Ｂ列が２０のときＡ列を B と表示させたいなら、上表のセル D4 の 20 を 21 に書き替えてください。

回答No.4

ipsum11

質問の意味が理解できません。ですので、間違っていたら無視してください。
やりたいことは、B列の数値が２１以上３０未満なら「A」、１５以上２０以下なら「B」、１０以上１４以下なら「C」、１０未満なら「D」をA列に表示ってことですかね。

= IF( B6 < 10, "D", IF( B6 <= 14, "C", IF( B6 <= 20, "B", IF( B6 < 30, "A", "" ) ) ) )

でどうでしょうか？

回答No.3

mu2011

仮に０以下、３０以上は表示しないとしましたが、次の方法は如何でしょうか。

=IF(OR(B1<=0,B1>=30),"",LOOKUP(B1,{0,10,15,21},{"D","C","B","A"}))

回答No.1

miyuyu

> ※A列に何らかの関数を設定する事で可能ですか？
質問に対する回答は可能です。としかいいようがないです。

#もし、方法そのものズバリを求めているのであれば
例：=IF(RC[1]<10,"D",IF(RC[1]<15,"C",IF(RC[1]<20,"B",IF(RC[1]<30,"A",""))))
でいかがでしょうか。